[ObjC ARC] Converts ios/chrome/browser/ui/settings:settings_arc_transition to ARC.

ios/chrome/browser/ui/settings/contextual_search_collection_view_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/settings/contextual_search_collection_view_controller.h"
 
 #import "base/mac/foundation_util.h"
-#import "base/mac/scoped_nsobject.h"
 #include "components/google/core/browser/google_util.h"
 #include "components/strings/grit/components_strings.h"
 #include "ios/chrome/browser/application_context.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #import "ios/chrome/browser/ui/collection_view/cells/MDCCollectionViewCell+Chrome.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_footer_item.h"
 #import "ios/chrome/browser/ui/collection_view/cells/collection_view_switch_item.h"
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/contextual_search/touch_to_search_permissions_mediator.h"
 #import "ios/chrome/browser/ui/settings/settings_utils.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 typedef NS_ENUM(NSInteger, SectionIdentifier) {
   SectionIdentifierTouchToSearch = kSectionIdentifierEnumZero,
   SectionIdentifierFooter,
 };
 
 typedef NS_ENUM(NSUInteger, ItemType) {
   ItemTypeTouchToSearchSwitch = kItemTypeEnumZero,
   ItemTypeFooter,
 };
 
 }  // namespace
 
 @interface ContextualSearchCollectionViewController () {
   // Permissions interface for Touch-to-Search.
-  base::scoped_nsobject<TouchToSearchPermissionsMediator>
-      _touchToSearchPermissions;
+  TouchToSearchPermissionsMediator* _touchToSearchPermissions;
 }
 
 // Returns the switch item to use for the touch to search setting.
 - (CollectionViewSwitchItem*)touchToSearchSwitchItem;
 
 // Returns the item to use for the footer.
 - (CollectionViewFooterItem*)footerItem;
 
 // Called when the touch to search switch is toggled.
 - (void)switchToggled:(id)sender;
 
 @end
 
 @implementation ContextualSearchCollectionViewController
 
 #pragma mark - Initialization
 
 - (instancetype)initWithPermissions:
     (TouchToSearchPermissionsMediator*)touchToSearchPermissions {
   self = [super initWithStyle:CollectionViewControllerStyleAppBar];
   if (self) {
     self.title = l10n_util::GetNSString(IDS_IOS_CONTEXTUAL_SEARCH_TITLE);
-    _touchToSearchPermissions.reset([touchToSearchPermissions retain]);
+    _touchToSearchPermissions = touchToSearchPermissions;
     self.collectionViewAccessibilityIdentifier = @"Contextual Search";
     [self loadModel];
   }
   return self;
 }
 
 - (instancetype)initWithBrowserState:(ios::ChromeBrowserState*)browserState {
-  return [self
-      initWithPermissions:[[[TouchToSearchPermissionsMediator alloc]
-                              initWithBrowserState:browserState] autorelease]];
+  return [self initWithPermissions:[[TouchToSearchPermissionsMediator alloc]
+                                       initWithBrowserState:browserState]];
 }
 
 #pragma mark - SettingsRootCollectionViewController
 
 - (void)loadModel {
   [super loadModel];
   CollectionViewModel* model = self.collectionViewModel;
 
   [model addSectionWithIdentifier:SectionIdentifierTouchToSearch];
   [model addItem:[self touchToSearchSwitchItem]
       toSectionWithIdentifier:SectionIdentifierTouchToSearch];
 
   [model addSectionWithIdentifier:SectionIdentifierFooter];
   [model addItem:[self footerItem]
       toSectionWithIdentifier:SectionIdentifierFooter];
 }
 
 - (CollectionViewSwitchItem*)touchToSearchSwitchItem {
-  CollectionViewSwitchItem* item = [[[CollectionViewSwitchItem alloc]
-      initWithType:ItemTypeTouchToSearchSwitch] autorelease];
+  CollectionViewSwitchItem* item = [[CollectionViewSwitchItem alloc]
+      initWithType:ItemTypeTouchToSearchSwitch];
   item.text = l10n_util::GetNSString(IDS_IOS_CONTEXTUAL_SEARCH_TITLE);
   item.on =
       ([_touchToSearchPermissions preferenceState] != TouchToSearch::DISABLED);
   return item;
 }
 
 - (CollectionViewFooterItem*)footerItem {
   NSString* footerText =
       [NSString stringWithFormat:@"%@ BEGIN_LINK%@END_LINK",
                                  l10n_util::GetNSString(
                                      IDS_IOS_CONTEXTUAL_SEARCH_DESCRIPTION),
                                  l10n_util::GetNSString(IDS_LEARN_MORE)];
   GURL learnMoreURL = google_util::AppendGoogleLocaleParam(
       GURL(l10n_util::GetStringUTF8(IDS_IOS_CONTEXTUAL_SEARCH_LEARN_MORE_URL)),
       GetApplicationContext()->GetApplicationLocale());
 
-  CollectionViewFooterItem* item = [[[CollectionViewFooterItem alloc]
-      initWithType:ItemTypeFooter] autorelease];
+  CollectionViewFooterItem* item =
+      [[CollectionViewFooterItem alloc] initWithType:ItemTypeFooter];
   item.text = footerText;
   item.linkURL = learnMoreURL;
   item.linkDelegate = self;
   return item;
 }
 
 - (void)switchToggled:(id)sender {
   NSIndexPath* switchPath = [self.collectionViewModel
       indexPathForItemType:ItemTypeTouchToSearchSwitch
          sectionIdentifier:SectionIdentifierTouchToSearch];
@@ skipping 85 matching lines @@
   switch (type) {
     case ItemTypeFooter:
     case ItemTypeTouchToSearchSwitch:
       return YES;
     default:
       return NO;
   }
 }
 
 @end