Clean up mac translate bars.

chrome/browser/cocoa/translate/translate_infobar_base.mm

 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <Cocoa/Cocoa.h>
 #import "chrome/browser/cocoa/translate/translate_infobar_base.h"
 
 #include "app/l10n_util.h"
 #include "base/histogram.h"
 #include "base/logging.h"  // for NOTREACHED()
@@ skipping 104 matching lines @@
     case kTranslationError:
       infobar_controller =
           [[TranslateMessageInfobarController alloc] initWithDelegate:this];
       break;
     default:
       NOTREACHED();
   }
   return new InfoBar(infobar_controller);
 }
 
+@implementation TranslateInfoBarControllerBase (FrameChangeObserver)
+
+// Triggered when the frame changes.  This will figure out what size and
+// visibility the options popup should be.
+- (void)didChangeFrame:(NSNotification*)notification {
+  [self adjustOptionsButtonSizeAndVisibilityForView:
+      [[self visibleControls] lastObject]];
+}
+
+@end
+
+
 @interface TranslateInfoBarControllerBase (Private)
 
 // Removes all controls so that layout can add in only the controls
 // required.
 - (void)clearAllControls;
 
 // Create all the various controls we need for the toolbar.
 - (void)constructViews;
 
 // Reloads text for all labels for the current state.
