Add support for native extension notifications

chrome/browser/ui/cocoa/notifications/notification_builder_mac.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/notifications/notification_builder_mac.h"
 
 #import <AppKit/AppKit.h>
 
 #include "base/mac/mac_util.h"
 #include "base/mac/scoped_nsobject.h"
 
 #include "chrome/browser/ui/cocoa/notifications/notification_constants_mac.h"
 
 namespace {
 
 // Internal builder constants representing the different notification fields
 // They don't need to be exposed outside the builder.
 
 NSString* const kNotificationTitle = @"title";
 NSString* const kNotificationSubTitle = @"subtitle";
 NSString* const kNotificationInformativeText = @"informativeText";
 NSString* const kNotificationImage = @"icon";
 NSString* const kNotificationButtonOne = @"buttonOne";
 NSString* const kNotificationButtonTwo = @"buttonTwo";
 NSString* const kNotificationTag = @"tag";
 NSString* const kNotificationCloseButtonTag = @"closeButton";
 NSString* const kNotificationOptionsButtonTag = @"optionsButton";
 NSString* const kNotificationSettingsButtonTag = @"settingsButton";
+
 }  // namespace
 
 @implementation NotificationBuilder {
   base::scoped_nsobject<NSMutableDictionary> notificationData_;
 }
 
 - (instancetype)initWithCloseLabel:(NSString*)closeLabel
                       optionsLabel:(NSString*)optionsLabel
                      settingsLabel:(NSString*)settingsLabel {
   if ((self = [super init])) {
@@ skipping 76 matching lines @@
 - (void)setIncognito:(BOOL)incognito {
   [notificationData_ setObject:[NSNumber numberWithBool:incognito]
                         forKey:notification_constants::kNotificationIncognito];
 }
 
 - (void)setNotificationType:(NSNumber*)notificationType {
   [notificationData_ setObject:notificationType
                         forKey:notification_constants::kNotificationType];
 }
 
+- (void)setShowSettingsButton:(BOOL)showSettingsButton {
+  [notificationData_
+      setObject:[NSNumber numberWithBool:showSettingsButton]
+         forKey:notification_constants::kNotificationHasSettingsButton];
+}
+
 - (NSUserNotification*)buildUserNotification {
   base::scoped_nsobject<NSUserNotification> toast(
       [[NSUserNotification alloc] init]);
   [toast setTitle:[notificationData_ objectForKey:kNotificationTitle]];
   [toast setSubtitle:[notificationData_ objectForKey:kNotificationSubTitle]];
   [toast setInformativeText:[notificationData_
                                 objectForKey:kNotificationInformativeText]];
 
   // Icon
   if ([notificationData_ objectForKey:kNotificationImage]) {
     if ([[NSImage class] conformsToProtocol:@protocol(NSSecureCoding)]) {
       NSImage* image = [notificationData_ objectForKey:kNotificationImage];
       [toast setContentImage:image];
     } else {  // NSImage only conforms to NSSecureCoding from 10.10 onwards.
       base::scoped_nsobject<NSImage> image([[NSImage alloc]
           initWithData:[notificationData_ objectForKey:kNotificationImage]]);
       [toast setContentImage:image];
     }
   }
 
+  // Type (needed to define the buttons)
+  NSNumber* type = [notificationData_
+      objectForKey:notification_constants::kNotificationType];

[Peter Beverloo, 2017/04/07 16:19:05]

Move back to line 219 w/o the comment now that |type| isn't used for that
anymore.

+
+  // Extensions don't have a settings button.

[Peter Beverloo, 2017/04/07 16:19:05]

nit: this layer doesn't care, I'd just generalize as "Not all notifications have
a settings button". Which, in turn, is implied by the fact that it's called "has
settings button".

+  NSNumber* showSettingsButton = [notificationData_
+      objectForKey:notification_constants::kNotificationHasSettingsButton];
+
   // Buttons
   if ([toast respondsToSelector:@selector(_showsButtons)]) {
     DCHECK([notificationData_ objectForKey:kNotificationCloseButtonTag]);
     DCHECK([notificationData_ objectForKey:kNotificationSettingsButtonTag]);
     DCHECK([notificationData_ objectForKey:kNotificationOptionsButtonTag]);
+    DCHECK([notificationData_
+        objectForKey:notification_constants::kNotificationHasSettingsButton]);
+
+    BOOL settingsButton = [showSettingsButton boolValue];
 
     [toast setValue:@YES forKey:@"_showsButtons"];
     // A default close button label is provided by the platform but we
     // explicitly override it in case the user decides to not
     // use the OS language in Chrome.
     [toast setOtherButtonTitle:[notificationData_
                                    objectForKey:kNotificationCloseButtonTag]];
 
     // Display the Settings button as the action button if there are either no
     // developer-provided action buttons, or the alternate action menu is not
     // available on this Mac version. This avoids needlessly showing the menu.
-    // TODO(miguelg): Extensions should not have a settings button.
     if (![notificationData_ objectForKey:kNotificationButtonOne] ||
         ![toast respondsToSelector:@selector(_alwaysShowAlternateActionMenu)]) {
-      [toast
-          setActionButtonTitle:
-              [notificationData_ objectForKey:kNotificationSettingsButtonTag]];
+      if (settingsButton) {
+        [toast setActionButtonTitle:
+                   [notificationData_
+                       objectForKey:kNotificationSettingsButtonTag]];
+      } else {
+        [toast setHasActionButton:NO];

[Peter Beverloo, 2017/04/07 16:19:05]

Is this necessary? Surely that's the default?

+      }
+
     } else {
       // Otherwise show the alternate menu, then show the developer actions and
-      // finally the settings one.
+      // finally the settings one if needed.
       DCHECK(
           [toast respondsToSelector:@selector(_alwaysShowAlternateActionMenu)]);
       DCHECK(
           [toast respondsToSelector:@selector(_alternateActionButtonTitles)]);
       [toast
           setActionButtonTitle:[notificationData_
                                    objectForKey:kNotificationOptionsButtonTag]];
       [toast setValue:@YES forKey:@"_alwaysShowAlternateActionMenu"];
 
       NSMutableArray* buttons = [NSMutableArray arrayWithCapacity:3];
       [buttons
           addObject:[notificationData_ objectForKey:kNotificationButtonOne]];
       if ([notificationData_ objectForKey:kNotificationButtonTwo]) {
         [buttons
             addObject:[notificationData_ objectForKey:kNotificationButtonTwo]];
       }
-      [buttons addObject:[notificationData_
-                             objectForKey:kNotificationSettingsButtonTag]];
+      if (settingsButton) {
+        [buttons addObject:[notificationData_
+                               objectForKey:kNotificationSettingsButtonTag]];
+      }
+
       [toast setValue:buttons forKey:@"_alternateActionButtonTitles"];
     }
   }
 
   // Tag
   if ([toast respondsToSelector:@selector(setIdentifier:)] &&
       [notificationData_ objectForKey:kNotificationTag]) {
     [toast setValue:[notificationData_ objectForKey:kNotificationTag]
              forKey:@"identifier"];
   }
@@ skipping 11 matching lines @@
 
   DCHECK([notificationData_
       objectForKey:notification_constants::kNotificationProfileId]);
   NSString* profileId = [notificationData_
       objectForKey:notification_constants::kNotificationProfileId];
 
   DCHECK([notificationData_
       objectForKey:notification_constants::kNotificationIncognito]);
   NSNumber* incognito = [notificationData_
       objectForKey:notification_constants::kNotificationIncognito];
-  NSNumber* type = [notificationData_
-      objectForKey:notification_constants::kNotificationType];
 
   toast.get().userInfo = @{
     notification_constants::kNotificationOrigin : origin,
     notification_constants::kNotificationId : notificationId,
     notification_constants::kNotificationProfileId : profileId,
     notification_constants::kNotificationIncognito : incognito,
     notification_constants::kNotificationType : type,
+    notification_constants::kNotificationHasSettingsButton : showSettingsButton,
   };
 
   return toast.autorelease();
 }
 
 - (NSDictionary*)buildDictionary {
   return [[notificationData_ copy] autorelease];
 }
 
 @end