[Cronet] Build static libcronet.a for iOS with complete dependencies.

components/cronet/ios/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/ios/rules.gni")
 import("//build/config/mac/symbols.gni")
 import("//build/mac/tweak_info_plist.gni")
 import("//build/util/process_version.gni")
 import("//build/util/version.gni")
@@ skipping 14 matching lines @@
   sources = [
     "//chrome/VERSION",
   ]
   output = "$target_gen_dir/version.h"
   extra_args = [
     "-e",
     "VERSION_FULL=\"%s.%s.%s.%s\" % (MAJOR,MINOR,BUILD,PATCH)",
   ]
 }
 
+config("cronet_include_config") {
+  include_dirs = [ "//components/grpc_support/include" ]
+}
+
+config("cronet_static_config") {
+  libs = [
+    "Cronet.framework",
+    "UIKit.Framework",
+    "CFNetwork.framework",
+    "MobileCoreServices.framework",
+    "Security.framework",
+    "SystemConfiguration.framework",
+    "resolv",
+  ]
+  configs = [ ":cronet_include_config" ]
+}
+
+_cronet_deps = [
+  ":cronet_version_header",
+  ":generate_accept_languages",
+  "//base:base",
+  "//components/grpc_support",
+  "//components/metrics:metrics",
+  "//components/metrics/proto:proto",
+  "//components/prefs:prefs",
+  "//ios/net:net",
+  "//ios/web:user_agent",
+  "//net",
+  "//url",
+]
+
+_cronet_sources = [
+  "../histogram_manager.cc",
+  "../histogram_manager.h",
+  "../stale_host_resolver.cc",
+  "../stale_host_resolver.h",
+  "../url_request_context_config.cc",
+  "../url_request_context_config.h",
+  "Cronet.h",
+  "Cronet.mm",
+  "cronet_c_for_grpc.h",
+  "cronet_environment.h",
+  "cronet_environment.mm",
+]
+
+_cronet_public_headers = [
+  "Cronet.h",
+  "cronet_c_for_grpc.h",
+]
+_cronet_public_headers += grpc_public_headers
+
 source_set("cronet_sources") {
-  deps = [
-    ":cronet_version_header",
-    ":generate_accept_languages",
-    "//base:base",
-    "//components/grpc_support",
-    "//components/metrics:metrics",
-    "//components/metrics/proto:proto",
-    "//components/prefs:prefs",
-    "//ios/net:net",
-    "//ios/web:user_agent",
-    "//net",
-    "//url",
-  ]
+  deps = _cronet_deps
 
-  sources = [
-    "../histogram_manager.cc",
-    "../histogram_manager.h",
-    "../stale_host_resolver.cc",
-    "../stale_host_resolver.h",
-    "../url_request_context_config.cc",
-    "../url_request_context_config.h",
-    "Cronet.h",
-    "Cronet.mm",
-    "cronet_c_for_grpc.h",
-    "cronet_environment.h",
-    "cronet_environment.mm",
-  ]
+  sources = _cronet_sources
 
   include_dirs = [ "//components/grpc_support/include" ]
 
   if (!use_platform_icu_alternatives) {
     deps += [ "//base:i18n" ]
   }
 }
 
 # Tweak |info_plist| with current version and revision.
 tweak_info_plist("tweak_cronet_plist") {
   info_plist = "Info.plist"
 }
 
 ios_framework_bundle("cronet_framework") {
   output_name = "Cronet"
   info_plist_target = ":tweak_cronet_plist"
 
   deps = [
     ":cronet_sources",
     "//base",
     "//net:net",
   ]
 
   libs = [ "UIKit.Framework" ]
 
-  include_dirs = [ "//components/grpc_support/include" ]
-
   public_deps = [
     "//components/grpc_support",
   ]
 
-  public_headers = [
-    "Cronet.h",
-    "cronet_c_for_grpc.h",
-  ]
-  public_headers += grpc_public_headers
+  public_headers = _cronet_public_headers
 
   sources = [
     "Cronet.h",
   ]
 
   configs -= [ "//build/config/compiler:default_symbols" ]
   configs += [ "//build/config/compiler:symbols" ]
+
+  public_configs = [ ":cronet_include_config" ]
 }
 
 test("cronet_unittests") {
   testonly = true
 
   sources = [
     "//components/cronet/histogram_manager_unittest.cc",
     "//components/cronet/run_all_unittests.cc",
     "//components/cronet/stale_host_resolver_unittest.cc",
     "//components/cronet/url_request_context_config_unittest.cc",
@@ skipping 14 matching lines @@
   script = "//components/cronet/tools/generate_accept_languages.py"
   args = [
     rebase_path("$target_gen_dir"),
     rebase_path("//"),
   ]
   outputs = [
     "$target_gen_dir/accept_languages_table.h",
   ]
 }
 
+# A static library which contains just _cronet_sources.
+static_library("cronet_static") {
+  visibility = [ ":*" ]
+  deps = _cronet_deps
+  sources = _cronet_sources
+  public_configs = [ ":cronet_include_config" ]
+  public_deps = [
+    "//components/grpc_support",
+  ]
+}
+
+# A static library which contains all dependencies of :cronet_static.
+static_library("cronet_deps_complete") {
+  visibility = [ ":*" ]
+  complete_static_lib = true
+  deps = [
+    ":cronet_static",
+  ]
+}
+
+# A static library which contains cronet and all dependendencies hidden inside.
+action("cronet_static_complete") {
+  visibility = [ ":*" ]
+  script = "//components/cronet/tools/hide_symbols.py"
+  deps = [
+    ":cronet_deps_complete",
+    ":cronet_static",
+  ]
+  outputs = [
+    "$target_out_dir/$current_cpu/cronet_static_complete.a",
+  ]
+  args = [
+    "--input_libs",
+    rebase_path("$target_out_dir/libcronet_static.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libcronet_deps_complete.a", root_build_dir),

[mef, 2017/06/02 16:26:17]

The x86 debug size of libcronet_deps_complete.a is over 700mb and it causes
problems with ld, so we use ar to build cronet_static_complete.a without hiding
symbols for this configuration. This causes problems later on, when static
Cronet.framework becomes too big to get into internal source repository.

Is there a good way to strip some of the debug info prior to ld?

+    "--output_obj",
+    rebase_path("$target_out_dir/$current_cpu/cronet_static_complete.o",
+                root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/$current_cpu/cronet_static_complete.a",
+                root_build_dir),
+    "--current_cpu",
+    current_cpu,
+  ]
+
+  public_configs = [ ":cronet_static_config" ]
+}
+
+# A fat static library which exports cronet public symbols and hides all dependendencies.
+lipo_binary("libcronet") {
+  arch_binary_target = ":cronet_static_complete"
+  arch_binary_output = "cronet_static_complete.a"
+  output_name = "libcronet.a"
+  enable_stripping = false
+  enable_dsyms = false
+}
+
+template("ios_static_framework") {
+  _target_name = target_name
+  _output_name = target_name
+  if (defined(invoker.output_name)) {
+    _output_name = invoker.output_name
+  }
+  _framework_name = target_name
+  if (defined(invoker.framework_name)) {
+    _framework_name = invoker.framework_name
+  }
+
+  _bundle_target_name = _target_name + "_bundle"
+  _framework_headers_target = _target_name + "_framework_headers"
+  bundle_data(_framework_headers_target) {
+    visibility = [ ":$_bundle_target_name" ]
+    sources = invoker.public_headers
+    outputs = [
+      "{{bundle_root_dir}}/Headers/{{source_file_part}}",
+    ]
+  }
+
+  _framework_binary_target = _target_name + "_framework_binary"
+  _static_library_target = invoker.static_library_target
+
+  bundle_data(_framework_binary_target) {
+    visibility = [ ":$_bundle_target_name" ]
+    sources = get_target_outputs(_static_library_target)
+    outputs = [
+      "{{bundle_root_dir}}/$_framework_name",
+    ]
+    public_deps = [
+      _static_library_target,
+    ]
+  }
+
+  create_bundle(_bundle_target_name) {
+    product_type = "com.apple.product-type.framework"
+    bundle_root_dir = "$root_out_dir/Static/$_output_name"
+    bundle_executable_dir = bundle_root_dir
+    bundle_resources_dir = bundle_root_dir
+    bundle_plugins_dir = bundle_root_dir
+    deps = [
+      ":$_framework_binary_target",
+      ":$_framework_headers_target",
+    ]
+  }
+
+  action(_target_name) {
+    script = "//components/cronet/tools/dummy.py"

[mef, 2017/06/02 16:26:17]

This dummy action is used to put output of |cronet_static_framework| target into
"$root_out_dir/Static/Cronet.framework" instead of
$root_out_dir/CronetStatic.framework".

Without it GN has complained that 'Cronet.framework' is being generated by 2
targets - cronet_framework and cronet_static_framework. 

Is there a better solution? 

+    outputs = [
+      "$root_out_dir/Static/$_output_name",
+    ]
+    deps = [
+      ":$_bundle_target_name",
+    ]
+    public_configs = invoker.public_configs
+  }
+}
+
+ios_static_framework("cronet_static_framework") {
+  output_name = "Cronet.framework"
+  framework_name = "Cronet"
+  public_headers = _cronet_public_headers
+  static_library_target = ":libcronet"

[mef, 2017/06/02 16:26:17]

Depending on lipo_binary target to produce fat static library results in errors
with additional_target_cpus where lipo tries to merge 2 libraries with the same
architecture. 

We need to do something similar to ios_framework_bundle to properly handle
additional cpus.

+  public_configs = [ ":cronet_static_config" ]
+}
+
 if (additional_toolchains == [] || current_toolchain == default_toolchain) {
   _package_dir = "$root_out_dir/cronet"
 
   action("generate_license") {
     _license_path = "$_package_dir/LICENSE"
 
     script = "//components/cronet/tools/cronet_licenses.py"
     inputs = [
       "//build/util/LASTCHANGE",
       "//buildtools/$host_os/gn",
     ]
     outputs = [
       _license_path,
     ]
     args = [
       "license",
       rebase_path(_license_path, root_build_dir),
       "--gn",
       "--gn-path",
       rebase_path("//buildtools/$host_os/gn", root_build_dir),
     ]
   }
 
+  copy("cronet_static_copy") {
+    sources = [
+      "$root_out_dir/Static/Cronet.framework",
+    ]
+    outputs = [
+      "$_package_dir/Static/Cronet.framework",
+    ]
+
+    deps = [
+      ":cronet_static_framework",
+    ]
+  }
+
   copy("cronet_package_copy") {
     sources = [
       "$root_out_dir/Cronet.framework",
       "//AUTHORS",
       "//chrome/VERSION",
     ]
     outputs = [
       "$_package_dir/{{source_file_part}}",
     ]
 
     deps = [
       ":cronet_framework",
+      ":cronet_static_copy",
     ]
   }
 
   if (enable_dsyms) {
     action("cronet_dsym_archive") {
       script = "//chrome/tools/build/mac/archive_symbols.py"
 
       # These are the dSYMs that will be archived. The sources list must be
       # the target outputs that correspond to the dSYMs (since a dSYM is a
       # directory it cannot be listed as a source file). The targets that
@@ skipping 23 matching lines @@
   }
 
   group("cronet_package") {
     deps = [
       ":cronet_dsym_archive",
       ":cronet_package_copy",
       ":generate_license",
     ]
   }
 }