[ObjC ARC] Converts ios/chrome/browser/ui/settings:settings_arc to ARC.

ios/chrome/browser/ui/settings/autofill_collection_view_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/settings/autofill_collection_view_controller.h"
 
-#import "base/ios/weak_nsobject.h"
 #include "base/mac/foundation_util.h"
-#import "base/mac/objc_property_releaser.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/autofill/core/browser/personal_data_manager.h"
 #include "components/autofill/core/common/autofill_pref_names.h"
 #import "components/autofill/ios/browser/credit_card_util.h"
 #import "components/autofill/ios/browser/personal_data_manager_observer_bridge.h"
 #include "components/prefs/pref_service.h"
 #include "ios/chrome/browser/application_context.h"
 #include "ios/chrome/browser/autofill/personal_data_manager_factory.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #import "ios/chrome/browser/ui/collection_view/cells/MDCCollectionViewCell+Chrome.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_switch_item.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_text_item.h"
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/settings/autofill_credit_card_edit_collection_view_controller.h"
 #import "ios/chrome/browser/ui/settings/autofill_profile_edit_collection_view_controller.h"
 #import "ios/chrome/browser/ui/settings/cells/autofill_data_item.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Palettes/src/MaterialPalettes.h"
 #include "ui/base/l10n/l10n_util.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 typedef NS_ENUM(NSInteger, SectionIdentifier) {
   SectionIdentifierSwitches = kSectionIdentifierEnumZero,
   SectionIdentifierProfiles,
   SectionIdentifierCards,
 };
 
 typedef NS_ENUM(NSInteger, ItemType) {
   ItemTypeAutofillSwitch = kItemTypeEnumZero,
   ItemTypeWalletSwitch,
   ItemTypeAddress,
   ItemTypeCard,
   ItemTypeHeader,
 };
 
 }  // namespace
 
 #pragma mark - AutofillCollectionViewController
 
 @interface AutofillCollectionViewController ()<
     PersonalDataManagerObserverBridgeDelegate> {
   std::string _locale;  // User locale.
   autofill::PersonalDataManager* _personalDataManager;
-  base::mac::ObjCPropertyReleaser
-      _propertyReleaser_AutofillCollectionViewController;
+
   ios::ChromeBrowserState* _browserState;
   std::unique_ptr<autofill::PersonalDataManagerObserverBridge> _observer;
   BOOL _deletionInProgress;
 
   // Writing user-initiated switch state changes to the pref service results in
   // an observer callback, which handles general data updates with a reloadData.
   // It is better to handle user-initiated changes with more specific actions
   // such as inserting or removing items/sections. This boolean is used to
   // stop the observer callback from acting on user-initiated changes.
   BOOL _userInteractionInProgress;
@@ skipping 12 matching lines @@
     self.shouldHideDoneButton = YES;
     _browserState = browserState;
     _locale = GetApplicationContext()->GetApplicationLocale();
     _personalDataManager =
         autofill::PersonalDataManagerFactory::GetForBrowserState(_browserState);
     _observer.reset(new autofill::PersonalDataManagerObserverBridge(self));
     _personalDataManager->AddObserver(_observer.get());
 
     [self updateEditButton];
     [self loadModel];
-
-    _propertyReleaser_AutofillCollectionViewController.Init(
-        self, [AutofillCollectionViewController class]);
   }
   return self;
 }
 
 - (void)dealloc {
   _personalDataManager->RemoveObserver(_observer.get());
-  [super dealloc];
 }
 
 #pragma mark - CollectionViewController
 
 - (void)loadModel {
   [super loadModel];
   CollectionViewModel* model = self.collectionViewModel;
 
   [model addSectionWithIdentifier:SectionIdentifierSwitches];
   [model addItem:[self autofillSwitchItem]
@@ skipping 38 matching lines @@
         forSectionWithIdentifier:SectionIdentifierCards];
     for (autofill::CreditCard* creditCard : creditCards) {
       DCHECK(creditCard);
       [model addItem:[self itemForCreditCard:*creditCard]
           toSectionWithIdentifier:SectionIdentifierCards];
     }
   }
 }
 
 - (CollectionViewItem*)autofillSwitchItem {
-  CollectionViewSwitchItem* switchItem = [[[CollectionViewSwitchItem alloc]
-      initWithType:ItemTypeAutofillSwitch] autorelease];
+  CollectionViewSwitchItem* switchItem =
+      [[CollectionViewSwitchItem alloc] initWithType:ItemTypeAutofillSwitch];
   switchItem.text = l10n_util::GetNSString(IDS_IOS_AUTOFILL);
   switchItem.on = [self isAutofillEnabled];
   return switchItem;
 }
 
 - (CollectionViewItem*)walletSwitchItem {
-  CollectionViewSwitchItem* switchItem = [[[CollectionViewSwitchItem alloc]
-      initWithType:ItemTypeWalletSwitch] autorelease];
+  CollectionViewSwitchItem* switchItem =
+      [[CollectionViewSwitchItem alloc] initWithType:ItemTypeWalletSwitch];
   switchItem.text = l10n_util::GetNSString(IDS_IOS_AUTOFILL_USE_WALLET_DATA);
   switchItem.on = [self isWalletEnabled];
   return switchItem;
 }
 
 - (CollectionViewItem*)profileSectionHeader {
   CollectionViewTextItem* header = [self genericHeader];
   header.text = l10n_util::GetNSString(IDS_IOS_AUTOFILL_ADDRESSES_GROUP_NAME);
   return header;
 }
 
 - (CollectionViewItem*)cardSectionHeader {
   CollectionViewTextItem* header = [self genericHeader];
   header.text = l10n_util::GetNSString(IDS_IOS_AUTOFILL_CREDITCARDS_GROUP_NAME);
   return header;
 }
 
 - (CollectionViewTextItem*)genericHeader {
-  CollectionViewTextItem* header = [
-      [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader] autorelease];
+  CollectionViewTextItem* header =
+      [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader];
   header.textColor = [[MDCPalette greyPalette] tint500];
   return header;
 }
 
 - (CollectionViewItem*)itemForProfile:
     (const autofill::AutofillProfile&)autofillProfile {
   std::string guid(autofillProfile.guid());
   NSString* title = base::SysUTF16ToNSString(autofillProfile.GetInfo(
       autofill::AutofillType(autofill::NAME_FULL), _locale));
   NSString* subTitle = base::SysUTF16ToNSString(autofillProfile.GetInfo(
       autofill::AutofillType(autofill::ADDRESS_HOME_LINE1), _locale));
   bool isServerProfile = autofillProfile.record_type() ==
                          autofill::AutofillProfile::SERVER_PROFILE;
 
   AutofillDataItem* item =
-      [[[AutofillDataItem alloc] initWithType:ItemTypeAddress] autorelease];
+      [[AutofillDataItem alloc] initWithType:ItemTypeAddress];
   item.text = title;
   item.leadingDetailText = subTitle;
   item.accessoryType = MDCCollectionViewCellAccessoryDisclosureIndicator;
   item.accessibilityIdentifier = title;
   item.GUID = guid;
   item.deletable = !isServerProfile;
   if (isServerProfile) {
     item.trailingDetailText =
         l10n_util::GetNSString(IDS_IOS_AUTOFILL_WALLET_SERVER_NAME);
   }
   return item;
 }
 
 - (CollectionViewItem*)itemForCreditCard:
     (const autofill::CreditCard&)creditCard {
   std::string guid(creditCard.guid());
   NSString* creditCardName = autofill::GetCreditCardName(creditCard, _locale);
 
-  AutofillDataItem* item =
-      [[[AutofillDataItem alloc] initWithType:ItemTypeCard] autorelease];
+  AutofillDataItem* item = [[AutofillDataItem alloc] initWithType:ItemTypeCard];
   item.text = creditCardName;
   item.leadingDetailText = autofill::GetCreditCardObfuscatedNumber(creditCard);
   item.accessoryType = MDCCollectionViewCellAccessoryDisclosureIndicator;
   item.accessibilityIdentifier = creditCardName;
   item.deletable = autofill::IsCreditCardLocal(creditCard);
   item.GUID = guid;
   if (![item isDeletable]) {
     item.trailingDetailText =
         l10n_util::GetNSString(IDS_IOS_AUTOFILL_WALLET_SERVER_NAME);
   }
@@ skipping 44 matching lines @@
 #pragma mark - Switch Callbacks
 
 - (void)autofillSwitchChanged:(UISwitch*)switchView {
   [self setSwitchItemOn:[switchView isOn] itemType:ItemTypeAutofillSwitch];
   _userInteractionInProgress = YES;
   [self setAutofillEnabled:[switchView isOn]];
   _userInteractionInProgress = NO;
   [self updateEditButton];
 
   // Avoid reference cycle in block.
-  base::WeakNSObject<AutofillCollectionViewController> weakSelf(self);
+  __weak AutofillCollectionViewController* weakSelf = self;
   [self.collectionView performBatchUpdates:^{
     // Obtain strong reference again.
-    base::scoped_nsobject<AutofillCollectionViewController> strongSelf(
-        [weakSelf retain]);
+    AutofillCollectionViewController* strongSelf = weakSelf;
     if (!strongSelf) {
       return;
     }
 
     if ([switchView isOn]) {
       [strongSelf insertWalletSwitchItem];
       [strongSelf insertProfileAndCardSections];
     } else {
       [strongSelf removeWalletSwitchItem];
       [strongSelf removeProfileAndCardSections];
@@ skipping 71 matching lines @@
   }
   if ([self.collectionViewModel
           hasSectionForSectionIdentifier:SectionIdentifierCards]) {
     [self.collectionViewModel
         removeSectionWithIdentifier:SectionIdentifierCards];
   }
   [self.collectionView deleteSections:sections];
 }
 
 - (NSIndexSet*)indexSetForExistingProfileAndCardSections {
-  NSMutableIndexSet* sections = [[[NSMutableIndexSet alloc] init] autorelease];
+  NSMutableIndexSet* sections = [[NSMutableIndexSet alloc] init];
   if ([self.collectionViewModel
           hasSectionForSectionIdentifier:SectionIdentifierProfiles]) {
     [sections
         addIndex:[self.collectionViewModel
                      sectionForSectionIdentifier:SectionIdentifierProfiles]];
   }
   if ([self.collectionViewModel
           hasSectionForSectionIdentifier:SectionIdentifierCards]) {
     [sections addIndex:[self.collectionViewModel
                            sectionForSectionIdentifier:SectionIdentifierCards]];
@@ skipping 56 matching lines @@
   [super collectionView:collectionView didSelectItemAtIndexPath:indexPath];
 
   // Edit mode is the state where the user can select and delete entries. In
   // edit mode, selection is handled by the superclass. When not in edit mode
   // selection presents the editing controller for the selected entry.
   if ([self.editor isEditing]) {
     return;
   }
 
   CollectionViewModel* model = self.collectionViewModel;
-  base::scoped_nsobject<UIViewController> controller;
+  UIViewController* controller;
   switch ([model itemTypeForIndexPath:indexPath]) {
     case ItemTypeAddress: {
       const std::vector<autofill::AutofillProfile*> autofillProfiles =
           _personalDataManager->GetProfiles();
-      controller.reset([[AutofillProfileEditCollectionViewController
+      controller = [AutofillProfileEditCollectionViewController
           controllerWithProfile:*autofillProfiles[indexPath.item]
-            personalDataManager:_personalDataManager] retain]);
+            personalDataManager:_personalDataManager];
       break;
     }
     case ItemTypeCard: {
       const std::vector<autofill::CreditCard*>& creditCards =
           _personalDataManager->GetCreditCards();
-      controller.reset([[AutofillCreditCardEditCollectionViewController alloc]
+      controller = [[AutofillCreditCardEditCollectionViewController alloc]
            initWithCreditCard:*creditCards[indexPath.item]
-          personalDataManager:_personalDataManager]);
+          personalDataManager:_personalDataManager];
       break;
     }
     default:
       break;
   }
 
-  if (controller.get()) {
+  if (controller) {
     [self.navigationController pushViewController:controller animated:YES];
   }
 }
 
 #pragma mark - MDCCollectionViewEditingDelegate
 
 - (BOOL)collectionViewAllowsEditing:(UICollectionView*)collectionView {
   return YES;
 }
 
@@ skipping 39 matching lines @@
 - (void)removeSectionIfEmptyForSectionWithIdentifier:
     (SectionIdentifier)sectionIdentifier {
   if (![self.collectionViewModel
           hasSectionForSectionIdentifier:sectionIdentifier]) {
     return;
   }
   NSInteger section =
       [self.collectionViewModel sectionForSectionIdentifier:sectionIdentifier];
   if ([self.collectionView numberOfItemsInSection:section] == 0) {
     // Avoid reference cycle in block.
-    base::WeakNSObject<AutofillCollectionViewController> weakSelf(self);
+    __weak AutofillCollectionViewController* weakSelf = self;
     [self.collectionView performBatchUpdates:^{
       // Obtain strong reference again.
-      base::scoped_nsobject<AutofillCollectionViewController> strongSelf(
-          [weakSelf retain]);
+      AutofillCollectionViewController* strongSelf = weakSelf;
       if (!strongSelf) {
         return;
       }
 
       // Remove section from model and collectionView.
       [[strongSelf collectionViewModel]
           removeSectionWithIdentifier:sectionIdentifier];
       [[strongSelf collectionView]
           deleteSections:[NSIndexSet indexSetWithIndex:section]];
     }
         completion:^(BOOL finished) {
           // Obtain strong reference again.
-          base::scoped_nsobject<AutofillCollectionViewController> strongSelf(
-              [weakSelf retain]);
+          AutofillCollectionViewController* strongSelf = weakSelf;
           if (!strongSelf) {
             return;
           }
 
           // Turn off edit mode if there is nothing to edit.
           if (![strongSelf localProfilesOrCreditCardsExist]) {
             [[strongSelf editor] setEditing:NO];
           }
           [strongSelf updateEditButton];
-          strongSelf.get()->_deletionInProgress = NO;
+          strongSelf->_deletionInProgress = NO;
         }];
   }
 }
 
 #pragma mark PersonalDataManagerObserverBridgeDelegate
 
 - (void)onPersonalDataChanged {
   // If the change is due to local editing, or if local editing is happening
   // concurrently, updates are handled by collection view editing callbacks.
   // Data is reloaded at the end of deletion to make sure entries are in sync.
@@ skipping 30 matching lines @@
   return _browserState->GetPrefs()->GetBoolean(
       autofill::prefs::kAutofillWalletImportEnabled);
 }
 
 - (void)setWalletEnabled:(BOOL)isEnabled {
   _browserState->GetPrefs()->SetBoolean(
       autofill::prefs::kAutofillWalletImportEnabled, isEnabled);
 }
 
 @end