[Payment Request] Selector view controller

ios/chrome/browser/payments/payment_request_selector_view_controller.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/payments/payment_request_selector_view_controller.h"
+
+#include "base/mac/foundation_util.h"
+#include "components/strings/grit/components_strings.h"
+#import "ios/chrome/browser/payments/cells/payments_text_item.h"
+#import "ios/chrome/browser/payments/payment_request_selector_view_controller_actions.h"
+#import "ios/chrome/browser/payments/payment_request_selector_view_controller_data_source.h"
+#import "ios/chrome/browser/ui/autofill/cells/status_item.h"
+#import "ios/chrome/browser/ui/collection_view/cells/MDCCollectionViewCell+Chrome.h"
+#import "ios/chrome/browser/ui/collection_view/cells/collection_view_item+collection_view_controller.h"
+#import "ios/chrome/browser/ui/collection_view/cells/collection_view_item.h"
+#import "ios/chrome/browser/ui/collection_view/collection_view_model.h"
+#import "ios/chrome/browser/ui/colors/MDCPalette+CrAdditions.h"
+#import "ios/chrome/browser/ui/icons/chrome_icon.h"
+#include "ios/chrome/browser/ui/uikit_ui_util.h"
+#include "ios/chrome/grit/ios_strings.h"
+#include "ios/chrome/grit/ios_theme_resources.h"
+#include "ui/base/l10n/l10n_util.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+
+NSString* const kPaymentRequestSelectorCollectionViewAccessibilityID =
+    @"kPaymentRequestSelectorCollectionViewAccessibilityID";
+
+const CGFloat kSeparatorEdgeInset = 14;
+
+typedef NS_ENUM(NSInteger, SectionIdentifier) {
+  SectionIdentifierItems = kSectionIdentifierEnumZero,
+};
+
+typedef NS_ENUM(NSInteger, ItemType) {
+  ItemTypeHeader = kItemTypeEnumZero,
+  ItemTypeSelectableItem,  // This is a repeated item type.
+  ItemTypeSpinner,
+  ItemTypeAddItem,
+};
+
+}  // namespace
+
+@interface PaymentRequestSelectorViewController ()<
+    PaymentRequestSelectorViewControllerActions>
+
+@end
+
+@implementation PaymentRequestSelectorViewController
+
+@synthesize delegate = _delegate;
+@synthesize dataSource = _dataSource;
+
+- (instancetype)init {
+  if ((self = [super initWithStyle:CollectionViewControllerStyleAppBar])) {
+    // Set up leading (return) button.
+    UIBarButtonItem* returnButton =
+        [ChromeIcon templateBarButtonItemWithImage:[ChromeIcon backIcon]
+                                            target:nil
+                                            action:@selector(onReturn)];

[gambard, 2017/04/18 08:06:37]

I am not sure this works, but I guess you will see it when implementing the
delegate.
I tested it in showcase and it did not work (there are actually two back buttons
and you can select the second one). Moving it to viewDidLoad make it work, I
think you should do that.

[lpromero, 2017/04/18 08:43:46]

What is "this"? Nil-target? It means that it sends it through the responder
chain starting with the button itself. The view controller should be in the
chain so I think it should work.
In Showcase, I think Moe will instantiate it with initWithStyle to not have two
bars, which will bypass this init and back button.

[gambard, 2017/04/18 08:52:45]

"This" is "Adding an action to the button". I know that the styling will be
changed in showcase, I am just saying that I checkouted the CL and tested it:
the action is not trigger if the button is configured in init. It is triggered
if it is done in viewDidLoad.

[Moe, 2017/04/18 12:43:30]

Like Louis mentioned I initialize the CVC in the showcase to not have an app
bar. Even if we make the button
work once the action is setup in -viewDidLoad there will still be two bars I
think and therefore two sets of buttons
which cause issues with the EG selectors when testing. In my experience we're
better of without the app bar.   

[gambard, 2017/04/18 12:47:48]

The "two buttons" things was just a repro step :) I should not have mentioned it
as it is clearly confusing and I apologize.
My point is: this does not seem to work. You should move all your code below "//
Set up leading (return) button." to -viewDidLoad. I am fine with committing it
as is, but keep it in mind when creating your delegate if this is not called.

+    returnButton.accessibilityLabel = l10n_util::GetNSString(IDS_ACCNAME_BACK);
+    self.navigationItem.leftBarButtonItem = returnButton;
+  }
+  return self;
+}
+
+#pragma mark - PaymentRequestSelectorViewControllerActions
+
+- (void)onReturn {
+  [self.delegate paymentRequestSelectorViewControllerDidReturn:self];
+}
+
+#pragma mark - CollectionViewController methods
+
+- (void)loadModel {
+  [super loadModel];
+  CollectionViewModel* model = self.collectionViewModel;
+
+  [model addSectionWithIdentifier:SectionIdentifierItems];
+
+  // If the view controller is in the pending state, only display a spinner and
+  // a message indicating the pending state.
+  if (self.dataSource.state == PaymentRequestSelectorStatePending) {
+    StatusItem* statusItem = [[StatusItem alloc] initWithType:ItemTypeSpinner];
+    statusItem.state = StatusItemState::VERIFYING;
+    statusItem.text = l10n_util::GetNSString(IDS_PAYMENTS_CHECKING_OPTION);
+    [model addItem:statusItem toSectionWithIdentifier:SectionIdentifierItems];
+    return;
+  }
+
+  CollectionViewItem* headerItem = [self.dataSource headerItem];
+  if (headerItem) {
+    headerItem.type = ItemTypeHeader;
+    [model addItem:headerItem toSectionWithIdentifier:SectionIdentifierItems];
+  }
+
+  [self.dataSource.selectableItems
+      enumerateObjectsUsingBlock:^(
+          CollectionViewItem<PaymentsHasAccessoryType>* item, NSUInteger index,
+          BOOL* stop) {
+        item.type = ItemTypeSelectableItem;
+        item.accessibilityTraits |= UIAccessibilityTraitButton;

[gambard, 2017/04/18 08:06:37]

Why do you need to set accessibilityTraits? Doesn't the cell already have some
useful traits?

[lpromero, 2017/04/18 08:43:46]

Not the button one. It's the VC that decides if there is an action or not, in
didSelectCell.

[gambard, 2017/04/18 08:52:45]

Acknowledged.

+        item.accessoryType = (index == self.dataSource.selectedItemIndex)
+                                 ? MDCCollectionViewCellAccessoryCheckmark
+                                 : MDCCollectionViewCellAccessoryNone;
+        [model addItem:item toSectionWithIdentifier:SectionIdentifierItems];
+      }];
+
+  CollectionViewItem* addButtonItem = [self.dataSource addButtonItem];
+  if (addButtonItem) {
+    addButtonItem.type = ItemTypeAddItem;
+    addButtonItem.accessibilityTraits |= UIAccessibilityTraitButton;
+    [model addItem:addButtonItem
+        toSectionWithIdentifier:SectionIdentifierItems];
+  }
+}
+
+- (void)viewDidLoad {
+  [super viewDidLoad];
+  self.collectionView.accessibilityIdentifier =
+      kPaymentRequestSelectorCollectionViewAccessibilityID;
+
+  // Customize collection view settings.
+  self.styler.cellStyle = MDCCollectionViewCellStyleCard;
+  self.styler.separatorInset =
+      UIEdgeInsetsMake(0, kSeparatorEdgeInset, 0, kSeparatorEdgeInset);
+}
+
+#pragma mark UICollectionViewDelegate
+
+- (void)collectionView:(UICollectionView*)collectionView
+    didSelectItemAtIndexPath:(NSIndexPath*)indexPath {
+  [super collectionView:collectionView didSelectItemAtIndexPath:indexPath];
+
+  CollectionViewModel* model = self.collectionViewModel;
+
+  CollectionViewItem<PaymentsHasAccessoryType>* item =
+      [model itemAtIndexPath:indexPath];
+  switch (item.type) {
+    case ItemTypeSelectableItem: {
+      // Update the currently selected cell, if any.
+      if (self.dataSource.selectedItemIndex != NSUIntegerMax) {
+        CollectionViewItem<PaymentsHasAccessoryType>* selectedItem =
+            [self.dataSource
+                selectableItemAtIndex:self.dataSource.selectedItemIndex];
+        selectedItem.accessoryType = MDCCollectionViewCellAccessoryNone;
+        [self reconfigureCellsForItems:@[ selectedItem ]
+               inSectionWithIdentifier:SectionIdentifierItems];
+      }
+
+      // Update the newly selected cell.
+      item.accessoryType = MDCCollectionViewCellAccessoryCheckmark;
+      [self reconfigureCellsForItems:@[ item ]
+             inSectionWithIdentifier:SectionIdentifierItems];
+
+      // Notify the delegate of the selection.
+      NSUInteger index =
+          [self.collectionViewModel indexInItemTypeForIndexPath:indexPath];
+      DCHECK(index < [[self.dataSource selectableItems] count]);
+      [self.delegate paymentRequestSelectorViewController:self
+                                     didSelectItemAtIndex:index];
+      break;
+    }
+    case ItemTypeAddItem: {
+      [self.delegate paymentRequestSelectorViewControllerDidSelectAddItem:self];
+      break;
+    }
+    default:
+      break;
+  }
+}
+
+#pragma mark MDCCollectionViewStylingDelegate
+
+- (CGFloat)collectionView:(UICollectionView*)collectionView
+    cellHeightAtIndexPath:(NSIndexPath*)indexPath {
+  CollectionViewItem* item =
+      [self.collectionViewModel itemAtIndexPath:indexPath];
+
+  UIEdgeInsets inset = [self collectionView:collectionView
+                                     layout:collectionView.collectionViewLayout
+                     insetForSectionAtIndex:indexPath.section];
+
+  return [MDCCollectionViewCell
+      cr_preferredHeightForWidth:CGRectGetWidth(collectionView.bounds) -
+                                 inset.left - inset.right
+                         forItem:item];
+}
+
+- (BOOL)collectionView:(UICollectionView*)collectionView
+    hidesInkViewAtIndexPath:(NSIndexPath*)indexPath {
+  NSInteger type = [self.collectionViewModel itemTypeForIndexPath:indexPath];
+  if (type == ItemTypeHeader) {
+    return YES;
+  } else {
+    return NO;
+  }
+}
+
+@end