[Cronet] Build static libcronet.a for iOS with complete dependencies.

components/cronet/ios/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/ios/rules.gni")
 import("//build/config/mac/symbols.gni")
 import("//build/mac/tweak_info_plist.gni")
 import("//build/util/process_version.gni")
 import("//build/util/version.gni")
@@ skipping 14 matching lines @@
   sources = [
     "//chrome/VERSION",
   ]
   output = "$target_gen_dir/version.h"
   extra_args = [
     "-e",
     "VERSION_FULL=\"%s.%s.%s.%s\" % (MAJOR,MINOR,BUILD,PATCH)",
   ]
 }
 
+config("cronet_include_config") {
+  include_dirs = [ "//components/grpc_support/include" ]
+}
+
+config("cronet_static_config") {
+  libs = [
+    "$target_out_dir/$current_cpu/libcronet_hide.a",
+    "UIKit.Framework",
+    "CFNetwork.framework",
+    "MobileCoreServices.framework",
+    "Security.framework",
+    "SystemConfiguration.framework",
+    "resolv",
+  ]
+}
+
+_cronet_deps = [
+  ":cronet_version_header",
+  ":generate_accept_languages",
+  "//base:base",
+  "//components/grpc_support",
+  "//components/metrics:metrics",
+  "//components/metrics/proto:proto",
+  "//components/prefs:prefs",
+  "//ios/net:net",
+  "//ios/web:user_agent",
+  "//net",
+  "//url",
+]
+
+_cronet_sources = [
+  "../histogram_manager.cc",
+  "../histogram_manager.h",
+  "../stale_host_resolver.cc",
+  "../stale_host_resolver.h",
+  "../url_request_context_config.cc",
+  "../url_request_context_config.h",
+  "Cronet.h",
+  "Cronet.mm",
+  "cronet_c_for_grpc.h",
+  "cronet_environment.h",
+  "cronet_environment.mm",
+]
+
 source_set("cronet_sources") {
-  deps = [
-    ":cronet_version_header",
-    ":generate_accept_languages",
-    "//base:base",
-    "//components/grpc_support",
-    "//components/metrics:metrics",
-    "//components/metrics/proto:proto",
-    "//components/prefs:prefs",
-    "//ios/net:net",
-    "//ios/web:user_agent",
-    "//net",
-    "//url",
-  ]
+  deps = _cronet_deps
 
-  sources = [
-    "../histogram_manager.cc",
-    "../histogram_manager.h",
-    "../stale_host_resolver.cc",
-    "../stale_host_resolver.h",
-    "../url_request_context_config.cc",
-    "../url_request_context_config.h",
-    "Cronet.h",
-    "Cronet.mm",
-    "cronet_c_for_grpc.h",
-    "cronet_environment.h",
-    "cronet_environment.mm",
-  ]
+  sources = _cronet_sources
 
   include_dirs = [ "//components/grpc_support/include" ]
 
   if (!use_platform_icu_alternatives) {
     deps += [ "//base:i18n" ]
   }
 }
 
 # Tweak |info_plist| with current version and revision.
 tweak_info_plist("tweak_cronet_plist") {
   info_plist = "Info.plist"
 }
 
 ios_framework_bundle("cronet_framework") {
   output_name = "Cronet"
   info_plist_target = ":tweak_cronet_plist"
 
   deps = [
     ":cronet_sources",
     "//base",
     "//net:net",
   ]
 
   libs = [ "UIKit.Framework" ]
 
   include_dirs = [ "//components/grpc_support/include" ]

[kapishnikov, 2017/05/22 17:15:57]

Is it still needed with the public_configs below? 

[mef, 2017/05/22 20:53:53]

Done.

 
   public_deps = [
     "//components/grpc_support",
   ]
 
   public_headers = [
     "Cronet.h",
     "cronet_c_for_grpc.h",
   ]
   public_headers += grpc_public_headers
 
   sources = [
     "Cronet.h",
   ]
 
   configs -= [ "//build/config/compiler:default_symbols" ]
   configs += [ "//build/config/compiler:symbols" ]
+
+  public_configs = [ ":cronet_include_config" ]
 }
 
 test("cronet_unittests") {
   testonly = true
 
   sources = [
     "//components/cronet/histogram_manager_unittest.cc",
     "//components/cronet/run_all_unittests.cc",
     "//components/cronet/stale_host_resolver_unittest.cc",
     "//components/cronet/url_request_context_config_unittest.cc",
@@ skipping 14 matching lines @@
   script = "//components/cronet/tools/generate_accept_languages.py"
   args = [
     rebase_path("$target_gen_dir"),
     rebase_path("//"),
   ]
   outputs = [
     "$target_gen_dir/accept_languages_table.h",
   ]
 }
 
+# A static library which contains just _cronet_sources.
+static_library("cronet_static") {
+  deps = _cronet_deps
+
+  sources = _cronet_sources
+
+  visibility = [ ":*" ]
+
+  include_dirs = [ "//components/grpc_support/include" ]

[kapishnikov, 2017/05/22 17:15:57]

Replace it with "cronet_include_config"?

[mef, 2017/05/22 20:53:53]

Done.

+
+  public_deps = [
+    "//components/grpc_support",
+  ]
+
+  public_headers = [
+    "Cronet.h",
+    "cronet_c_for_grpc.h",
+  ]
+  public_headers += grpc_public_headers
+}
+
+# A static library which contains all dependencies of :cronet_static.
+static_library("cronet_deps_complete") {
+  visibility = [ ":*" ]
+  complete_static_lib = true
+  deps = [
+    ":cronet_static",
+  ]
+}
+
+# A static library which contains cronet and all dependendencies hidden inside.
+action("cronet_hide") {

[kapishnikov, 2017/05/22 17:15:57]

Do we intend to keep this target public? If yes, we should give it a more
meaningful name.

[mef, 2017/05/22 20:53:53]

It is currently used by cronet_consumer_static. 
If we can make static framework, then we could hide this.
I've renamed it for now.

+  script = "//components/cronet/tools/hide_symbols.py"
+  deps = [
+    ":cronet_deps_complete",
+    ":cronet_static",
+  ]
+  outputs = [
+    "$target_out_dir/$current_cpu/libcronet_hide.a",
+  ]
+  args = [
+    "--input_libs",
+    rebase_path("$target_out_dir/libcronet_static.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libcronet_deps_complete.a", root_build_dir),
+    "--output_obj",
+    rebase_path("$target_out_dir/$current_cpu/libcronet_hide.o",
+                root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/$current_cpu/libcronet_hide.a",
+                root_build_dir),
+    "--current_cpu",
+    current_cpu,
+  ]
+
+  public_configs = [
+    ":cronet_include_config",

[kapishnikov, 2017/05/22 17:15:56]

Should we add ":cronet_include_config" to ":cronet_static", so it come from
there?

[mef, 2017/05/22 20:53:53]

Done.

+    ":cronet_static_config",
+  ]
+}
+
+# A fat static library which exports cronet public symbols and hides all dependendencies.
+lipo_binary("libcronet") {
+  arch_binary_target = ":cronet_hide"
+  arch_binary_output = "libcronet_hide.a"
+  output_name = "libcronet.a"
+  enable_stripping = false
+  enable_dsyms = false
+}
+
 if (additional_toolchains == [] || current_toolchain == default_toolchain) {
   _package_dir = "$root_out_dir/cronet"
 
   action("generate_license") {
     _license_path = "$_package_dir/LICENSE"
 
     script = "//components/cronet/tools/cronet_licenses.py"
     inputs = [
       "//build/util/LASTCHANGE",
       "//buildtools/$host_os/gn",
     ]
     outputs = [
       _license_path,
     ]
     args = [
       "license",
       rebase_path(_license_path, root_build_dir),
       "--gn",
       "--gn-path",
       rebase_path("//buildtools/$host_os/gn", root_build_dir),
     ]
   }
 
   copy("cronet_package_copy") {
     sources = [
       "$root_out_dir/Cronet.framework",
+      "$target_out_dir/libcronet.a",
       "//AUTHORS",
       "//chrome/VERSION",
     ]
     outputs = [
       "$_package_dir/{{source_file_part}}",
     ]
 
     deps = [
       ":cronet_framework",
+      ":libcronet",
     ]
   }
 
   if (enable_dsyms) {
     action("cronet_dsym_archive") {
       script = "//chrome/tools/build/mac/archive_symbols.py"
 
       # These are the dSYMs that will be archived. The sources list must be
       # the target outputs that correspond to the dSYMs (since a dSYM is a
       # directory it cannot be listed as a source file). The targets that
@@ skipping 23 matching lines @@
   }
 
   group("cronet_package") {
     deps = [
       ":cronet_dsym_archive",
       ":cronet_package_copy",
       ":generate_license",
     ]
   }
 }