[ObjC ARC] Converts ios/chrome/browser/ui/settings:settings_arc_transition to ARC.

ios/chrome/browser/ui/settings/native_apps_collection_view_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/settings/native_apps_collection_view_controller.h"
 #import "ios/chrome/browser/ui/settings/native_apps_collection_view_controller_private.h"
 
 #import <StoreKit/StoreKit.h>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #import "base/mac/foundation_util.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/metrics/histogram_macros.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/threading/sequenced_worker_pool.h"
 #include "components/image_fetcher/ios/ios_image_data_fetcher_wrapper.h"
 #import "ios/chrome/browser/installation_notifier.h"
 #import "ios/chrome/browser/ui/collection_view/cells/MDCCollectionViewCell+Chrome.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_footer_item.h"
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/colors/MDCPalette+CrAdditions.h"
 #import "ios/chrome/browser/ui/settings/cells/native_app_item.h"
 #import "ios/chrome/browser/ui/settings/settings_utils.h"
 #import "ios/chrome/common/string_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/public/provider/chrome/browser/chrome_browser_provider.h"
 #import "ios/public/provider/chrome/browser/native_app_launcher/native_app_metadata.h"
 #import "ios/public/provider/chrome/browser/native_app_launcher/native_app_whitelist_manager.h"
 #import "ios/third_party/material_components_ios/src/components/Buttons/src/MaterialButtons.h"
 #include "ios/web/public/web_thread.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 const NSInteger kTagShift = 1000;
 
 namespace {
 
 typedef NS_ENUM(NSInteger, SectionIdentifier) {
   SectionIdentifierLearnMore = kSectionIdentifierEnumZero,
   SectionIdentifierApps,
 };
 
 typedef NS_ENUM(NSInteger, ItemType) {
   ItemTypeApp = kItemTypeEnumZero,
   ItemTypeLearnMore,
 };
 
 }  // namespace
 
 @interface NativeAppsCollectionViewController ()<
     SKStoreProductViewControllerDelegate> {
   std::unique_ptr<image_fetcher::IOSImageDataFetcherWrapper> _imageFetcher;
-  base::scoped_nsobject<NSArray> _nativeAppsInSettings;
+  NSArray* _nativeAppsInSettings;
   BOOL _userDidSomething;
 }
 
 // List of the native apps visible in Settings.
 @property(nonatomic, copy) NSArray* appsInSettings;
 
 // Delegate for App-Store-related operations.
-@property(nonatomic, assign) id<StoreKitLauncher> storeKitLauncher;
+@property(nonatomic, weak) id<StoreKitLauncher> storeKitLauncher;
 
 // Sets up the list of visible apps based on |nativeAppWhitelistManager|, which
 // serves as datasource for this controller. Apps from
 // |nativeAppWhitelistManager| are stored in |_nativeAppsInSettings| and
 // |-reloadData| is sent to the receiver.
 - (void)configureWithNativeAppWhiteListManager:
     (id<NativeAppWhitelistManager>)nativeAppWhitelistManager;
 
 // Returns a new Native App collection view item for the metadata at |index| in
 // |_nativeAppsInSettings|.
