[ObjC ARC] Converts ios/chrome/browser/ui/tab_switcher:tab_switcher to ARC.

ios/chrome/browser/ui/tab_switcher/tab_switcher_header_view.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_header_view.h"
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/metrics/user_metrics_action.h"
 #import "ios/chrome/browser/ui/colors/MDCPalette+CrAdditions.h"
 #include "ios/chrome/browser/ui/rtl_geometry.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_header_cell.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_session_cell_data.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Palettes/src/MaterialPalettes.h"
 #include "ui/base/l10n/l10n_util.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 const CGFloat kCollectionViewTopMargin = 39.0;
 const CGFloat kCollectionViewHeight = 56.0;
 const CGFloat kDismissButtonWidth = 46.0;
 const CGFloat kDismissButtonHeight = 39.0;
 const CGFloat kCollectionViewCellWidth = 238;
 const CGFloat kActiveSpaceIndicatorHeight = 2;
 enum PanelSelectionChangeDirection { RIGHT, LEFT };
 }
 
 @protocol AccessiblePanelSelectorDelegate
 // Scrolls to the panel in the direction |direction|, if possible.
 - (void)moveToPanelInDirection:(PanelSelectionChangeDirection)direction;
 @end
 
 // An invisible view that offers VoiceOver control of the panel selection
 // UICollectionView.
 // Notes:
 // Directly subclassing UICollectionView resulted in a tons of unwanted
 // interactions with the cells.
 // Subclassing UIAccessibilityElement instead of UIView is not possible if
 // we want the accessibilityFrame to resize itself using autoresizing masks.
 @interface AccessiblePanelSelectorView : UIView {
   // The delegate which receives actions.
-  base::WeakNSProtocol<id<AccessiblePanelSelectorDelegate>> _delegate;
+  __weak id<AccessiblePanelSelectorDelegate> _delegate;
 }
 - (void)setDelegate:(id<AccessiblePanelSelectorDelegate>)delegate;
 @end
 
 @implementation AccessiblePanelSelectorView
 
 - (void)setDelegate:(id<AccessiblePanelSelectorDelegate>)delegate {
-  _delegate.reset(delegate);
+  _delegate = delegate;
 }
 
 - (UIAccessibilityTraits)accessibilityTraits {
   return [super accessibilityTraits] | UIAccessibilityTraitAdjustable |
          UIAccessibilityTraitCausesPageTurn;
 }
 
 - (BOOL)isAccessibilityElement {
   return YES;
 }
 
 - (void)accessibilityIncrement {
   [_delegate moveToPanelInDirection:RIGHT];
 }
 
 - (void)accessibilityDecrement {
   [_delegate moveToPanelInDirection:LEFT];
 }
 
 @end
 
 @interface TabSwitcherHeaderView ()<UICollectionViewDataSource,
                                     UICollectionViewDelegate,
                                     AccessiblePanelSelectorDelegate> {
-  base::scoped_nsobject<UICollectionViewFlowLayout> _flowLayout;
-  base::scoped_nsobject<UICollectionView> _collectionView;
-  base::scoped_nsobject<AccessiblePanelSelectorView> _accessibilityView;
-  base::scoped_nsobject<UIButton> _dismissButton;
-  base::scoped_nsobject<UIView> _activeSpaceIndicatorView;
+  UICollectionViewFlowLayout* _flowLayout;
+  UICollectionView* _collectionView;
+  AccessiblePanelSelectorView* _accessibilityView;
+  UIButton* _dismissButton;
+  UIView* _activeSpaceIndicatorView;
 
   BOOL _performingUpdate;
 }
 
 // Loads and initializes subviews.
 - (void)loadSubviews;
 // Performs layout of the collection view.
 - (void)layoutCollectionView;
 
 @end
