[ObjC ARC] Converts ios/chrome/browser/ui/settings:settings to ARC.

ios/chrome/browser/ui/settings/save_passwords_collection_view_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/settings/save_passwords_collection_view_controller.h"
 
 #include <memory>
 #include <vector>
 
 #include "base/ios/ios_util.h"
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #include "base/mac/foundation_util.h"
-#import "base/mac/objc_property_releaser.h"
-#import "base/mac/scoped_nsobject.h"
+
 #include "base/memory/ptr_util.h"
 #include "base/numerics/safe_conversions.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/autofill/core/common/password_form.h"
 #include "components/google/core/browser/google_util.h"
 #include "components/keyed_service/core/service_access_type.h"
 #include "components/password_manager/core/browser/affiliation_utils.h"
 #include "components/password_manager/core/browser/password_manager_constants.h"
 #include "components/password_manager/core/browser/password_store.h"
@@ skipping 15 matching lines @@
 #import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
 #import "ios/chrome/browser/ui/settings/password_details_collection_view_controller.h"
 #import "ios/chrome/browser/ui/settings/reauthentication_module.h"
 #import "ios/chrome/browser/ui/settings/settings_utils.h"
 #import "ios/chrome/browser/ui/settings/utils/pref_backed_boolean.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Palettes/src/MaterialPalettes.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 typedef NS_ENUM(NSInteger, SectionIdentifier) {
   SectionIdentifierMessage = kSectionIdentifierEnumZero,
   SectionIdentifierSavePasswordsSwitch,
   SectionIdentifierSavedPasswords,
   SectionIdentifierBlacklist,
 };
 
 typedef NS_ENUM(NSInteger, ItemType) {
@@ skipping 63 matching lines @@
 @end
 @implementation BlacklistedFormContentItem
 @end
 
 @interface SavePasswordsCollectionViewController ()<
     BooleanObserver,
     PasswordDetailsCollectionViewControllerDelegate,
     SuccessfulReauthTimeAccessor> {
   // The observable boolean that binds to the password manager setting state.
   // Saved passwords are only on if the password manager is enabled.
-  base::scoped_nsobject<PrefBackedBoolean> passwordManagerEnabled_;
+  PrefBackedBoolean* passwordManagerEnabled_;
   // The item related to the switch for the password manager setting.
-  base::scoped_nsobject<CollectionViewSwitchItem> savePasswordsItem_;
+  CollectionViewSwitchItem* savePasswordsItem_;
   // The interface for getting and manipulating a user's saved passwords.
   scoped_refptr<password_manager::PasswordStore> passwordStore_;
   // A helper object for passing data about saved passwords from a finished
   // password store request to the SavePasswordsCollectionViewController.
   std::unique_ptr<password_manager::SavePasswordsConsumer>
       savedPasswordsConsumer_;
   // A helper object for passing data about blacklisted sites from a finished
   // password store request to the SavePasswordsCollectionViewController.
   std::unique_ptr<password_manager::SavePasswordsConsumer>
       blacklistPasswordsConsumer_;
   // The list of the user's saved passwords.
   std::vector<std::unique_ptr<autofill::PasswordForm>> savedForms_;
   // The list of the user's blacklisted sites.
   std::vector<std::unique_ptr<autofill::PasswordForm>> blacklistedForms_;
   // Deletion of password being asynchronous, and the method taking a reference
   // to the PasswordForm, the PasswordForm must outlive the calls to
   // RemoveLogin. This vector will ensure this.
   std::vector<std::unique_ptr<autofill::PasswordForm>> deletedForms_;
   // The current Chrome browser state.
   ios::ChromeBrowserState* browserState_;
   // Object storing the time of the previous successful re-authentication.
   // This is meant to be used by the |ReauthenticationModule| for keeping
   // re-authentications valid for a certain time interval within the scope
   // of the Save Passwords Settings.
-  base::scoped_nsobject<NSDate> successfulReauthTime_;
+  NSDate* successfulReauthTime_;
   // Module containing the reauthentication mechanism for viewing and copying
   // passwords.
-  base::scoped_nsobject<ReauthenticationModule> reauthenticationModule_;
-
-  base::mac::ObjCPropertyReleaser
-      propertyReleaser_SavePasswordsCollectionViewController_;
+  ReauthenticationModule* reauthenticationModule_;
 }
 // Kick off async request to get logins from password store.
 - (void)getLoginsFromPasswordStore;
 @end
 
 @implementation SavePasswordsCollectionViewController
 
 #pragma mark - Initialization
 
 - (instancetype)initWithBrowserState:(ios::ChromeBrowserState*)browserState {
   DCHECK(browserState);
   self = [super initWithStyle:CollectionViewControllerStyleAppBar];
   if (self) {
     browserState_ = browserState;
-    reauthenticationModule_.reset([[ReauthenticationModule alloc]
-        initWithSuccessfulReauthTimeAccessor:self]);
+    reauthenticationModule_ = [[ReauthenticationModule alloc]
+        initWithSuccessfulReauthTimeAccessor:self];
     self.title = l10n_util::GetNSString(IDS_IOS_SAVE_PASSWORDS);
     self.shouldHideDoneButton = YES;
     passwordStore_ = IOSChromePasswordStoreFactory::GetForBrowserState(
         browserState_, ServiceAccessType::EXPLICIT_ACCESS);
     DCHECK(passwordStore_);
-    passwordManagerEnabled_.reset([[PrefBackedBoolean alloc]
+    passwordManagerEnabled_ = [[PrefBackedBoolean alloc]
         initWithPrefService:browserState_->GetPrefs()
                    prefName:password_manager::prefs::
-                                kPasswordManagerSavingEnabled]);
+                                kPasswordManagerSavingEnabled];
     [passwordManagerEnabled_ setObserver:self];
     [self getLoginsFromPasswordStore];
     [self updateEditButton];
     [self loadModel];
-
-    propertyReleaser_SavePasswordsCollectionViewController_.Init(
-        self, [SavePasswordsCollectionViewController class]);
   }
   return self;
 }
 
 - (void)dealloc {
   [passwordManagerEnabled_ setObserver:nil];
-  [super dealloc];
 }
 
 #pragma mark - SettingsRootCollectionViewController
 
 - (void)loadModel {
   [super loadModel];
   CollectionViewModel* model = self.collectionViewModel;
 
   // Manage account message.
   CollectionViewItem* manageAccountLinkItem = [self manageAccountLinkItem];
   if (manageAccountLinkItem) {
     [model addSectionWithIdentifier:SectionIdentifierMessage];
     [model addItem:manageAccountLinkItem
         toSectionWithIdentifier:SectionIdentifierMessage];
   }
 
   // Save passwords switch.
   [model addSectionWithIdentifier:SectionIdentifierSavePasswordsSwitch];
-  savePasswordsItem_.reset([[self savePasswordsItem] retain]);
+  savePasswordsItem_ = [self savePasswordsItem];
   [model addItem:savePasswordsItem_
       toSectionWithIdentifier:SectionIdentifierSavePasswordsSwitch];
 
   // Saved passwords.
   if ([passwordManagerEnabled_ value]) {
     if (!savedForms_.empty()) {
       [model addSectionWithIdentifier:SectionIdentifierSavedPasswords];
-      CollectionViewTextItem* headerItem = [[[CollectionViewTextItem alloc]
-          initWithType:ItemTypeHeader] autorelease];
+      CollectionViewTextItem* headerItem =
+          [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader];
       headerItem.text =
           l10n_util::GetNSString(IDS_PASSWORD_MANAGER_SHOW_PASSWORDS_TAB_TITLE);
       headerItem.textColor = [[MDCPalette greyPalette] tint500];
       [model setHeader:headerItem
           forSectionWithIdentifier:SectionIdentifierSavedPasswords];
       for (const auto& form : savedForms_) {
         [model addItem:[self savedFormItemWithForm:form.get()]
             toSectionWithIdentifier:SectionIdentifierSavedPasswords];
       }
     }
     if (!blacklistedForms_.empty()) {
       [model addSectionWithIdentifier:SectionIdentifierBlacklist];
-      CollectionViewTextItem* headerItem = [[[CollectionViewTextItem alloc]
-          initWithType:ItemTypeHeader] autorelease];
+      CollectionViewTextItem* headerItem =
+          [[CollectionViewTextItem alloc] initWithType:ItemTypeHeader];
       headerItem.text =
           l10n_util::GetNSString(IDS_PASSWORD_MANAGER_EXCEPTIONS_TAB_TITLE);
       headerItem.textColor = [[MDCPalette greyPalette] tint500];
       [model setHeader:headerItem
           forSectionWithIdentifier:SectionIdentifierBlacklist];
       for (const auto& form : blacklistedForms_) {
         [model addItem:[self blacklistedFormItemWithForm:form.get()]
             toSectionWithIdentifier:SectionIdentifierBlacklist];
       }
     }
   }
 }
 
 #pragma mark - Items
 
 - (CollectionViewItem*)manageAccountLinkItem {
-  CollectionViewFooterItem* footerItem = [[[CollectionViewFooterItem alloc]
-      initWithType:ItemTypeManageAccount] autorelease];
+  CollectionViewFooterItem* footerItem =
+      [[CollectionViewFooterItem alloc] initWithType:ItemTypeManageAccount];
   footerItem.text =
       l10n_util::GetNSString(IDS_IOS_SAVE_PASSWORDS_MANAGE_ACCOUNT);
   footerItem.linkURL = google_util::AppendGoogleLocaleParam(
       GURL(password_manager::kPasswordManagerAccountDashboardURL),
       GetApplicationContext()->GetApplicationLocale());
   footerItem.linkDelegate = self;
   return footerItem;
 }
 
 - (CollectionViewSwitchItem*)savePasswordsItem {
   CollectionViewSwitchItem* savePasswordsItem =
-      [[[CollectionViewSwitchItem alloc]
-          initWithType:ItemTypeSavePasswordsSwitch] autorelease];
+      [[CollectionViewSwitchItem alloc]
+          initWithType:ItemTypeSavePasswordsSwitch];
   savePasswordsItem.text = l10n_util::GetNSString(IDS_IOS_SAVE_PASSWORDS);
   savePasswordsItem.on = [passwordManagerEnabled_ value];
   return savePasswordsItem;
 }
 
 - (SavedFormContentItem*)savedFormItemWithForm:(autofill::PasswordForm*)form {
-  SavedFormContentItem* passwordItem = [[[SavedFormContentItem alloc]
-      initWithType:ItemTypeSavedPassword] autorelease];
+  SavedFormContentItem* passwordItem =
+      [[SavedFormContentItem alloc] initWithType:ItemTypeSavedPassword];
   passwordItem.text =
       base::SysUTF8ToNSString(GetHumanReadableOriginCopy(*form));
   passwordItem.detailText = base::SysUTF16ToNSString(form->username_value);
   if (experimental_flags::IsViewCopyPasswordsEnabled()) {
     passwordItem.accessibilityTraits |= UIAccessibilityTraitButton;
     passwordItem.accessoryType =
         MDCCollectionViewCellAccessoryDisclosureIndicator;
   }
   return passwordItem;
 }
 
 - (BlacklistedFormContentItem*)blacklistedFormItemWithForm:
     (autofill::PasswordForm*)form {
   BlacklistedFormContentItem* passwordItem =
-      [[[BlacklistedFormContentItem alloc] initWithType:ItemTypeBlacklisted]
-          autorelease];
+      [[BlacklistedFormContentItem alloc] initWithType:ItemTypeBlacklisted];
   passwordItem.text =
       base::SysUTF8ToNSString(GetHumanReadableOriginCopy(*form));
   return passwordItem;
 }
 
 #pragma mark - MDCCollectionViewEditingDelegate
 
 - (BOOL)collectionViewAllowsEditing:(UICollectionView*)collectionView {
   return YES;
 }
@@ skipping 68 matching lines @@
     [switchCell.switchView addTarget:self
                               action:@selector(savePasswordsSwitchChanged:)
                     forControlEvents:UIControlEventValueChanged];
   }
   return cell;
 }
 
 #pragma mark - BooleanObserver
 
 - (void)booleanDidChange:(id<ObservableBoolean>)observableBoolean {
-  DCHECK_EQ(observableBoolean, passwordManagerEnabled_.get());
+  DCHECK_EQ(observableBoolean, passwordManagerEnabled_);
 
   // Update the item.
-  savePasswordsItem_.get().on = [passwordManagerEnabled_ value];
+  savePasswordsItem_.on = [passwordManagerEnabled_ value];
 
   // Update the cell.
   [self reconfigureCellsForItems:@[ savePasswordsItem_ ]
          inSectionWithIdentifier:SectionIdentifierSavePasswordsSwitch];
 
   // Update the rest of the UI.
   [self.editor setEditing:NO];
   [self updateEditButton];
   [self reloadData];
 }
 
 #pragma mark - Actions
 
 - (void)savePasswordsSwitchChanged:(UISwitch*)switchView {
   // Update the setting.
   [passwordManagerEnabled_ setValue:switchView.on];
 
   // Update the item.
-  savePasswordsItem_.get().on = [passwordManagerEnabled_ value];
+  savePasswordsItem_.on = [passwordManagerEnabled_ value];
 
   // Update the rest of the UI.
   [self.editor setEditing:NO];
   [self updateEditButton];
   [self reloadData];
 }
 
 #pragma mark - Private methods
 
 - (void)getLoginsFromPasswordStore {
@@ skipping 44 matching lines @@
   if ([model itemTypeForIndexPath:indexPath] == ItemTypeSavedPassword) {
     DCHECK_EQ([model sectionIdentifierForSection:indexPath.section],
               SectionIdentifierSavedPasswords);
     if (experimental_flags::IsViewCopyPasswordsEnabled()) {
       DCHECK_LT(base::checked_cast<size_t>(indexPath.item), savedForms_.size());
       autofill::PasswordForm* form = savedForms_[indexPath.item].get();
       NSString* username = base::SysUTF16ToNSString(form->username_value);
       NSString* password = base::SysUTF16ToNSString(form->password_value);
       NSString* origin =
           base::SysUTF8ToNSString(GetHumanReadableOriginCopy(*form));
-      base::scoped_nsobject<UIViewController> controller(
+      UIViewController* controller =
           [[PasswordDetailsCollectionViewController alloc]
                 initWithPasswordForm:*form
                             delegate:self
               reauthenticationModule:reauthenticationModule_
                             username:username
                             password:password
-                              origin:origin]);
+                              origin:origin];
       [self.navigationController pushViewController:controller animated:YES];
     }
   }
 }
 
 #pragma mark MDCCollectionViewEditingDelegate
 
 - (BOOL)collectionView:(UICollectionView*)collectionView
     canEditItemAtIndexPath:(NSIndexPath*)indexPath {
   // Only password cells are editable.
@@ skipping 46 matching lines @@
   NSMutableOrderedSet* sectionsToRemove = [NSMutableOrderedSet orderedSet];
   // Sort and enumerate in reverse order to delete the items from the collection
   // view model.
   NSArray* sortedIndexPaths =
       [indexPaths sortedArrayUsingSelector:@selector(compare:)];
   for (NSIndexPath* indexPath in [sortedIndexPaths reverseObjectEnumerator]) {
     if ([collectionView numberOfItemsInSection:indexPath.section] == 0) {
       [sectionsToRemove addObject:@(indexPath.section)];
     }
   }
-  base::WeakNSObject<SavePasswordsCollectionViewController> weakSelf(self);
+  __weak SavePasswordsCollectionViewController* weakSelf = self;
   [self.collectionView performBatchUpdates:^{
-    base::scoped_nsobject<SavePasswordsCollectionViewController> strongSelf(
-        [weakSelf retain]);
+    SavePasswordsCollectionViewController* strongSelf = weakSelf;
     if (!strongSelf)
       return;
     for (NSNumber* sectionNumber in sectionsToRemove) {
       NSInteger section = [sectionNumber integerValue];
       NSInteger sectionIdentifier = [[strongSelf collectionViewModel]
           sectionIdentifierForSection:section];
       [[strongSelf collectionViewModel]
           removeSectionWithIdentifier:sectionIdentifier];
       [[strongSelf collectionView]
           deleteSections:[NSIndexSet indexSetWithIndex:section]];
     }
   }
       completion:^(BOOL finished) {
-        base::scoped_nsobject<SavePasswordsCollectionViewController> strongSelf(
-            [weakSelf retain]);
+        SavePasswordsCollectionViewController* strongSelf = weakSelf;
         if (!strongSelf)
           return;
         if (![strongSelf editButtonEnabled]) {
           [strongSelf setEditing:NO];
         }
         [strongSelf updateEditButton];
       }];
 }
 
 #pragma mark PasswordDetailsCollectionViewControllerDelegate
 
 - (void)deletePassword:(const autofill::PasswordForm&)form {
   passwordStore_->RemoveLogin(form);
   for (auto it = savedForms_.begin(); it != savedForms_.end(); ++it) {
     if (**it == form) {
       savedForms_.erase(it);
       return;
     }
   }
   [self.navigationController popViewControllerAnimated:YES];
 }
 
 #pragma mark SuccessfulReauthTimeAccessor
 
 - (void)updateSuccessfulReauthTime {
-  successfulReauthTime_.reset([[NSDate alloc] init]);
+  successfulReauthTime_ = [[NSDate alloc] init];
 }
 
 - (NSDate*)lastSuccessfulReauthTime {
-  return successfulReauthTime_.get();
+  return successfulReauthTime_;
 }
 
 @end