@@ skipping 34 matching lines @@
 
     [self loadModel];
   }
   return self;
 }
 
 - (void)dealloc {
   [[InstallationNotifier sharedInstance] unregisterForNotifications:self];
   if (!_userDidSomething)
     [self recordUserAction:settings::kNativeAppsActionDidNothing];
-  [super dealloc];
 }
 
 #pragma mark - View lifecycle
 
 - (void)viewDidLoad {
   self.title = l10n_util::GetNSString(IDS_IOS_GOOGLE_APPS_SM_SETTINGS);
   [self configureWithNativeAppWhiteListManager:
             ios::GetChromeBrowserProvider()->GetNativeAppWhitelistManager()];
 
   [super viewDidLoad];
@@ skipping 75 matching lines @@
                   forControlEvents:UIControlEventValueChanged];
   appCell.installButton.tag = [self tagForIndexPath:indexPath];
   [appCell.installButton addTarget:self
                             action:@selector(installApp:)
                   forControlEvents:UIControlEventTouchUpInside];
   CollectionViewItem* item =
       [self.collectionViewModel itemAtIndexPath:indexPath];
   NativeAppItem* appItem = base::mac::ObjCCastStrict<NativeAppItem>(item);
   if (!appItem.icon) {
     // Fetch the real icon.
-    base::WeakNSObject<NativeAppsCollectionViewController> weakSelf(self);
+    __weak NativeAppsCollectionViewController* weakSelf = self;
     id<NativeAppMetadata> metadata = [self nativeAppAtIndex:indexPath.item];
     [metadata fetchSmallIconWithImageFetcher:_imageFetcher.get()
                              completionBlock:^(UIImage* image) {
-                               base::scoped_nsobject<
-                                   NativeAppsCollectionViewController>
-                                   strongSelf([weakSelf retain]);
+
+                               NativeAppsCollectionViewController* strongSelf =
+                                   weakSelf;
                                if (!image || !strongSelf)
                                  return;
                                appItem.icon = image;
-                               [strongSelf.get().collectionView
+                               [strongSelf.collectionView
                                    reloadItemsAtIndexPaths:@[ indexPath ]];
                              }];
   }
 }
 
 - (CollectionViewItem*)learnMoreItem {
   NSString* learnMoreText =
       l10n_util::GetNSString(IDS_IOS_GOOGLE_APPS_SM_SECTION_HEADER);
-  CollectionViewFooterItem* learnMoreItem = [[[CollectionViewFooterItem alloc]
-      initWithType:ItemTypeLearnMore] autorelease];
+  CollectionViewFooterItem* learnMoreItem =
+      [[CollectionViewFooterItem alloc] initWithType:ItemTypeLearnMore];
   learnMoreItem.text = learnMoreText;
   return learnMoreItem;
 }
 
 #pragma mark - SKStoreProductViewControllerDelegate methods
 
 - (void)productViewControllerDidFinish:
     (SKStoreProductViewController*)viewController {
   [self dismissViewControllerAnimated:YES completion:nil];
 }
 
 #pragma mark - StoreKitLauncher methods
 
 - (void)openAppStore:(NSString*)appId {
   // Reported crashes show that -openAppStore: had been called with
   // a nil |appId|, but opening AppStore is meaningful only if the |appId| is
   // not nil, so be defensive and early return if |appId| is nil.
   if (![appId length])
     return;
   NSDictionary* product =
       @{SKStoreProductParameterITunesItemIdentifier : appId};
-  base::scoped_nsobject<SKStoreProductViewController> storeViewController(
-      [[SKStoreProductViewController alloc] init]);
+  SKStoreProductViewController* storeViewController =
+      [[SKStoreProductViewController alloc] init];
   [storeViewController setDelegate:self];
   [storeViewController loadProductWithParameters:product completionBlock:nil];
   [self presentViewController:storeViewController animated:YES completion:nil];
 }
 
 #pragma mark - MDCCollectionViewStylingDelegate
 
 // MDCCollectionViewStylingDelegate protocol is implemented so that cells don't
 // display ink on touch.
 - (BOOL)collectionView:(nonnull UICollectionView*)collectionView
@@ skipping 95 matching lines @@
 - (CollectionViewItem*)nativeAppItemAtIndex:(NSUInteger)index {
   id<NativeAppMetadata> metadata = [self nativeAppAtIndex:index];
   // Determine the state of the cell.
   NativeAppItemState state;
   if ([metadata isInstalled]) {
     state = [metadata shouldAutoOpenLinks] ? NativeAppItemSwitchOn
                                            : NativeAppItemSwitchOff;
   } else {
     state = NativeAppItemInstall;
   }
-  NativeAppItem* appItem =
-      [[[NativeAppItem alloc] initWithType:ItemTypeApp] autorelease];
+  NativeAppItem* appItem = [[NativeAppItem alloc] initWithType:ItemTypeApp];
   appItem.name = [metadata appName];
   appItem.state = state;
   return appItem;
 }
 
 - (NSArray*)appsInSettings {
-  return _nativeAppsInSettings.get();
+  return _nativeAppsInSettings;
 }
 
 - (void)setAppsInSettings:(NSArray*)apps {
-  _nativeAppsInSettings.reset([apps copy]);
+  _nativeAppsInSettings = [apps copy];
 }
 
 - (NSInteger)tagForIndexPath:(NSIndexPath*)indexPath {
   DCHECK(indexPath.section ==
          [self.collectionViewModel
              sectionForSectionIdentifier:SectionIdentifierApps]);
   return indexPath.item + kTagShift;
 }
 
 - (NSIndexPath*)indexPathForTag:(NSInteger)shiftedTag {
   NSInteger unshiftedTag = shiftedTag - kTagShift;
   return [NSIndexPath
       indexPathForItem:unshiftedTag
              inSection:[self.collectionViewModel
                            sectionForSectionIdentifier:SectionIdentifierApps]];
 }
 
 @end