[ios clean] Adds ToolsMenu to TabGrid

ios/clean/chrome/browser/ui/tab_grid/tab_grid_view_controller.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/clean/chrome/browser/ui/tab_grid/tab_grid_view_controller.h"
 
 #include "base/mac/foundation_util.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_overlay_view.h"
 #import "ios/clean/chrome/browser/ui/actions/settings_actions.h"
 #import "ios/clean/chrome/browser/ui/actions/tab_grid_actions.h"
 #import "ios/clean/chrome/browser/ui/commands/settings_commands.h"
 #import "ios/clean/chrome/browser/ui/commands/tab_grid_commands.h"
+#import "ios/clean/chrome/browser/ui/commands/tools_menu_commands.h"
 #import "ios/clean/chrome/browser/ui/tab_collection/tab_collection_data_source.h"
 #import "ios/clean/chrome/browser/ui/tab_collection/tab_collection_tab_cell.h"
 #import "ios/clean/chrome/browser/ui/tab_grid/mdc_floating_button+cr_tab_grid.h"
 #import "ios/clean/chrome/browser/ui/tab_grid/tab_grid_collection_view_layout.h"
 #import "ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
@@ skipping 60 matching lines @@
   self.tabs.contentInset =
       UIEdgeInsetsMake(CGRectGetMaxY(self.toolbar.frame), 0, 0, 0);
 }
 
 #pragma mark - SettingsActions
 
 - (void)showSettings:(id)sender {
   [self.dispatcher showSettings];
 }
 
+#pragma mark - ToolsMenuActions
+
+- (void)showToolsMenu:(id)sender {
+  [self.dispatcher showToolsMenu];
+}
+
 #pragma mark - TabGridActions
 
 - (void)showTabGrid:(id)sender {
   [self.dispatcher showTabGrid];
 }
 
 - (void)createNewTab:(id)sender {
   [self.dispatcher createAndShowNewTabInTabGrid];
 }
 
 #pragma mark - ZoomTransitionDelegate methods
 
 - (CGRect)rectForZoomWithKey:(NSObject*)key inView:(UIView*)view {
+  if (!key) {

[edchin, 2017/04/10 05:50:57]

This logic requires some comments. It's not intuitive.

[sczs, 2017/04/11 18:47:59]

Done.

+    if ([self.toolbar conformsToProtocol:@protocol(ZoomTransitionDelegate)]) {

[edchin, 2017/04/10 05:50:57]

Is it necessary to check conformance and reinterpret when we know for sure that
TabGridToolbar conforms?

[marq (ping after 24h), 2017/04/10 11:36:39]

It shouldn't be. 

[sczs, 2017/04/11 18:47:59]

Removed this check. 

+      return [reinterpret_cast<id<ZoomTransitionDelegate>>(self.toolbar)
+          rectForZoomWithKey:key
+                      inView:view];
+    }
+    return CGRectNull;
+  }
+
   NSIndexPath* cellPath = base::mac::ObjCCastStrict<NSIndexPath>(key);
-  if (!key)
-    return CGRectNull;
   UICollectionViewCell* cell = [self.tabs cellForItemAtIndexPath:cellPath];
   return [view convertRect:cell.bounds fromView:cell];
 }
 
+#pragma mark - MenuPresentationDelegate
+
+- (CGRect)frameForMenuPresentation:(UIPresentationController*)presentation {

[edchin, 2017/04/10 05:50:57]

If this code exists in multiple places, maybe we should have a utils method for
this code.

[sczs, 2017/04/11 18:47:59]

Definitely, I think thats out of the scope of this CL, but we should discuss on
how to create utils files/methods for different purposes.

+  CGSize menuSize = presentation.presentedView.frame.size;
+  CGRect menuRect;
+  menuRect.size = menuSize;
+
+  CGRect menuOriginRect = [self rectForZoomWithKey:nil inView:self.view];
+  if (CGRectIsNull(menuOriginRect)) {
+    menuRect.origin = CGPointMake(50, 50);

[edchin, 2017/04/10 05:50:57]

Magic numbers?

[sczs, 2017/04/11 18:47:59]

Agree, this is Mark original code. Once we move to a utils file we can get rid
of them.

+    return menuRect;
+  }
+  // Calculate which corner of the menu the origin rect is in. This is
+  // determined by comparing frames, and thus is RTL-independent.
+  if (CGRectGetMinX(menuOriginRect) - CGRectGetMinX(self.view.bounds) <
+      CGRectGetMaxX(self.view.bounds) - CGRectGetMaxX(menuOriginRect)) {
+    // Origin rect is closer to the left edge of |self.view| than to the right.
+    menuRect.origin.x = CGRectGetMinX(menuOriginRect);
+  } else {
+    // Origin rect is closer to the right edge of |self.view| than to the left.
+    menuRect.origin.x = CGRectGetMaxX(menuOriginRect) - menuSize.width;
+  }
+
+  if (CGRectGetMinY(menuOriginRect) - CGRectGetMinY(self.view.bounds) <
+      CGRectGetMaxY(self.view.bounds) - CGRectGetMaxY(menuOriginRect)) {
+    // Origin rect is closer to the top edge of |self.view| than to the bottom.
+    menuRect.origin.y = CGRectGetMinY(menuOriginRect);
+  } else {
+    // Origin rect is closer to the bottom edge of |self.view| than to the top.
+    menuRect.origin.y = CGRectGetMaxY(menuOriginRect) - menuSize.height;
+  }
+
+  return menuRect;
+}
+
 #pragma mark - TabGridConsumer methods
 
 - (void)addNoTabsOverlay {
   // PLACEHOLDER: The new tab grid will have a completely different zero tab
   // overlay from the tab switcher. Also, the overlay will be above the recent
   // tabs section.
   TabSwitcherPanelOverlayView* overlayView =
       [[TabSwitcherPanelOverlayView alloc] initWithFrame:self.tabs.bounds
                                             browserState:nil];
   overlayView.overlayType =
       TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_NO_OPEN_TABS;
   overlayView.autoresizingMask =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
   [self.tabs addSubview:overlayView];
   self.noTabsOverlay = overlayView;
 }
 
 - (void)removeNoTabsOverlay {
   [self.noTabsOverlay removeFromSuperview];
 }
 
 @end