[ObjC ARC] Converts ios/chrome/browser/ui/settings:settings_arc to ARC.

ios/chrome/browser/ui/settings/block_popups_collection_view_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/settings/block_popups_collection_view_controller.h"
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #import "base/mac/foundation_util.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/values.h"
 #include "components/content_settings/core/browser/host_content_settings_map.h"
 #include "components/content_settings/core/common/content_settings_pattern.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/content_settings/host_content_settings_map_factory.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_switch_item.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_text_item.h"
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/settings/settings_navigation_controller.h"
 #import "ios/chrome/browser/ui/settings/utils/content_setting_backed_boolean.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Palettes/src/MaterialPalettes.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 typedef NS_ENUM(NSInteger, SectionIdentifier) {
   SectionIdentifierMainSwitch = kSectionIdentifierEnumZero,
   SectionIdentifierExceptions,
 };
 
 typedef NS_ENUM(NSInteger, ItemType) {
   ItemTypeMainSwitch = kItemTypeEnumZero,
   ItemTypeHeader,
   ItemTypeException,
 };
 
 }  // namespace
 
 @interface BlockPopupsCollectionViewController ()<BooleanObserver> {
   ios::ChromeBrowserState* _browserState;  // weak
 
   // List of url patterns that are allowed to display popups.
   base::ListValue _exceptions;
 
   // The observable boolean that binds to the "Disable Popups" setting state.
-  base::scoped_nsobject<ContentSettingBackedBoolean> _disablePopupsSetting;
+  ContentSettingBackedBoolean* _disablePopupsSetting;
 
   // The item related to the switch for the "Disable Popups" setting.
-  base::scoped_nsobject<CollectionViewSwitchItem> _blockPopupsItem;
+  CollectionViewSwitchItem* _blockPopupsItem;
 }
 
 // Fetch the urls that can display popups and add them to |_exceptions|.
 - (void)populateExceptionsList;
 
 // Returns YES if popups are currently blocked by default, NO otherwise.
 - (BOOL)popupsCurrentlyBlocked;
 
 @end
 
 @implementation BlockPopupsCollectionViewController
 
 - (instancetype)initWithBrowserState:(ios::ChromeBrowserState*)browserState {
   DCHECK(browserState);
   self = [super initWithStyle:CollectionViewControllerStyleAppBar];
   if (self) {
     _browserState = browserState;
     HostContentSettingsMap* settingsMap =
         ios::HostContentSettingsMapFactory::GetForBrowserState(_browserState);
-    _disablePopupsSetting.reset([[ContentSettingBackedBoolean alloc]
+    _disablePopupsSetting = [[ContentSettingBackedBoolean alloc]
         initWithHostContentSettingsMap:settingsMap
                              settingID:CONTENT_SETTINGS_TYPE_POPUPS
-                              inverted:YES]);
+                              inverted:YES];
     [_disablePopupsSetting setObserver:self];
     self.title = l10n_util::GetNSString(IDS_IOS_BLOCK_POPUPS);
     self.collectionViewAccessibilityIdentifier =
         @"block_popups_settings_view_controller";
 
     [self populateExceptionsList];
     [self updateEditButton];
     [self loadModel];
   }
   return self;
 }
 
 - (void)dealloc {
   [_disablePopupsSetting setObserver:nil];
-  [super dealloc];
 }
 
 #pragma mark - SettingsRootCollectionViewController
 
 - (void)loadModel {
   [super loadModel];
 
   CollectionViewModel* model = self.collectionViewModel;
 
   // Block popups switch.
   [model addSectionWithIdentifier:SectionIdentifierMainSwitch];
 
-  _blockPopupsItem.reset(
-      [[CollectionViewSwitchItem alloc] initWithType:ItemTypeMainSwitch]);
-  _blockPopupsItem.get().text = l10n_util::GetNSString(IDS_IOS_BLOCK_POPUPS);
-  _blockPopupsItem.get().on = [_disablePopupsSetting value];
-  _blockPopupsItem.get().accessibilityIdentifier =
-      @"blockPopupsContentView_switch";
+  _blockPopupsItem =
+      [[CollectionViewSwitchItem alloc] initWithType:ItemTypeMainSwitch];
+  _blockPopupsItem.text = l10n_util::GetNSString(IDS_IOS_BLOCK_POPUPS);
+  _blockPopupsItem.on = [_disablePopupsSetting value];
+  _blockPopupsItem.accessibilityIdentifier = @"blockPopupsContentView_switch";
   [model addItem:_blockPopupsItem
       toSectionWithIdentifier:SectionIdentifierMainSwitch];
 
   if ([self popupsCurrentlyBlocked] && _exceptions.GetSize()) {
     [self populateExceptionsItems];
   }
 }
 
 - (BOOL)shouldShowEditButton {
   return [self popupsCurrentlyBlocked];
@@ skipping 61 matching lines @@
 }
 
 - (void)collectionView:(UICollectionView*)collectionView
     didDeleteItemsAtIndexPaths:(NSArray*)indexPaths {
   // The only editable section is the block popups exceptions section.
   if ([self.collectionViewModel
           hasSectionForSectionIdentifier:SectionIdentifierExceptions]) {
     NSInteger exceptionsSectionIndex = [self.collectionViewModel
         sectionForSectionIdentifier:SectionIdentifierExceptions];
     if ([collectionView numberOfItemsInSection:exceptionsSectionIndex] == 0) {
-      base::WeakNSObject<BlockPopupsCollectionViewController> weakSelf(self);
+      __weak BlockPopupsCollectionViewController* weakSelf = self;
       [self.collectionView performBatchUpdates:^{
-        base::scoped_nsobject<BlockPopupsCollectionViewController> strongSelf(
-            [weakSelf retain]);
+        BlockPopupsCollectionViewController* strongSelf = weakSelf;
         if (!strongSelf) {
           return;
         }
-        NSInteger section = [strongSelf.get().collectionViewModel
+        NSInteger section = [strongSelf.collectionViewModel
             sectionForSectionIdentifier:SectionIdentifierExceptions];
-        [strongSelf.get().collectionViewModel
+        [strongSelf.collectionViewModel
             removeSectionWithIdentifier:SectionIdentifierExceptions];
-        [strongSelf.get().collectionView
+        [strongSelf.collectionView
             deleteSections:[NSIndexSet indexSetWithIndex:section]];
       }
                                     completion:nil];
     }
   }
 }
 
 #pragma mark MDCCollectionViewStylingDelegate
 
 - (BOOL)collectionView:(UICollectionView*)collectionView
     hidesInkViewAtIndexPath:(NSIndexPath*)indexPath {
   NSInteger type = [self.collectionViewModel itemTypeForIndexPath:indexPath];
   switch (type) {
     case ItemTypeMainSwitch:
       return YES;
     default:
       return NO;
   }
 }
 
 #pragma mark - BooleanObserver
 
 - (void)booleanDidChange:(id<ObservableBoolean>)observableBoolean {
-  DCHECK_EQ(observableBoolean, _disablePopupsSetting.get());
+  DCHECK_EQ(observableBoolean, _disablePopupsSetting);
 
   // Update the item.
-  _blockPopupsItem.get().on = [_disablePopupsSetting value];
+  _blockPopupsItem.on = [_disablePopupsSetting value];
 
   // Update the cell.
   [self reconfigureCellsForItems:@[ _blockPopupsItem ]
          inSectionWithIdentifier:SectionIdentifierMainSwitch];
 
   // Update the rest of the UI.
   [self.editor setEditing:NO];
   [self updateEditButton];
   [self layoutSections:[_disablePopupsSetting value]];
 }
 
 #pragma mark - Actions
 
 - (void)blockPopupsSwitchChanged:(UISwitch*)switchView {
   // Update the setting.
   [_disablePopupsSetting setValue:switchView.on];
 
   // Update the item.
-  _blockPopupsItem.get().on = [_disablePopupsSetting value];
+  _blockPopupsItem.on = [_disablePopupsSetting value];
 
   // Update the rest of the UI.
   [self.editor setEditing:NO];
   [self updateEditButton];
   [self layoutSections:switchView.on];
 }
 
 #pragma mark - Private
 
 - (BOOL)popupsCurrentlyBlocked {
@@ skipping 29 matching lines @@
       LOG(ERROR) << "Secondary content settings patterns are not "
                  << "supported by the content settings UI";
     }
   }
 }
 
 - (void)populateExceptionsItems {
   CollectionViewModel* model = self.collectionViewModel;
   [model addSectionWithIdentifier:SectionIdentifierExceptions];
 
-  CollectionViewTextItem* header = [
-      [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader] autorelease];
+  CollectionViewTextItem* header =
+      [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader];
   header.text = l10n_util::GetNSString(IDS_IOS_POPUPS_ALLOWED);
   header.textColor = [[MDCPalette greyPalette] tint500];
   [model setHeader:header forSectionWithIdentifier:SectionIdentifierExceptions];
 
   for (size_t i = 0; i < _exceptions.GetSize(); ++i) {
     std::string allowed_url;
     _exceptions.GetString(i, &allowed_url);
-    CollectionViewTextItem* item = [[[CollectionViewTextItem alloc]
-        initWithType:ItemTypeException] autorelease];
+    CollectionViewTextItem* item =
+        [[CollectionViewTextItem alloc] initWithType:ItemTypeException];
     item.text = base::SysUTF8ToNSString(allowed_url);
     [model addItem:item toSectionWithIdentifier:SectionIdentifierExceptions];
   }
 }
 
 - (void)layoutSections:(BOOL)blockPopupsIsOn {
   BOOL hasExceptions = _exceptions.GetSize();
   BOOL exceptionsListShown = [self.collectionViewModel
       hasSectionForSectionIdentifier:SectionIdentifierExceptions];
 
   if (blockPopupsIsOn && !exceptionsListShown && hasExceptions) {
     // Animate in the list of exceptions. Animation looks much better if the
     // section is added at once, rather than row-by-row as each object is added.
-    base::WeakNSObject<BlockPopupsCollectionViewController> weakSelf(self);
+    __weak BlockPopupsCollectionViewController* weakSelf = self;
     [self.collectionView performBatchUpdates:^{
-      base::scoped_nsobject<BlockPopupsCollectionViewController> strongSelf(
-          [weakSelf retain]);
+      BlockPopupsCollectionViewController* strongSelf = weakSelf;
       if (!strongSelf)
         return;
       [strongSelf populateExceptionsItems];
       NSUInteger index = [[strongSelf collectionViewModel]
           sectionForSectionIdentifier:SectionIdentifierExceptions];
       [[strongSelf collectionView]
           insertSections:[NSIndexSet indexSetWithIndex:index]];
     }
                                   completion:nil];
   } else if (!blockPopupsIsOn && exceptionsListShown) {
     // Make sure the exception section is not shown.
-    base::WeakNSObject<BlockPopupsCollectionViewController> weakSelf(self);
+    __weak BlockPopupsCollectionViewController* weakSelf = self;
     [self.collectionView performBatchUpdates:^{
-      base::scoped_nsobject<BlockPopupsCollectionViewController> strongSelf(
-          [weakSelf retain]);
+      BlockPopupsCollectionViewController* strongSelf = weakSelf;
       if (!strongSelf)
         return;
       NSUInteger index = [[strongSelf collectionViewModel]
           sectionForSectionIdentifier:SectionIdentifierExceptions];
       [[strongSelf collectionViewModel]
           removeSectionWithIdentifier:SectionIdentifierExceptions];
       [[strongSelf collectionView]
           deleteSections:[NSIndexSet indexSetWithIndex:index]];
     }
                                   completion:nil];
   }
 }
 
 @end