[ios clean] Functionality for menu overflow navigation buttons

ios/clean/chrome/browser/ui/tools/menu_view_controller.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/clean/chrome/browser/ui/tools/menu_view_controller.h"
 
 #include "base/i18n/rtl.h"
 #import "base/logging.h"
 #import "base/macros.h"
 #import "ios/chrome/browser/ui/rtl_geometry.h"
 #import "ios/clean/chrome/browser/ui/commands/find_in_page_visibility_commands.h"
+#import "ios/clean/chrome/browser/ui/commands/navigation_commands.h"
 #import "ios/clean/chrome/browser/ui/commands/tools_menu_commands.h"
 #import "ios/clean/chrome/browser/ui/toolbar/toolbar_button.h"
 #import "ios/clean/chrome/browser/ui/tools/menu_overflow_controls_stackview.h"
 #import "ios/clean/chrome/browser/ui/tools/tools_actions.h"
 #import "ios/clean/chrome/browser/ui/tools/tools_menu_item.h"
 #import "ios/third_party/material_components_ios/src/components/Typography/src/MaterialTypography.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 namespace {
 const CGFloat kMenuWidth = 250;
 const CGFloat kMenuItemHeight = 48;
 }
 
 @interface MenuViewController ()<ToolsActions>
+@property(nonatomic, strong) UIStackView* menuStackView;
 @property(nonatomic, strong) NSArray<ToolsMenuItem*>* menuItems;
 @property(nonatomic, strong)
     MenuOverflowControlsStackView* toolbarOverflowStackView;
 @end
 
 @implementation MenuViewController
 @synthesize dispatcher = _dispatcher;
 @synthesize menuItems = _menuItems;