@@ skipping 82 matching lines @@
 
 - (void)loadLabelText {
   // Do nothing by default, should be implemented by subclasses.
 }
 
 - (void)updateState {
   [self loadLabelText];
   [self clearAllControls];
   [self showVisibleControls:[self visibleControls]];
   [self layout];
+  [self adjustOptionsButtonSizeAndVisibilityForView:
+      [[self visibleControls] lastObject]];
 }
 
 - (void)setInfoBarGradientColor {
   NSColor* startingColor = [NSColor colorWithCalibratedWhite:0.93 alpha:1.0];
   NSColor* endingColor = [NSColor colorWithCalibratedWhite:0.85 alpha:1.0];
   NSGradient* translateInfoBarGradient =
       [[[NSGradient alloc] initWithStartingColor:startingColor
                                      endingColor:endingColor] autorelease];
 
   [infoBarView_ setGradient:translateInfoBarGradient];
   [infoBarView_
       setStrokeColor:[NSColor colorWithCalibratedWhite:0.75 alpha:1.0]];
 }
 
 - (void)removeOkCancelButtons {
   // Removing okButton_ & cancelButton_ from the view may cause them
   // to be released and since we can still access them from other areas
   // in the code later, we need them to be nil when this happens.
   [okButton_ removeFromSuperview];
   okButton_ = nil;
   [cancelButton_ removeFromSuperview];
   cancelButton_ = nil;
 }
 
 - (void)clearAllControls {
   // Step 1: remove all controls from the infobar so we have a clean slate.
-  NSArray *allControls = [NSArray arrayWithObjects:label2_.get(), label3_.get(),
-      fromLanguagePopUp_.get(), toLanguagePopUp_.get(),
-      showOriginalButton_.get(), tryAgainButton_.get(), nil];
+  NSArray *allControls = [self allControls];
 
   for (NSControl* control in allControls) {
     if ([control superview])
       [control removeFromSuperview];
   }
 }
 
 - (void)showVisibleControls:(NSArray*)visibleControls {
   NSRect optionsFrame = [optionsPopUp_ frame];
   for (NSControl* control in visibleControls) {
@@ skipping 19 matching lines @@
 }
 
 - (void)layout {
 
 }
 
 - (NSArray*)visibleControls {
   return [NSArray array];
 }
 
-- (void) rebuildOptionsMenu {
+- (void)rebuildOptionsMenu:(BOOL)hideTitle {
   // The options model doesn't know how to handle state transitions, so rebuild
   // it each time through here.
   optionsMenuModel_.reset(
               new OptionsMenuModel([self delegate]));
 
   [optionsPopUp_ removeAllItems];
   // Set title.
-  NSString* optionsLabel =
+  NSString* optionsLabel = hideTitle ? @"" :
       l10n_util::GetNSString(IDS_TRANSLATE_INFOBAR_OPTIONS);
   [optionsPopUp_ addItemWithTitle:optionsLabel];
 
    // Populate options menu.
   NSMenu* optionsMenu = [optionsPopUp_ menu];
   [optionsMenu setAutoenablesItems:NO];
   for (int i = 0; i < optionsMenuModel_->GetItemCount(); ++i) {
     NSString* title = base::SysUTF16ToNSString(
         optionsMenuModel_->GetLabelAt(i));
     int cmd = optionsMenuModel_->GetCommandIdAt(i);
@@ skipping 74 matching lines @@
   // Set ourselves as the delegate for the options menu so we can populate it
   // dynamically.
   [[optionsPopUp_ menu] setDelegate:self];
 
   // Replace label_ with label1_ so we get a consistent look between all the
   // labels we display in the translate view.
   [[label_ superview] replaceSubview:label_ with:label1_.get()];
   label_.reset(); // Now released.
 
   // Populate contextual menus.
-  [self rebuildOptionsMenu];
+  [self rebuildOptionsMenu:NO];
   [self populateLanguageMenus];
 
   // Set OK & Cancel text.
   [okButton_ setTitle:GetNSStringWithFixup(IDS_TRANSLATE_INFOBAR_ACCEPT)];
   [cancelButton_ setTitle:GetNSStringWithFixup(IDS_TRANSLATE_INFOBAR_DENY)];
 
   // Set up "Show original" and "Try again" buttons.
-  [showOriginalButton_ setBezelStyle:NSRoundRectBezelStyle];
   [showOriginalButton_ setFrame:okButtonFrame];
-  [tryAgainButton_ setBezelStyle:NSRoundRectBezelStyle];
   [tryAgainButton_ setFrame:okButtonFrame];
 
+  // Set each of the buttons and popups to the NSTexturedRoundedBezelStyle
+  // (metal-looking) style.
+  NSArray* allControls = [self allControls];
+  for (NSControl* control in allControls) {
+    if (![control isKindOfClass:[NSButton class]])
+      continue;
+    NSButton* button = (NSButton*)control;
+    [button setBezelStyle:NSTexturedRoundedBezelStyle];
+    if ([button isKindOfClass:[NSPopUpButton class]]) {
+      [[button cell] setArrowPosition:NSPopUpArrowAtBottom];
+    }
+  }
+  // The options button is handled differently than the rest as it floats
+  // to the right.
+  [optionsPopUp_ setBezelStyle:NSTexturedRoundedBezelStyle];
+  [[optionsPopUp_ cell] setArrowPosition:NSPopUpArrowAtBottom];
+
   [showOriginalButton_ setTarget:self];
   [showOriginalButton_ setAction:@selector(showOriginal:)];
   [tryAgainButton_ setTarget:self];
   [tryAgainButton_ setAction:@selector(ok:)];
 
   [showOriginalButton_
       setTitle:GetNSStringWithFixup(IDS_TRANSLATE_INFOBAR_REVERT)];
   [tryAgainButton_
       setTitle:GetNSStringWithFixup(IDS_TRANSLATE_INFOBAR_RETRY)];
 
   // Add and configure controls that are visible in all modes.
   [optionsPopUp_ setAutoresizingMask:NSViewMinXMargin | NSViewMinYMargin |
           NSViewMaxYMargin];
   // Add "options" popup z-ordered below all other controls so when we
   // resize the toolbar it doesn't hide them.
   [infoBarView_ addSubview:optionsPopUp_
                 positioned:NSWindowBelow
                 relativeTo:nil];
   [GTMUILocalizerAndLayoutTweaker sizeToFitView:optionsPopUp_];
   MoveControl(closeButton_, optionsPopUp_, spaceBetweenControls_, false);
   VerticallyCenterView(optionsPopUp_);
 
+  [infoBarView_ setPostsFrameChangedNotifications:YES];
+  [[NSNotificationCenter defaultCenter]
+      addObserver:self
+         selector:@selector(didChangeFrame:)
+             name:NSViewFrameDidChangeNotification
+           object:infoBarView_];
   // Show and place GUI elements.
   [self updateState];
 }
 
+- (void)adjustOptionsButtonSizeAndVisibilityForView:(NSView*)lastView {
+  [optionsPopUp_ setHidden:NO];
+  [self rebuildOptionsMenu:NO];
+  [[optionsPopUp_ cell] setArrowPosition:NSPopUpArrowAtBottom];
+  [optionsPopUp_ sizeToFit];
+  
+  MoveControl(closeButton_, optionsPopUp_, spaceBetweenControls_, false);
+  if (!VerifyControlOrderAndSpacing(lastView, optionsPopUp_)) {
+    [self rebuildOptionsMenu:YES];
+    NSRect oldFrame = [optionsPopUp_ frame];
+    oldFrame.size.width = NSHeight(oldFrame);
+    [optionsPopUp_ setFrame:oldFrame];
+    [[optionsPopUp_ cell] setArrowPosition:NSPopUpArrowAtCenter];
+    MoveControl(closeButton_, optionsPopUp_, spaceBetweenControls_, false);
+    if (!VerifyControlOrderAndSpacing(lastView, optionsPopUp_)) {
+      [optionsPopUp_ setHidden:YES];
+    }
+  }
+}
+
 // Called when "Translate" button is clicked.
 - (IBAction)ok:(id)sender {
   TranslateInfoBarDelegate* delegate = [self delegate];
   TranslateInfoBarDelegate::Type state = delegate->type();
   DCHECK(state == TranslateInfoBarDelegate::kBeforeTranslate ||
       state == TranslateInfoBarDelegate::kTranslationError);
   delegate->Translate();
   UMA_HISTOGRAM_COUNTS("Translate.Translate", 1);
 }
 
@@ skipping 33 matching lines @@
     int cmd = [item tag];
     // Danger Will Robinson! : This call can release the infobar (e.g. invoking
     // "About Translate" can open a new tab).
     // Do not access member variables after this line!
     optionsMenuModel_->ExecuteCommand(cmd);
   } else {
     NOTREACHED();
   }
 }
 
+- (void)dealloc {
+  [[NSNotificationCenter defaultCenter] removeObserver:self];
+  [super dealloc];
+}
+
 #pragma mark NSMenuDelegate
 
 // Invoked by virtue of us being set as the delegate for the options menu.
 - (void)menuNeedsUpdate:(NSMenu *)menu {
-  [self rebuildOptionsMenu];
+  [self adjustOptionsButtonSizeAndVisibilityForView:
+      [[self visibleControls] lastObject]];
 }
 
 @end
 
 @implementation TranslateInfoBarControllerBase (TestingAPI)
 
+- (NSArray*)allControls {
+  return [NSArray arrayWithObjects:label1_.get(),fromLanguagePopUp_.get(),
+      label2_.get(), toLanguagePopUp_.get(), label3_.get(), okButton_,
+      cancelButton_, showOriginalButton_.get(), tryAgainButton_.get(),
+      nil];
+}
+
 - (NSMenu*)optionsMenu {
   return [optionsPopUp_ menu];
 }
 
 - (NSButton*)tryAgainButton {
   return tryAgainButton_.get();
 }
 
 - (bool)verifyLayout {
   // All the controls available to translate infobars, except the options popup.
   // The options popup is shown/hidden instead of actually removed.  This gets
   // checked in the subclasses.
-  NSArray* allControls = [NSArray arrayWithObjects:label1_.get(),
-      fromLanguagePopUp_.get(), label2_.get(), toLanguagePopUp_.get(),
-      label3_.get(), showOriginalButton_.get(), tryAgainButton_.get(), nil];
+  NSArray* allControls = [self allControls];
   NSArray* visibleControls = [self visibleControls];
 
   // Step 1: Make sure control visibility is what we expect.
   for (NSUInteger i = 0; i < [allControls count]; ++i) {
     id control = [allControls objectAtIndex:i];
     bool hasSuperView = [control superview];
     bool expectedVisibility = [visibleControls containsObject:control];
 
     if (expectedVisibility != hasSuperView) {
       NSString *title = @"";
       if ([control isKindOfClass:[NSPopUpButton class]]) {
         title = [[[control menu] itemAtIndex:0] title];
       }
 
       LOG(ERROR) <<
           "State: " << [self description] <<
           " Control @" << i << (hasSuperView ? " has" : " doesn't have") <<
           " a superview" << [[control description] UTF8String] <<
           " Title=" << [title UTF8String];
       return false;
     }
   }
 
   // Step 2: Check that controls are ordered correctly with no overlap.
   id previousControl = nil;
   for (NSUInteger i = 0; i < [visibleControls count]; ++i) {
     id control = [visibleControls objectAtIndex:i];
+    // The options pop up doesn't lay out like the rest of the controls as
+    // it floats to the right.  It has some known issues shown in
+    // http://crbug.com/47941.
+    if (control == optionsPopUp_.get())
+      continue;
     if (previousControl &&
         !VerifyControlOrderAndSpacing(previousControl, control)) {
       NSString *title = @"";
       if ([control isKindOfClass:[NSPopUpButton class]]) {
         title = [[[control menu] itemAtIndex:0] title];
       }
       LOG(ERROR) <<
           "State: " << [self description] <<
           " Control @" << i << " not ordered correctly: " <<
           [[control description] UTF8String] <<[title UTF8String];
       return false;
     }
     previousControl = control;
   }
 
   return true;
 }
 
 @end // TranslateInfoBarControllerBase (TestingAPI)