Create js_library and js_binary templates for closure compiling.

third_party/closure_compiler/compile_js.gni

+# Copyright 2017 The Chromium Authors.  All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/closure_compiler/closure_args.gni")
+
+script_path = "//third_party/closure_compiler"
+compiler_path = "$script_path/compiler/compiler.jar"
+
+# Defines a target that creates an ordering for .js files to be used by
+# js_binary to compile.
+#
+# Variables:
+#   sources:
+#     List of Javascript files to include in the library
+#
+#   deps:
+#     List of js_library targets to depend on
+#
+# Example:
+#   js_library("apple_tree") {
+#     sources = ["tree_main.js"]
+#     deps = [
+#       ":branch",
+#       ":trunk",
+#       ":root",
+#     ]
+#   }
+
+template("js_library") {
+  assert(defined(invoker.sources) || defined(invoker.deps),
+         "Need sources or deps in $target_name for js_library")
+  action(target_name) {
+    script = "$script_path/js_library.py"
+    forward_variables_from(invoker,
+                           [
+                             "sources",
+                             "deps",
+                           ])
+    outputs = [
+      "$target_gen_dir/$target_name.txt",
+    ]
+    args = [ "--output" ] + rebase_path(outputs, root_build_dir)
+    if (defined(sources)) {
+      args += [ "--sources" ] + rebase_path(sources, root_build_dir)
+    }
+    if (defined(deps)) {
+      args += [ "--deps" ]
+      foreach(dep, deps) {
+        # Get the output path for each dep
+        dep_gen_dir = get_label_info(dep, "target_gen_dir")
+        dep_name = get_label_info(dep, "name")
+        dep_output_path = "$dep_gen_dir/$dep_name.txt"
+        args += [ rebase_path(dep_output_path, root_build_dir) ]
+      }
+    }
+  }
+}
+
+# Defines a target that compiles javascript files using the closure compiler.
+# This will produce a minified and optimized javascript output file, and will
+# peform error, syntax, and type checking.  Additional checks and options
+# can be configured using the defs attribute.
+#
+# Variables:
+#   sources:
+#     List of .js files to compile
+#
+#   deps:
+#     List of js_library rules to depend on
+#
+#   outputs:
+#     A file to write the compiled .js to.
+#     Only takes in a single file, but should be placed in a list
+#
+#   bootstrap_file:
+#      A .js files to include before all others
+#
+#   config_files:
+#     A list of .js files to include after the bootstrap_file but before all
+#     others
+#
+#   defs:
+#     A list of custom flags to pass to the closure compiler.  Do not include
+#     the leading dashes
+#
+#   externs_list:
+#     A list of .js files to pass to the compiler as externs
+#
+# Example:
+#   js_binary("tree") {
+#     sources = ["tree_main.js"]
+#     deps = [":apple_tree"]
+#     outputs = [ "$target_gen_dir/tree.js" ]
+#     defs = ["jscomp_error=undefinedVars"]
+#   }
+
+template("js_binary") {
+  assert(defined(invoker.sources) || defined(invoker.deps),
+         "Need sources or deps in $target_name for js_binary")
+  assert(defined(invoker.outputs), "Need outputs in $target_name for js_binary")
+
+  action(target_name) {
+    script = "$script_path/js_binary.py"
+    forward_variables_from(invoker, "*")
+    args = [
+      "--compiler",
+      rebase_path(compiler_path, root_build_dir),
+    ]
+    args += [ "--output" ] + rebase_path(outputs, root_build_dir)
+    if (defined(sources)) {
+      args += [ "--sources" ] + rebase_path(sources, root_build_dir)
+    }
+    if (defined(deps)) {
+      args += [ "--deps" ]
+      foreach(dep, deps) {
+        target_path = get_label_info(dep, "target_gen_dir") + "/" +

[mbjorge, 2017/04/07 23:30:19]

copy from above; makes it clear it's doing the same thing

[damargulis, 2017/04/08 00:19:49]

Done.

+                      get_label_info(dep, "name") + ".txt"
+        args += [ rebase_path(target_path, root_build_dir) ]
+      }
+    }
+    if (defined(bootstrap_file)) {
+      args += [
+        "--bootstrap",
+        rebase_path(bootstrap_file, root_build_dir),
+      ]
+    }
+    if (defined(config_files)) {
+      args += [ "--config" ] + rebase_path(config_files, root_build_dir)
+    }
+    args += [ "--defs" ] + default_closure_args

[mbjorge, 2017/04/07 23:30:19]

Add a comment above here:

# |default_closure_args| from //third_party/closure_compiler/closure_args.gni

[damargulis, 2017/04/08 00:19:49]

Done.

+    if (defined(defs)) {
+      args += defs
+    }
+    args +=
+        [ "--externs" ] +
+        [ rebase_path("$script_path/externs/polymer-1.0.js", root_build_dir) ]
+    if (defined(externs_list)) {
+      args += rebase_path(externs_list, root_build_dir)
+    }
+  }
+}