[Mac] Support for Touch Bar Customization

chrome/browser/ui/cocoa/browser_window_touch_bar.mm

 // Copyright 2017 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/browser_window_touch_bar.h"
 
 #include <memory>
 
+#include "base/mac/foundation_util.h"
 #include "base/mac/mac_util.h"
 #import "base/mac/scoped_nsobject.h"
 #import "base/mac/sdk_forward_declarations.h"
 #include "base/metrics/histogram_macros.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/app/chrome_command_ids.h"
 #include "chrome/app/vector_icons/vector_icons.h"
 #include "chrome/browser/command_updater.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/search_engines/template_url_service_factory.h"
@@ skipping 27 matching lines @@
   STOP,
   RELOAD,
   HOME,
   SEARCH,
   STAR,
   NEW_TAB,
   TOUCH_BAR_ACTION_COUNT
 };
 
 // The touch bar's identifier.
-const NSTouchBarCustomizationIdentifier kBrowserWindowTouchBarId =
-    @"BrowserWindowTouchBarId";
+NSString* const kBrowserWindowTouchBarId = @"browser-window";
 
 // Touch bar items identifiers.
-const NSTouchBarItemIdentifier kBackForwardTouchId = @"BackForwardTouchId";
-const NSTouchBarItemIdentifier kReloadOrStopTouchId = @"ReloadOrStopTouchId";
-const NSTouchBarItemIdentifier kHomeTouchId = @"HomeTouchId";
-const NSTouchBarItemIdentifier kSearchTouchId = @"SearchTouchId";
-const NSTouchBarItemIdentifier kStarTouchId = @"StarTouchId";
-const NSTouchBarItemIdentifier kNewTabTouchId = @"NewTabTouchId";
+NSString* const kBackForwardTouchId = @"BACK-FWD";
+NSString* const kReloadOrStopTouchId = @"RELOAD-STOP";
+NSString* const kHomeTouchId = @"HOME";
+NSString* const kSearchTouchId = @"SEARCH";
+NSString* const kStarTouchId = @"BOOKMARK";
+NSString* const kNewTabTouchId = @"NEW-TAB";
 
 // The button indexes in the back and forward segment control.
 const int kBackSegmentIndex = 0;
 const int kForwardSegmentIndex = 1;
 
 // Touch bar icon colors values.
 const SkColor kTouchBarDefaultIconColor = SK_ColorWHITE;
 const SkColor kTouchBarStarActiveColor = gfx::kGoogleBlue500;
 
 // The size of the touch bar icons.
 const int kTouchBarIconSize = 16;
 
-// The width of the search button in the touch bar.
-const int kSearchBtnWidthWithHomeBtn = 205;
-const int kSearchBtnWidthWithoutHomeBtn = 280;
+// The min width of the search button in the touch bar.
+const int kSearchBtnMinWidth = 205;
 
 // Creates an NSImage from the given VectorIcon.
 NSImage* CreateNSImageFromIcon(const gfx::VectorIcon& icon,
                                SkColor color = kTouchBarDefaultIconColor) {
   return NSImageFromImageSkiaWithColorSpace(
       gfx::CreateVectorIcon(icon, kTouchBarIconSize, color),
       base::mac::GetSRGBColorSpace());
 }
 
 // Creates a NSButton for the touch bar.
 NSButton* CreateTouchBarButton(const gfx::VectorIcon& icon,
                                BrowserWindowTouchBar* owner,
                                int command,
                                int tooltip_id,
                                SkColor color = kTouchBarDefaultIconColor) {
   NSButton* button =
       [NSButton buttonWithImage:CreateNSImageFromIcon(icon, color)
                          target:owner
                          action:@selector(executeCommand:)];
   button.tag = command;
   [button setAccessibilityLabel:l10n_util::GetNSString(tooltip_id)];
   return button;
 }
 
