[ObjC ARC] Converts ios/chrome/browser/ui/tab_switcher:tab_switcher to ARC.

ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_controller.h"
 
 #include "base/logging.h"
 #import "base/mac/foundation_util.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #import "ios/chrome/browser/tabs/tab.h"
 #include "ios/chrome/browser/ui/ntp/recent_tabs/synced_sessions.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_cache.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_cell.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_overlay_view.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_view.h"
 #include "ios/chrome/browser/ui/tab_switcher/tab_switcher_session_changes.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 void FillVectorWithHashesUsingDistantSession(
     synced_sessions::DistantSession const& session,
     std::vector<size_t>* hashes) {
   DCHECK(hashes);
   DCHECK(hashes->empty());
   for (size_t i = 0; i < session.tabs.size(); ++i) {
     hashes->push_back(session.tabs[i]->hashOfUserVisibleProperties());
   }
 }
 
 }  // namespace
 
 @interface TabSwitcherPanelController ()<UICollectionViewDataSource,
                                          UICollectionViewDelegate,
                                          SessionCellDelegate> {
   ios::ChromeBrowserState* _browserState;  // Weak.
-  base::scoped_nsobject<TabSwitcherPanelView> _panelView;
-  base::scoped_nsobject<TabSwitcherModel> _model;
+  TabSwitcherPanelView* _panelView;
+  TabSwitcherModel* _model;
   std::string _sessionTag;
   TabSwitcherSessionType _sessionType;
-  base::scoped_nsobject<TabSwitcherCache> _cache;
-  base::scoped_nsobject<TabSwitcherPanelOverlayView> _overlayView;
+  TabSwitcherCache* _cache;
+  TabSwitcherPanelOverlayView* _overlayView;
   std::unique_ptr<const synced_sessions::DistantSession> _distantSession;
   std::unique_ptr<const TabModelSnapshot> _localSession;
 }
 
 // Changes the visibility of the zero tab state overlay view.
 - (void)setZeroTabStateOverlayVisible:(BOOL)show;
 
 @end
 
 @implementation TabSwitcherPanelController
 
 @synthesize delegate = _delegate;
 @synthesize sessionType = _sessionType;
 
 - (instancetype)initWithModel:(TabSwitcherModel*)model
      forDistantSessionWithTag:(std::string const&)sessionTag
                  browserState:(ios::ChromeBrowserState*)browserState {
   self = [super init];
   if (self) {
     DCHECK(model);
     _sessionType = TabSwitcherSessionType::DISTANT_SESSION;
-    _model.reset([model retain]);
+    _model = model;
     _distantSession = [model distantSessionForTag:sessionTag];
     _sessionTag = sessionTag;
     _browserState = browserState;
     [self loadView];
   }
   return self;
 }
 
 - (instancetype)initWithModel:(TabSwitcherModel*)model
         forLocalSessionOfType:(TabSwitcherSessionType)sessionType
                     withCache:(TabSwitcherCache*)cache
                  browserState:(ios::ChromeBrowserState*)browserState {
   self = [super init];
   if (self) {
     DCHECK(model);
     _sessionType = sessionType;
-    _model.reset([model retain]);
+    _model = model;
     _localSession = [model tabModelSnapshotForLocalSession:sessionType];
-    _cache.reset([cache retain]);
+    _cache = cache;
     _browserState = browserState;
     [self loadView];
   }
   return self;
 }
 
 - (TabSwitcherPanelView*)view {
   return _panelView;
 }
 
@@ skipping 210 matching lines @@
   return _overlayView && [_overlayView alpha] != 0.0;
 }
 
 - (void)setZeroTabStateOverlayVisible:(BOOL)show {
   if (show == [self isOverlayVisible])
     return;
 
   DCHECK(TabSwitcherSessionTypeIsLocalSession(_sessionType));
 
   if (!_overlayView) {
-    _overlayView.reset([[TabSwitcherPanelOverlayView alloc]
-        initWithFrame:[_panelView bounds]
-         browserState:_browserState]);
+    _overlayView =
+        [[TabSwitcherPanelOverlayView alloc] initWithFrame:[_panelView bounds]
+                                              browserState:_browserState];
     [_overlayView
         setOverlayType:
             (_sessionType == TabSwitcherSessionType::OFF_THE_RECORD_SESSION)
                 ? TabSwitcherPanelOverlayType::
                       OVERLAY_PANEL_USER_NO_INCOGNITO_TABS
                 : TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_NO_OPEN_TABS];
 
     [_overlayView setAlpha:0];
     [_overlayView setAutoresizingMask:UIViewAutoresizingFlexibleHeight |
                                       UIViewAutoresizingFlexibleWidth];
     [_panelView addSubview:_overlayView];
     [_overlayView setNeedsLayout];
   }
 
   [UIView
       animateWithDuration:0.25
                animations:^{
                  [_overlayView setAlpha:show ? 1.0 : 0.0];
                  [self.delegate
                      tabSwitcherPanelControllerDidUpdateOverlayViewVisibility:
                          self];
                }];
 }
 
 - (void)loadView {
-  _panelView.reset(
-      [[TabSwitcherPanelView alloc] initWithSessionType:_sessionType]);
-  _panelView.get().collectionView.dataSource = self;
-  _panelView.get().collectionView.delegate = self;
+  _panelView = [[TabSwitcherPanelView alloc] initWithSessionType:_sessionType];
+  _panelView.collectionView.dataSource = self;
+  _panelView.collectionView.delegate = self;
 }
 
 - (synced_sessions::DistantSession const*)distantSession {
   return _distantSession.get();
 }
 
 @end