@@ skipping 34 matching lines @@
 }
 
 - (void)performUpdate:(void (^)(TabSwitcherHeaderView* headerView))updateBlock {
   [self performUpdate:updateBlock completion:nil];
 }
 
 - (void)performUpdate:(void (^)(TabSwitcherHeaderView* headerView))updateBlock
            completion:(ProceduralBlock)completion {
   DCHECK(updateBlock);
 
-  __block TabSwitcherHeaderView* weakSelf = self;
+  __weak TabSwitcherHeaderView* weakSelf = self;
   [_collectionView performBatchUpdates:^{
-    if (!weakSelf)
+    TabSwitcherHeaderView* strongSelf = weakSelf;
+    if (!strongSelf)
       return;
-    weakSelf->_performingUpdate = YES;
-    updateBlock(weakSelf);
-    weakSelf->_performingUpdate = NO;
+    strongSelf->_performingUpdate = YES;
+    updateBlock(strongSelf);
+    strongSelf->_performingUpdate = NO;
   }
       completion:^(BOOL finished) {
         // Reestablish selection after the update.
         const NSInteger selectedPanelIndex =
             [[weakSelf delegate] tabSwitcherHeaderViewSelectedPanelIndex];
         if (selectedPanelIndex != NSNotFound)
           [weakSelf selectItemAtIndex:selectedPanelIndex];
         if (completion)
           completion();
       }];
 }
 
 - (void)insertSessionsAtIndexes:(NSArray*)indexes {
   DCHECK(_performingUpdate);
   [_collectionView
       insertItemsAtIndexPaths:[self indexPathArrayWithIndexes:indexes]];
 }
 
 - (void)removeSessionsAtIndexes:(NSArray*)indexes {
   DCHECK(_performingUpdate);
   [_collectionView
       deleteItemsAtIndexPaths:[self indexPathArrayWithIndexes:indexes]];
 }
 
 - (UIView*)dismissButton {
-  return _dismissButton.get();
+  return _dismissButton;
 }
 
 #pragma mark - Private
 
 - (NSInteger)selectedIndex {
   NSInteger selectedIndex = NSNotFound;
   NSArray* selectedIndexPaths = [_collectionView indexPathsForSelectedItems];
   if (selectedIndexPaths.count) {
     NSIndexPath* selectedIndexPath = selectedIndexPaths[0];
     selectedIndex = selectedIndexPath.item;
@@ skipping 16 matching lines @@
   const CGRect cellRect = CGRectMake(
       [self leftToRightIndexForFlowLayoutIndex:index] *
           kCollectionViewCellWidth,
       0, kCollectionViewCellWidth, [_collectionView bounds].size.height);
   [_collectionView scrollRectToVisible:cellRect animated:animated];
   [self layoutActiveSpaceIndicatorAnimated:animated];
 }
 
 - (NSArray*)indexPathArrayWithIndexes:(NSArray*)indexes {
   NSMutableArray* array =
-      [[[NSMutableArray alloc] initWithCapacity:indexes.count] autorelease];
+      [[NSMutableArray alloc] initWithCapacity:indexes.count];
   for (NSNumber* index in indexes) {
     [array
         addObject:[NSIndexPath indexPathForItem:[index intValue] inSection:0]];
   }
   return array;
 }
 
 - (void)loadSubviews {
-  base::scoped_nsobject<UICollectionViewFlowLayout> flowLayout(
-      [[UICollectionViewFlowLayout alloc] init]);
+  UICollectionViewFlowLayout* flowLayout =
+      [[UICollectionViewFlowLayout alloc] init];
   [flowLayout setMinimumLineSpacing:0];
   [flowLayout setMinimumInteritemSpacing:0];
   const CGSize cellSize =
       CGSizeMake(kCollectionViewCellWidth, kCollectionViewHeight);
   [flowLayout setItemSize:cellSize];
   [flowLayout setScrollDirection:UICollectionViewScrollDirectionHorizontal];
   _flowLayout = flowLayout;
 
-  _collectionView.reset([[UICollectionView alloc]
-             initWithFrame:[self collectionViewFrame]
-      collectionViewLayout:flowLayout]);
+  _collectionView =
+      [[UICollectionView alloc] initWithFrame:[self collectionViewFrame]
+                         collectionViewLayout:flowLayout];
   [_collectionView setDelegate:self];
   [_collectionView setDataSource:self];
   [_collectionView registerClass:[TabSwitcherHeaderCell class]
       forCellWithReuseIdentifier:[TabSwitcherHeaderCell identifier]];
   [_collectionView setShowsVerticalScrollIndicator:NO];
   [_collectionView setShowsHorizontalScrollIndicator:NO];
   [_collectionView setBackgroundColor:[[MDCPalette greyPalette] tint900]];
   [_collectionView setAllowsMultipleSelection:NO];
   [_collectionView setAllowsSelection:YES];
   [_collectionView setIsAccessibilityElement:NO];
   [_collectionView setAccessibilityElementsHidden:YES];
   [self addSubview:_collectionView];
 
-  _accessibilityView.reset([[AccessiblePanelSelectorView alloc]
-      initWithFrame:[self collectionViewFrame]]);
+  _accessibilityView = [[AccessiblePanelSelectorView alloc]
+      initWithFrame:[self collectionViewFrame]];
   [_accessibilityView
       setAutoresizingMask:UIViewAutoresizingFlexibleBottomMargin |
                           UIViewAutoresizingFlexibleWidth];
   [_accessibilityView setDelegate:self];
   [_accessibilityView setUserInteractionEnabled:NO];
   [self addSubview:_accessibilityView];
 
-  _dismissButton.reset([[UIButton alloc] initWithFrame:CGRectZero]);
+  _dismissButton = [[UIButton alloc] initWithFrame:CGRectZero];
   UIImage* dismissImage =
       [UIImage imageNamed:@"tabswitcher_tab_switcher_button"];
   dismissImage =
       [dismissImage imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
   [_dismissButton setContentMode:UIViewContentModeCenter];
   [_dismissButton setBackgroundColor:[UIColor clearColor]];
   [_dismissButton setTintColor:[UIColor whiteColor]];
   [_dismissButton setImage:dismissImage forState:UIControlStateNormal];
   [_dismissButton
       setAccessibilityLabel:l10n_util::GetNSString(
                                 IDS_IOS_TAB_STRIP_LEAVE_TAB_SWITCHER)];
 
   [_dismissButton addTarget:self
                      action:@selector(dismissButtonTouchUpInside:)
            forControlEvents:UIControlEventTouchUpInside];
   [_dismissButton setTranslatesAutoresizingMaskIntoConstraints:NO];
   [self addSubview:_dismissButton];
 
   NSArray* constraints = @[
     @"V:|-0-[dismissButton(==buttonHeight)]",
     @"H:[dismissButton(==buttonWidth)]-0-|",
   ];
   NSDictionary* viewsDictionary = @{
-    @"dismissButton" : _dismissButton.get(),
+    @"dismissButton" : _dismissButton,
   };
   NSDictionary* metrics = @{
     @"buttonHeight" : @(kDismissButtonHeight),
     @"buttonWidth" : @(kDismissButtonWidth),
   };
   ApplyVisualConstraintsWithMetricsAndOptions(
       constraints, viewsDictionary, metrics, LayoutOptionForRTLSupport(), self);
 
-  base::scoped_nsobject<UIView> activeSpaceIndicatorView(
-      [[UIView alloc] initWithFrame:CGRectZero]);
+  UIView* activeSpaceIndicatorView = [[UIView alloc] initWithFrame:CGRectZero];
   [activeSpaceIndicatorView
       setBackgroundColor:[[MDCPalette cr_bluePalette] tint500]];
   [activeSpaceIndicatorView
       setFrame:CGRectMake(
                    0, self.bounds.size.height - kActiveSpaceIndicatorHeight,
                    kCollectionViewCellWidth, kActiveSpaceIndicatorHeight)];
   [self addSubview:activeSpaceIndicatorView];
   _activeSpaceIndicatorView = activeSpaceIndicatorView;
 }
 
@@ skipping 93 matching lines @@
   [[self delegate] tabSwitcherHeaderViewDidSelectSessionAtIndex:indexPath.item];
 }
 
 #pragma mark - UIScrollViewDelegate
 
 - (void)scrollViewDidScroll:(UIScrollView*)scrollView {
   [self layoutActiveSpaceIndicatorAnimated:NO];
 }
 
 @end