+@synthesize menuStackView = _menuStackView;
 @synthesize toolbarOverflowStackView = _toolbarOverflowStackView;
 
 - (void)loadView {
   CGRect frame;
   frame.size = CGSizeMake(kMenuWidth, kMenuItemHeight * _menuItems.count);
   frame.origin = CGPointZero;
   self.view = [[UIView alloc] initWithFrame:frame];
   self.view.backgroundColor = [UIColor whiteColor];
   self.view.autoresizingMask = UIViewAutoresizingNone;
   self.view.layer.borderColor = [UIColor clearColor].CGColor;
 }
 
 - (void)viewDidLoad {
   NSMutableArray<UIButton*>* buttons =
       [[NSMutableArray alloc] initWithCapacity:_menuItems.count];
 
+  // Load menu items.
   for (ToolsMenuItem* item in _menuItems) {
     UIButton* menuButton = [UIButton buttonWithType:UIButtonTypeSystem];
     menuButton.translatesAutoresizingMaskIntoConstraints = NO;
     menuButton.tintColor = [UIColor blackColor];
     [menuButton setTitle:item.title forState:UIControlStateNormal];
     [menuButton setContentEdgeInsets:UIEdgeInsetsMakeDirected(0, 10.0f, 0, 0)];
     [menuButton.titleLabel setFont:[MDCTypography subheadFont]];
     [menuButton.titleLabel setTextAlignment:NSTextAlignmentNatural];
     [menuButton addTarget:self
-                   action:@selector(closeToolsMenu:)
+                   action:@selector(closeToolsMenu)
          forControlEvents:UIControlEventTouchUpInside];
     if (item.action) {
       id target = (item.action == @selector(showFindInPage)) ? self : nil;
       [menuButton addTarget:target
                      action:item.action
            forControlEvents:UIControlEventTouchUpInside];
     }
     [buttons addObject:menuButton];
   }
 
   // Placeholder stack view to hold menu contents.
-  UIStackView* menu = [[UIStackView alloc] initWithArrangedSubviews:buttons];
-  menu.translatesAutoresizingMaskIntoConstraints = NO;
-  menu.axis = UILayoutConstraintAxisVertical;
-  menu.distribution = UIStackViewDistributionFillEqually;
-  menu.alignment = UIStackViewAlignmentLeading;
+  self.menuStackView = [[UIStackView alloc] initWithArrangedSubviews:buttons];
+  self.menuStackView.translatesAutoresizingMaskIntoConstraints = NO;
+  self.menuStackView.axis = UILayoutConstraintAxisVertical;
+  self.menuStackView.distribution = UIStackViewDistributionFillEqually;
+  self.menuStackView.alignment = UIStackViewAlignmentLeading;
 
   // Stack view to hold overflow ToolbarButtons.
   if (self.traitCollection.horizontalSizeClass ==
       UIUserInterfaceSizeClassCompact) {
-    self.toolbarOverflowStackView =
-        [[MenuOverflowControlsStackView alloc] init];
-    // PLACEHOLDER: ToolsMenuButton might end up being part of the MenuVC's view
-    // instead of the StackView. We are waiting confirmation on this.
-    [self.toolbarOverflowStackView.toolsMenuButton
-               addTarget:nil
-                  action:@selector(closeToolsMenu:)
-        forControlEvents:UIControlEventTouchUpInside];
-    [menu insertArrangedSubview:self.toolbarOverflowStackView atIndex:0];
-    [NSLayoutConstraint activateConstraints:@[
-      [self.toolbarOverflowStackView.leadingAnchor
-          constraintEqualToAnchor:menu.leadingAnchor],
-      [self.toolbarOverflowStackView.trailingAnchor
-          constraintEqualToAnchor:menu.trailingAnchor],
-    ]];
+    [self setUpOverFlowControlsStackView];
   }
 
-  [self.view addSubview:menu];
+  // Setup constraints.
+  [self.view addSubview:self.menuStackView];
   [NSLayoutConstraint activateConstraints:@[
-    [menu.leadingAnchor constraintEqualToAnchor:self.view.leadingAnchor],
-    [menu.trailingAnchor constraintEqualToAnchor:self.view.trailingAnchor],
-    [menu.bottomAnchor constraintEqualToAnchor:self.view.bottomAnchor],
-    [menu.topAnchor constraintEqualToAnchor:self.view.topAnchor],
+    [self.menuStackView.leadingAnchor
+        constraintEqualToAnchor:self.view.leadingAnchor],
+    [self.menuStackView.trailingAnchor
+        constraintEqualToAnchor:self.view.trailingAnchor],
+    [self.menuStackView.bottomAnchor
+        constraintEqualToAnchor:self.view.bottomAnchor],
+    [self.menuStackView.topAnchor constraintEqualToAnchor:self.view.topAnchor],
+  ]];
+}
+
+- (void)setUpOverFlowControlsStackView {
+  self.toolbarOverflowStackView = [[MenuOverflowControlsStackView alloc] init];
+  // PLACEHOLDER: ToolsMenuButton might end up being part of the MenuVC's view
+  // instead of the StackView. We are waiting confirmation on this.
+  [self.toolbarOverflowStackView.toolsMenuButton
+             addTarget:nil

[lpromero, 2017/04/18 09:34:11]

This uses nil-targeting but not the others. Consider cleaning the discrepancy.

[sczs, 2017/04/19 22:49:00]

Good catch. Done.

+                action:@selector(closeToolsMenu)
+      forControlEvents:UIControlEventTouchUpInside];
+  [self.toolbarOverflowStackView.reloadButton
+             addTarget:self
+                action:@selector(reloadPage)
+      forControlEvents:UIControlEventTouchUpInside];
+  [self.toolbarOverflowStackView.stopButton
+             addTarget:self
+                action:@selector(stopLoadingPage)
+      forControlEvents:UIControlEventTouchUpInside];
+
+  [self.menuStackView insertArrangedSubview:self.toolbarOverflowStackView
+                                    atIndex:0];
+  [NSLayoutConstraint activateConstraints:@[
+    [self.toolbarOverflowStackView.leadingAnchor
+        constraintEqualToAnchor:self.menuStackView.leadingAnchor],
+    [self.toolbarOverflowStackView.trailingAnchor
+        constraintEqualToAnchor:self.menuStackView.trailingAnchor],
   ]];
 }
 
 #pragma mark - ToolsMenuCommands
 
-- (void)closeToolsMenu:(id)sender {
+- (void)closeToolsMenu {
   [self.dispatcher closeToolsMenu];
 }
 
 - (void)showFindInPage {
   [self.dispatcher showFindInPage];

[lpromero, 2017/04/18 09:34:11]

Should this also close the tools menu if opened?

[marq (ping after 24h), 2017/04/18 12:11:23]

It does already; all of the regular menu buttons have -closeToolMenu as their
first action.

[lpromero, 2017/04/18 12:12:16]

Acknowledged.

 }
 
+#pragma mark - NavigationCommands
+
+- (void)reloadPage {
+  [self.dispatcher reloadPage];
+  [self closeToolsMenu];

[marq (ping after 24h), 2017/04/18 12:11:23]

Please follow the pattern of the other menu controls and have the buttons send
-closeToolsMenu as a separate action (added before the specific button actions).

[sczs, 2017/04/19 22:49:00]

Done.

+}
+
+- (void)stopLoadingPage {
+  [self.dispatcher stopLoadingPage];
+  [self closeToolsMenu];
+}
+
 #pragma mark - Tools Consumer
 
 - (void)setToolsMenuItems:(NSArray*)menuItems {
   _menuItems = menuItems;
 }
 
 @end