For building v8 using gn on aix_ppc64, linux_s390x and linux_ppc64.

build/config/BUILDCONFIG.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # =============================================================================
 # WHAT IS THIS FILE?
 # =============================================================================
 #
 # This is the master GN build configuration. This file is loaded after the
 # build args (args.gn) for the build directory and after the toplevel ".gn"
@@ skipping 51 matching lines @@
   }
 }
 
 if (current_cpu == "") {
   current_cpu = target_cpu
 }
 if (current_os == "") {
   current_os = target_os
 }
 
+# Checks whether we are running on a Power or z System.
+# This is used many times in multiple files and the four parts
+# of the clause almost always go together.
+# Creating a helper variable vastly improves readability.

[brettw, 2017/04/26 20:07:42]

I think this line:
"Creating a helper variable vastly improves readability."
can just be deleted, I think it's implicit in the above.

[rayb, 2017/04/27 19:29:45]

Done.

+is_power_or_z = current_cpu == "s390x" || current_cpu == "s390" ||

[brettw, 2017/04/26 20:07:42]

If we're going to keep this here, it should be called something like
"current_cpu_is_power_or_z" so it's clear that this applies to the current CPU.

[rayb, 2017/04/27 19:29:45]

Done.

+                current_cpu == "ppc64" || current_cpu == "ppc"
+
 # =============================================================================
 # BUILD FLAGS
 # =============================================================================
 #
 # This block lists input arguments to the build, along with their default
 # values.
 #
 # If a value is specified on the command line, it will overwrite the defaults
 # given in a declare_args block, otherwise the default will be used.
 #
@@ skipping 46 matching lines @@
   # release (!is_debug). This might be better expressed as a tri-state
   # (debug, release, official) but for historical reasons there are two
   # separate flags.
   is_official_build = false
 
   # Whether we're a traditional desktop unix.
   is_desktop_linux = current_os == "linux"
 
   # Set to true when compiling with the Clang compiler. Typically this is used
   # to configure warnings.
-  is_clang = current_os == "mac" || current_os == "ios" ||
-             current_os == "linux" || current_os == "chromeos"
+  is_clang =
+      current_os == "mac" || current_os == "ios" || current_os == "chromeos" ||
+      (current_os == "linux" && !is_power_or_z)
 
   # Allows the path to a custom target toolchain to be injected as a single
   # argument, and set as the default toolchain.
   custom_toolchain = ""
 
   # This should not normally be set as a build argument.  It's here so that
   # every toolchain can pass through the "global" value via toolchain_args().
   host_toolchain = ""
 
   # DON'T ADD MORE FLAGS HERE. Read the comment above.
@@ skipping 50 matching lines @@
   } else if (host_os == "mac") {
     host_toolchain = "//build/toolchain/mac:clang_$host_cpu"
   } else if (host_os == "win") {
     # On Windows always use the target CPU for host builds. On the
     # configurations we support this will always work and it saves build steps.
     if (is_clang) {
       host_toolchain = "//build/toolchain/win:clang_$target_cpu"
     } else {
       host_toolchain = "//build/toolchain/win:$target_cpu"
     }
+  } else if (host_os == "aix") {
+    host_toolchain = "//build/toolchain/aix:$host_cpu"
   } else {
     assert(false, "Unsupported host_os: $host_os")
   }
 }
 
 _default_toolchain = ""
 
 if (target_os == "android") {
   assert(host_os == "linux" || host_os == "mac",
          "Android builds are only supported on Linux and Mac hosts.")
@@ skipping 15 matching lines @@
   assert(host_os == "mac", "Mac cross-compiles are unsupported.")
   _default_toolchain = host_toolchain
 } else if (target_os == "win") {
   # On Windows we use the same toolchain for host and target by default.
   assert(target_os == host_os, "Win cross-compiles only work on win hosts.")
   if (is_clang) {
     _default_toolchain = "//build/toolchain/win:clang_$target_cpu"
   } else {
     _default_toolchain = "//build/toolchain/win:$target_cpu"
   }
+} else if (target_os == "aix") {
+  _default_toolchain = "//build/toolchain/aix:$target_cpu"
 } else if (target_os == "winrt_81" || target_os == "winrt_81_phone" ||
            target_os == "winrt_10") {
   _default_toolchain = "//build/toolchain/win:winrt_$target_cpu"
 } else {
   assert(false, "Unsupported target_os: $target_os")
 }
 
 # If a custom toolchain has been set in the args, set it as default. Otherwise,
 # set the default toolchain for the platform (if any).
 if (custom_toolchain != "") {
@@ skipping 80 matching lines @@
   is_win = false
 } else if (current_os == "linux") {
   is_android = false
   is_chromeos = false
   is_ios = false
   is_linux = true
   is_mac = false
   is_nacl = false
   is_posix = true
   is_win = false
+} else if (current_os == "aix") {
+  is_android = false
+  is_chromeos = false
+  is_ios = false
+  is_linux = false
+  is_mac = false
+  is_nacl = false
+  is_posix = true
+  is_win = false
 }
 
 # =============================================================================
 # SOURCES FILTERS
 # =============================================================================
 #
 # These patterns filter out platform-specific files when assigning to the
 # sources variable. The magic variable |sources_assignment_filter| is applied
 # to each assignment or appending to the sources variable and matches are
 # automatically removed.
 #
 # Note that the patterns are NOT regular expressions. Only "*" and "\b" (path
 # boundary = end of string or slash) are supported, and the entire string
 # must match the pattern (so you need "*.cc" to match all .cc files, for
 # example).
 
 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 # below.
 sources_assignment_filter = []
 if (!is_posix) {
   sources_assignment_filter += [
     "*_posix.h",
     "*_posix.cc",
     "*_posix_unittest.h",
     "*_posix_unittest.cc",
     "*\bposix/*",
   ]
 }
+
 if (!is_win) {
   sources_assignment_filter += [
     "*_win.cc",
     "*_win.h",
     "*_win_unittest.cc",
     "*\bwin/*",
     "*.def",
     "*.rc",
   ]
 }
@@ skipping 108 matching lines @@
     "//build/config/win:nominmax",
     "//build/config/win:unicode",
     "//build/config/win:winver",
     "//build/config/win:vs_code_analysis",
   ]
 }
 if (current_os == "winrt_81" || current_os == "winrt_81_phone" ||
     current_os == "winrt_10") {
   default_compiler_configs += [ "//build/config/win:target_winrt" ]
 }
+
 if (is_posix) {
-  default_compiler_configs += [
-    "//build/config/gcc:no_exceptions",
-    "//build/config/gcc:symbol_visibility_hidden",
-  ]
+  default_compiler_configs += [ "//build/config/gcc:no_exceptions" ]
+  if (current_os != "aix") {
+    default_compiler_configs +=
+        [ "//build/config/gcc:symbol_visibility_hidden" ]
+  }
 }
 
 if (is_android) {
   default_compiler_configs +=
       [ "//build/config/android:default_cygprofile_instrumentation" ]
 }
 
 if (is_clang && !is_nacl) {
   default_compiler_configs += [
     "//build/config/clang:find_bad_constructs",
@@ skipping 135 matching lines @@
 set_defaults("component") {
   if (is_component_build) {
     configs = default_shared_library_configs
     if (is_android) {
       configs -= [ "//build/config/android:hide_all_but_jni_onload" ]
     }
   } else {
     configs = default_compiler_configs
   }
 }