+NSString* GetTouchBarId(NSString* const touch_bar_id) {
+  NSString* chrome_bundle_id =
+      base::SysUTF8ToNSString(base::mac::BaseBundleID());
+  return [NSString stringWithFormat:@"%@.%@", chrome_bundle_id, touch_bar_id];
+}
+
+NSString* GetTouchBarItemId(NSString* const touch_bar_id,
+                            NSString* const item_id) {
+  return [NSString
+      stringWithFormat:@"%@-%@", GetTouchBarId(touch_bar_id), item_id];
+}
+
 TouchBarAction TouchBarActionFromCommand(int command) {
   switch (command) {
     case IDC_BACK:
       return TouchBarAction::BACK;
     case IDC_FORWARD:
       return TouchBarAction::FORWARD;
     case IDC_STOP:
       return TouchBarAction::STOP;
     case IDC_RELOAD:
       return TouchBarAction::RELOAD;
@@ skipping 83 matching lines @@
 
   return self;
 }
 
 - (NSTouchBar*)makeTouchBar {
   if (!base::FeatureList::IsEnabled(features::kBrowserTouchBar))
     return nil;
 
   base::scoped_nsobject<NSTouchBar> touchBar(
       [[NSClassFromString(@"NSTouchBar") alloc] init]);
-  NSArray* touchBarItemIdentifiers;
-  if (showHomeButton_.GetValue()) {
-    touchBarItemIdentifiers = @[
-      kBackForwardTouchId, kReloadOrStopTouchId, kHomeTouchId, kSearchTouchId,
-      kStarTouchId, kNewTabTouchId
-    ];
-  } else {
-    touchBarItemIdentifiers = @[
-      kBackForwardTouchId, kReloadOrStopTouchId, kSearchTouchId, kStarTouchId,
-      kNewTabTouchId
-    ];
+  NSMutableArray* customIdentifiers = [NSMutableArray arrayWithCapacity:7];
+  NSMutableArray* defaultIdentifiers = [NSMutableArray arrayWithCapacity:6];
+
+  NSArray* touchBarItems = @[
+    kBackForwardTouchId, kReloadOrStopTouchId, kHomeTouchId, kSearchTouchId,
+    kStarTouchId, kNewTabTouchId
+  ];
+
+  for (NSString* item in touchBarItems) {
+    NSString* itemIdentifier =
+        GetTouchBarItemId(kBrowserWindowTouchBarId, item);
+    [customIdentifiers addObject:itemIdentifier];
+
+    // Don't add the home button if it's not shown in the toolbar.
+    if (showHomeButton_.GetValue() || ![item isEqualTo:kHomeTouchId])
+      [defaultIdentifiers addObject:itemIdentifier];
   }
 
-  [touchBar setCustomizationIdentifier:kBrowserWindowTouchBarId];
-  [touchBar setDefaultItemIdentifiers:touchBarItemIdentifiers];
-  [touchBar setCustomizationAllowedItemIdentifiers:touchBarItemIdentifiers];
+  [customIdentifiers addObject:NSTouchBarItemIdentifierFlexibleSpace];
+
+  [touchBar setCustomizationIdentifier:GetTouchBarId(kBrowserWindowTouchBarId)];
+  [touchBar setDefaultItemIdentifiers:defaultIdentifiers];
+  [touchBar setCustomizationAllowedItemIdentifiers:customIdentifiers];
   [touchBar setDelegate:self];
 
   return touchBar.autorelease();
 }
 
 - (NSTouchBarItem*)touchBar:(NSTouchBar*)touchBar
       makeItemForIdentifier:(NSTouchBarItemIdentifier)identifier {
   if (!touchBar)
     return nil;
 
   base::scoped_nsobject<NSCustomTouchBarItem> touchBarItem([[NSClassFromString(
       @"NSCustomTouchBarItem") alloc] initWithIdentifier:identifier]);
-  if ([identifier isEqualTo:kBackForwardTouchId]) {
+  if ([identifier hasSuffix:kBackForwardTouchId]) {
     [touchBarItem setView:[self backOrForwardTouchBarView]];
-  } else if ([identifier isEqualTo:kReloadOrStopTouchId]) {
+    [touchBarItem setCustomizationLabel:
+                      l10n_util::GetNSString(
+                          IDS_TOUCH_BAR_BACK_FORWARD_CUSTOMIZATION_LABEL)];
+  } else if ([identifier hasSuffix:kReloadOrStopTouchId]) {
     const gfx::VectorIcon& icon =
         isPageLoading_ ? kNavigateStopIcon : kNavigateReloadIcon;
     int commandId = isPageLoading_ ? IDC_STOP : IDC_RELOAD;
     int tooltipId = isPageLoading_ ? IDS_TOOLTIP_STOP : IDS_TOOLTIP_RELOAD;
     [touchBarItem
         setView:CreateTouchBarButton(icon, self, commandId, tooltipId)];
-  } else if ([identifier isEqualTo:kHomeTouchId]) {
+    [touchBarItem setCustomizationLabel:
+                      l10n_util::GetNSString(
+                          IDS_TOUCH_BAR_STOP_RELOAD_CUSTOMIZATION_LABEL)];
+  } else if ([identifier hasSuffix:kHomeTouchId]) {
     [touchBarItem setView:CreateTouchBarButton(kNavigateHomeIcon, self,
                                                IDC_HOME, IDS_TOOLTIP_HOME)];
-  } else if ([identifier isEqualTo:kNewTabTouchId]) {
+    [touchBarItem
+        setCustomizationLabel:l10n_util::GetNSString(
+                                  IDS_TOUCH_BAR_HOME_CUSTOMIZATION_LABEL)];
+  } else if ([identifier hasSuffix:kNewTabTouchId]) {
     [touchBarItem
         setView:CreateTouchBarButton(kNewTabMacTouchbarIcon, self, IDC_NEW_TAB,
                                      IDS_TOOLTIP_NEW_TAB)];
-  } else if ([identifier isEqualTo:kStarTouchId]) {
+    [touchBarItem
+        setCustomizationLabel:l10n_util::GetNSString(
+                                  IDS_TOUCH_BAR_NEW_TAB_CUSTOMIZATION_LABEL)];
+  } else if ([identifier hasSuffix:kStarTouchId]) {
     const gfx::VectorIcon& icon =
         isStarred_ ? toolbar::kStarActiveIcon : toolbar::kStarIcon;
     SkColor iconColor =
         isStarred_ ? kTouchBarStarActiveColor : kTouchBarDefaultIconColor;
     int tooltipId = isStarred_ ? IDS_TOOLTIP_STARRED : IDS_TOOLTIP_STAR;
     [touchBarItem setView:CreateTouchBarButton(icon, self, IDC_BOOKMARK_PAGE,
                                                tooltipId, iconColor)];
-  } else if ([identifier isEqualTo:kSearchTouchId]) {
+    [touchBarItem
+        setCustomizationLabel:l10n_util::GetNSString(
+                                  IDS_TOUCH_BAR_BOOKMARK_CUSTOMIZATION_LABEL)];
+  } else if ([identifier hasSuffix:kSearchTouchId]) {
     [touchBarItem setView:[self searchTouchBarView]];
+    [touchBarItem setCustomizationLabel:l10n_util::GetNSString(
+                                            IDS_TOUCH_BAR_GOOGLE_SEARCH)];
   }
 
   return touchBarItem.autorelease();
 }
 
 - (NSView*)backOrForwardTouchBarView {
   NSArray* images = @[
     CreateNSImageFromIcon(ui::kBackArrowIcon),
     CreateNSImageFromIcon(ui::kForwardArrowIcon)
   ];
@@ skipping 50 matching lines @@
     image = CreateNSImageFromIcon(ui::kSearchIcon);
   }
 
   NSButton* searchButton =
       [NSButton buttonWithTitle:base::SysUTF16ToNSString(title)
                           image:image
                          target:self
                          action:@selector(executeCommand:)];
   searchButton.imageHugsTitle = YES;
   searchButton.tag = IDC_FOCUS_LOCATION;
-  int width = showHomeButton_.GetValue() ? kSearchBtnWidthWithHomeBtn
-                                         : kSearchBtnWidthWithoutHomeBtn;
-  [searchButton.widthAnchor constraintEqualToConstant:width].active = YES;
+  [searchButton.widthAnchor
+      constraintGreaterThanOrEqualToConstant:kSearchBtnMinWidth]
+      .active = YES;
+  [searchButton
+      setContentHuggingPriority:1.0
+                 forOrientation:NSLayoutConstraintOrientationHorizontal];
   return searchButton;
 }
 
 - (void)backOrForward:(id)sender {
   NSSegmentedControl* control = sender;
   int command =
       [control selectedSegment] == kBackSegmentIndex ? IDC_BACK : IDC_FORWARD;
   LogTouchBarUMA(command);
   commandUpdater_->ExecuteCommand(command);
 }
 
 - (void)executeCommand:(id)sender {
   int command = [sender tag];
   LogTouchBarUMA(command);
   commandUpdater_->ExecuteCommand(command);
 }
 
 @end