Introduce host_pkg_config variable for cross-compilation

build/config/linux/pkg_config.gni

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 
 # Defines a config specifying the result of running pkg-config for the given
 # packages. Put the package names you want to query in the "packages" variable
 # inside the template invocation.
 #
@@ skipping 14 matching lines @@
 #   ignore_libs = true
 
 declare_args() {
   # A pkg-config wrapper to call instead of trying to find and call the right
   # pkg-config directly. Wrappers like this are common in cross-compilation
   # environments.
   # Leaving it blank defaults to searching PATH for 'pkg-config' and relying on
   # the sysroot mechanism to find the right .pc files.
   pkg_config = ""
 
+  # A optional pkg-config wrapper to use for tools built on the host.
+  host_pkg_config = ""
+
   # CrOS systemroots place pkgconfig files at <systemroot>/usr/share/pkgconfig
   # and one of <systemroot>/usr/lib/pkgconfig or <systemroot>/usr/lib64/pkgconfig
   # depending on whether the systemroot is for a 32 or 64 bit architecture.
   #
   # When build under GYP, CrOS board builds specify the 'system_libdir' variable
   # as part of the GYP_DEFINES provided by the CrOS emerge build or simple
   # chrome build scheme. This variable permits controlling this for GN builds
   # in similar fashion by setting the `system_libdir` variable in the build's
   # args.gn file to 'lib' or 'lib64' as appropriate for the target architecture.
   system_libdir = "lib"
@@ skipping 13 matching lines @@
   ]
 } else if (pkg_config != "") {
   pkg_config_args = [
     "-p",
     pkg_config,
   ]
 } else {
   pkg_config_args = []
 }
 
-# Only use the custom libdir when building with the target sysroot.
 if (target_sysroot != "" && sysroot == target_sysroot) {
   pkg_config_args += [
     "--system_libdir",
     system_libdir,
   ]
 }
 
+if (host_pkg_config != "") {
+  host_pkg_config_args = [
+    "-p",
+    host_pkg_config,
+  ]
+} else {
+  host_pkg_config_args = pkg_config_args
+}
+
 template("pkg_config") {
+  # Only use the custom libdir when building with the target sysroot.

[Dirk Pranke, 2017/04/21 00:25:25]

Why did this comment move?

[richard.townsend, 2017/04/21 17:08:03]

Done.

+  if (host_toolchain == current_toolchain) {
+    active_pkg_config_args = host_pkg_config_args
+  } else {
+    active_pkg_config_args = pkg_config_args
+  }

[Dirk Pranke, 2017/04/21 00:25:25]

I'd probably move this if down to line 97 and just have

if (current == host) {
  args = host_pkg_config_args + invoker.packages
} else {
  args = pkg_config_args + invoker.packages
}

[richard.townsend, 2017/04/21 17:08:03]

Done.

   assert(defined(invoker.packages),
          "Variable |packages| must be defined to be a list in pkg_config.")
   config(target_name) {
-    args = pkg_config_args + invoker.packages
+    args = active_pkg_config_args + invoker.packages
     if (defined(invoker.extra_args)) {
       args += invoker.extra_args
     }
 
     pkgresult = exec_script(pkg_config_script, args, "value")
     include_dirs = pkgresult[0]
     cflags = pkgresult[1]
 
     if (!defined(invoker.ignore_libs) || !invoker.ignore_libs) {
       libs = pkgresult[2]
       lib_dirs = pkgresult[3]
       ldflags = pkgresult[4]
     }
 
     forward_variables_from(invoker,
                            [
                              "defines",
                              "visibility",
                            ])
   }
 }