[Cronet] Build static libcronet.a for iOS with complete dependencies.

components/cronet/ios/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/ios/rules.gni")
 import("//build/config/mac/symbols.gni")
 import("//build/mac/tweak_info_plist.gni")
 import("//build/util/process_version.gni")
 import("//build/util/version.gni")
@@ skipping 55 matching lines @@
   if (!use_platform_icu_alternatives) {
     deps += [ "//base:i18n" ]
   }
 }
 
 # Tweak |info_plist| with current version and revision.
 tweak_info_plist("tweak_cronet_plist") {
   info_plist = "Info.plist"
 }
 
+_deps = [
+  ":cronet_version_header",
+  ":generate_accept_languages",
+  "//base:base",
+  "//components/grpc_support",
+  "//components/metrics:metrics",
+  "//components/metrics/proto:proto",
+  "//components/prefs:prefs",
+  "//ios/net:net",
+  "//ios/web:user_agent",
+  "//net",
+  "//url",
+]
+
+static_library("cronet_static") {
+  deps = _deps
+
+  visibility = [ ":*" ]
+
+  include_dirs = [ "//components/grpc_support/include" ]
+
+  public_deps = [
+    "//components/grpc_support",
+  ]
+
+  public_headers = [
+    "Cronet.h",
+    "cronet_c_for_grpc.h",
+  ]
+  public_headers += grpc_public_headers
+
+  sources = [
+    "../histogram_manager.cc",
+    "../histogram_manager.h",
+    "../stale_host_resolver.cc",
+    "../stale_host_resolver.h",
+    "../url_request_context_config.cc",
+    "../url_request_context_config.h",
+    "Cronet.h",
+    "Cronet.mm",
+    "cronet_c_for_grpc.h",
+    "cronet_environment.h",
+    "cronet_environment.mm",
+  ]
+}
+
 ios_framework_bundle("cronet_framework") {
   output_name = "Cronet"
   info_plist_target = ":tweak_cronet_plist"
 
   deps = [
     ":cronet_sources",
     "//base",
     "//net:net",
   ]
 
@@ skipping 44 matching lines @@
   script = "//components/cronet/tools/generate_accept_languages.py"
   args = [
     rebase_path("$target_gen_dir"),
     rebase_path("//"),
   ]
   outputs = [
     "$target_gen_dir/accept_languages_table.h",
   ]
 }
 
+# A static library which contains all dependencies of :cronet_static.
+static_library("deps_complete") {

[kapishnikov, 2017/05/17 16:02:49]

Should we add "cronet_" prefix in front of the name? Even though the target is
private, I think it can be invoked from the command line.

[mef, 2017/05/19 18:07:58]

Done.

+  visibility = [ ":*" ]
+  complete_static_lib = true
+  deps = _deps

[kapishnikov, 2017/05/17 16:02:48]

Why don't we add "cronet_static" as the dependency?

+}
+
+config("cronet_config") {
+  libs = [
+    "$target_out_dir/libcronet.a",
+    "UIKit.Framework",
+    "CFNetwork.framework",
+    "MobileCoreServices.framework",
+    "Security.framework",
+    "SystemConfiguration.framework",
+    "resolv",
+  ]
+}
+
+action("lib_cronet") {

[kapishnikov, 2017/05/17 16:02:49]

Is it possible to build a static iOS framework and expose it to the public
instead of the stand-alone static library?

[mef, 2017/05/19 18:07:58]

Yes, we should be able to do that. Next patch maybe?

+  script = "//components/cronet/tools/hide_symbols.py"
+  deps = [
+    ":cronet_static",
+    ":deps_complete",
+  ]
+  outputs = [
+    "$target_out_dir/libcronet.a",
+    "$target_out_dir/libcronet.o",
+  ]
+  args = [
+    "--input_libs",
+    rebase_path("$target_out_dir/libcronet_static.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libdeps_complete.a", root_build_dir),
+    "--output_obj",
+    rebase_path("$target_out_dir/libcronet.o", root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/libcronet.a", root_build_dir),
+    "--current_cpu",
+    current_cpu,
+  ]
+
+  public_configs = [ ":cronet_config" ]
+}
+
 if (additional_toolchains == [] || current_toolchain == default_toolchain) {
   _package_dir = "$root_out_dir/cronet"
 
   action("generate_license") {
     _license_path = "$_package_dir/LICENSE"
 
     script = "//components/cronet/tools/cronet_licenses.py"
     inputs = [
       "//build/util/LASTCHANGE",
       "//buildtools/$host_os/gn",
     ]
     outputs = [
       _license_path,
     ]
     args = [
       "license",
       rebase_path(_license_path, root_build_dir),
       "--gn",
       "--gn-path",
       rebase_path("//buildtools/$host_os/gn", root_build_dir),
     ]
   }
 
   copy("cronet_package_copy") {
     sources = [
       "$root_out_dir/Cronet.framework",
+      "$target_out_dir/libcronet.a",
       "//AUTHORS",
       "//chrome/VERSION",
     ]
     outputs = [
       "$_package_dir/{{source_file_part}}",
     ]
 
     deps = [
       ":cronet_framework",
+      ":lib_cronet",
     ]
   }
 
   if (enable_dsyms) {
     action("cronet_dsym_archive") {
       script = "//chrome/tools/build/mac/archive_symbols.py"
 
       # These are the dSYMs that will be archived. The sources list must be
       # the target outputs that correspond to the dSYMs (since a dSYM is a
       # directory it cannot be listed as a source file). The targets that
@@ skipping 19 matching lines @@
     }
   } else {
     group("cronet_dsym_archive") {
     }
   }
 
   group("cronet_package") {
     deps = [
       ":cronet_dsym_archive",
       ":cronet_package_copy",
       ":generate_license",

[kapishnikov, 2017/05/17 16:02:48]

Should the sample be part of the package? At least, we can use this target to
compile it.

     ]
   }
 }