[ObjC ARC] Converts ios/chrome/browser/ui:ui_internal to ARC.

ios/chrome/browser/ui/browser_view_controller.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/browser_view_controller.h"
 
 #import <AssetsLibrary/AssetsLibrary.h>
 #import <MobileCoreServices/MobileCoreServices.h>
 #import <PassKit/PassKit.h>
 #import <Photos/Photos.h>
 #import <QuartzCore/QuartzCore.h>
 
 #include <stdint.h>
 #include <cmath>
 #include <memory>
 
 #include "base/base64.h"
 #include "base/command_line.h"
 #include "base/files/file_path.h"
 #include "base/format_macros.h"
 #include "base/i18n/rtl.h"
 #include "base/ios/block_types.h"
 #include "base/ios/ios_util.h"
 #include "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #include "base/mac/bind_objc_block.h"
 #include "base/mac/bundle_locations.h"
 #include "base/mac/foundation_util.h"
-#include "base/mac/objc_property_releaser.h"
+
 #import "base/mac/scoped_block.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/macros.h"
 #include "base/memory/ptr_util.h"
 #include "base/metrics/histogram_macros.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "base/threading/sequenced_worker_pool.h"
@@ skipping 153 matching lines @@
 #include "net/base/mime_util.h"
 #include "net/base/registry_controlled_domains/registry_controlled_domain.h"
 #include "net/ssl/ssl_info.h"
 #include "net/url_request/url_request_context_getter.h"
 #include "third_party/google_toolbox_for_mac/src/iPhone/GTMUIImage+Resize.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/base/page_transition_types.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using base::UserMetricsAction;
 using bookmarks::BookmarkNode;
 
 class BrowserBookmarkModelBridge;
 class InfoBarContainerDelegateIOS;
 
 namespace ios_internal {
 NSString* const kPageInfoWillShowNotification =
     @"kPageInfoWillShowNotification";
 NSString* const kPageInfoWillHideNotification =
@@ skipping 270 matching lines @@
   // Notifies the toolbar menu of reading list changes.
   base::scoped_nsobject<ReadingListMenuNotifier> _readingListMenuNotifier;
 
   // The sender for the last received IDC_VOICE_SEARCH command.
   base::WeakNSObject<UIView> _voiceSearchButton;
 
   // Coordinator for displaying alerts.
   base::scoped_nsobject<AlertCoordinator> _alertCoordinator;
 
   // Releaser for properties that aren't backed by scoped_nsobjects.
-  base::mac::ObjCPropertyReleaser _propertyReleaser_BrowserViewController;
 }
 
 // The browser's side swipe controller.  Lazily instantiated on the first call.
-@property(nonatomic, retain, readonly) SideSwipeController* sideSwipeController;
+@property(nonatomic, strong, readonly) SideSwipeController* sideSwipeController;
 // The browser's preload controller.
-@property(nonatomic, retain, readonly) PreloadController* preloadController;
+@property(nonatomic, strong, readonly) PreloadController* preloadController;
 // The dialog presenter for this BVC's tab model.
-@property(nonatomic, retain, readonly) DialogPresenter* dialogPresenter;
+@property(nonatomic, strong, readonly) DialogPresenter* dialogPresenter;
 // The object that manages keyboard commands on behalf of the BVC.
-@property(nonatomic, retain, readonly) KeyCommandsProvider* keyCommandsProvider;
+@property(nonatomic, strong, readonly) KeyCommandsProvider* keyCommandsProvider;
 // Whether the current tab can enable the reader mode menu item.
 @property(nonatomic, assign, readonly) BOOL canUseReaderMode;
 // Whether the current tab can enable the request desktop menu item.
 @property(nonatomic, assign, readonly) BOOL canUseDesktopUserAgent;
 // Whether the sharing menu should be enabled.
 @property(nonatomic, assign, readonly) BOOL canShowShareMenu;
 // Helper method to check web controller canShowFindBar method.
 @property(nonatomic, assign, readonly) BOOL canShowFindBar;
 // Whether the controller's view is currently available.
 // YES from viewWillAppear to viewWillDisappear.
 @property(nonatomic, assign, getter=isVisible) BOOL visible;
 // Whether the controller's view is currently visible.
 // YES from viewDidAppear to viewWillDisappear.
 @property(nonatomic, assign) BOOL viewVisible;
 // Whether the controller is currently dismissing a presented view controller.
 @property(nonatomic, assign, getter=isDismissingModal) BOOL dismissingModal;
 // Returns YES if the toolbar has not been scrolled out by fullscreen.
 @property(nonatomic, assign, readonly, getter=isToolbarOnScreen)
     BOOL toolbarOnScreen;
 // Whether a new tab animation is occurring.
 @property(nonatomic, assign, readonly, getter=isInNewTabAnimation)
     BOOL inNewTabAnimation;
 // Whether BVC prefers to hide the status bar. This value is used to determine
 // the response from the |prefersStatusBarHidden| method.
 @property(nonatomic, assign) BOOL hideStatusBar;
 // Whether the VoiceSearchBar should be displayed.
 @property(nonatomic, readonly) BOOL shouldShowVoiceSearchBar;
 // Coordinator for displaying a modal overlay with activity indicator to prevent
 // the user from interacting with the browser view.
-@property(nonatomic, retain)
+@property(nonatomic, strong)
     ActivityOverlayCoordinator* activityOverlayCoordinator;
 
 // The user agent type used to load the currently visible page. User agent type
 // is NONE if there is no visible page or visible page is a native page.
 @property(nonatomic, assign, readonly) web::UserAgentType userAgentType;
 
 // BVC initialization:
 // If the BVC is initialized with a valid browser state & tab model immediately,
 // the path is straightforward: functionality is enabled, and the UI is built
 // when -viewDidLoad is called.
@@ skipping 274 matching lines @@
     *arrow_half_width = 0;
     *bar_height = animation.CurrentValueBetween(0, bar_target_height);
   }
 
   void InfoBarContainerStateChanged(bool is_animating) override {
     [controller_ infoBarContainerStateChanged:is_animating];
   }
 
   bool DrawInfoBarArrows(int* x) const override { return false; }
 
-  BrowserViewController* controller_;  // weak
+  __weak BrowserViewController* controller_;
 };
 
 // Called from the BrowserBookmarkModelBridge from C++ -> ObjC.
 @interface BrowserViewController (BookmarkBridgeMethods)
 // If a bookmark matching the currentTab url is added or moved, update the
 // toolbar state so the star highlight is in sync.
 - (void)bookmarkNodeModified:(const BookmarkNode*)node;
 - (void)allBookmarksRemoved;
 @end
 
@@ skipping 38 matching lines @@
   void BookmarkNodeChildrenReordered(bookmarks::BookmarkModel* model,
                                      const BookmarkNode* node) override {}
 
   void BookmarkAllUserNodesRemoved(
       bookmarks::BookmarkModel* model,
       const std::set<GURL>& removed_urls) override {
     [owner_ allBookmarksRemoved];
   }
 
  private:
-  BrowserViewController* owner_;  // Weak.
+  __weak BrowserViewController* owner_;
 };
 
 @implementation BrowserViewController
 
 @synthesize contentArea = _contentArea;
 @synthesize typingShield = _typingShield;
 @synthesize active = _active;
 @synthesize visible = _visible;
 @synthesize viewVisible = _viewVisible;
 @synthesize dismissingModal = _dismissingModal;
 @synthesize hideStatusBar = _hideStatusBar;
 @synthesize activityOverlayCoordinator = _activityOverlayCoordinator;
 @synthesize presenting = _presenting;
 
 #pragma mark - Object lifecycle
 
 - (instancetype)initWithTabModel:(TabModel*)model
                     browserState:(ios::ChromeBrowserState*)browserState
                dependencyFactory:
                    (BrowserViewControllerDependencyFactory*)factory {
   self = [super initWithNibName:nil bundle:base::mac::FrameworkBundle()];
   if (self) {
     DCHECK(factory);
-    _propertyReleaser_BrowserViewController.Init(self,
-                                                 [BrowserViewController class]);
-    _dependencyFactory.reset([factory retain]);
-    _nativeControllersForTabIDs.reset(
-        [[NSMapTable strongToWeakObjectsMapTable] retain]);
+
+    _dependencyFactory.reset(factory);
+    _nativeControllersForTabIDs.reset([NSMapTable strongToWeakObjectsMapTable]);
     _dialogPresenter.reset([[DialogPresenter alloc] initWithDelegate:self
                                             presentingViewController:self]);
     _javaScriptDialogPresenter.reset(
         new JavaScriptDialogPresenterImpl(_dialogPresenter));
     _webStateDelegate.reset(new web::WebStateDelegateBridge(self));
     // TODO(leng): Delay this.
     [[UpgradeCenter sharedInstance] registerClient:self];
     _inNewTabAnimation = NO;
     if (model && browserState)
       [self updateWithTabModel:model browserState:browserState];
@@ skipping 23 matching lines @@
   if (_bookmarkModel)
     _bookmarkModel->RemoveObserver(_bookmarkModelBridge.get());
   [_model removeObserver:self];
   [[UpgradeCenter sharedInstance] unregisterClient:self];
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [_toolbarController setDelegate:nil];
   if (_voiceSearchController.get())
     _voiceSearchController->SetDelegate(nil);
   [_rateThisAppDialog setDelegate:nil];
   [_model closeAllTabs];
-  [super dealloc];
 }
 
 #pragma mark - Accessibility
 
 - (BOOL)accessibilityPerformEscape {
   [self dismissPopups];
   return YES;
 }
 
 #pragma mark - Properties
 
 - (void)setActive:(BOOL)active {
   if (_active == active) {
     return;
   }
   _active = active;
 
   // If not active, display an activity indicator overlay over the view to
   // prevent interaction with the web page.
   // TODO(crbug.com/637093): This coordinator should be managed by the
   // coordinator used to present BrowserViewController, when implemented.
   if (active) {
     [self.activityOverlayCoordinator stop];
     self.activityOverlayCoordinator = nil;
   } else if (!self.activityOverlayCoordinator) {
-    self.activityOverlayCoordinator = [[[ActivityOverlayCoordinator alloc]
-        initWithBaseViewController:self] autorelease];
+    self.activityOverlayCoordinator =
+        [[ActivityOverlayCoordinator alloc] initWithBaseViewController:self];
     [self.activityOverlayCoordinator start];
   }
 
   if (_browserState) {
     web::ActiveStateManager* active_state_manager =
         web::BrowserState::GetActiveStateManager(_browserState);
     active_state_manager->SetActive(active);
   }
 
   [_model setWebUsageEnabled:active];
@@ skipping 168 matching lines @@
 #pragma mark - UIViewController methods
 
 // Perform additional set up after loading the view, typically from a nib.
 - (void)viewDidLoad {
   CGRect initialViewsRect = self.view.frame;
   initialViewsRect.origin.y += StatusBarHeight();
   initialViewsRect.size.height -= StatusBarHeight();
   UIViewAutoresizing initialViewAutoresizing =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
 
-  self.contentArea = [[[BrowserContainerView alloc]
-      initWithFrame:initialViewsRect] autorelease];
+  self.contentArea =
+      [[BrowserContainerView alloc] initWithFrame:initialViewsRect];
   self.contentArea.autoresizingMask = initialViewAutoresizing;
-  self.typingShield =
-      [[[UIButton alloc] initWithFrame:initialViewsRect] autorelease];
+  self.typingShield = [[UIButton alloc] initWithFrame:initialViewsRect];
   self.typingShield.autoresizingMask = initialViewAutoresizing;
   [self.typingShield addTarget:self
                         action:@selector(shieldWasTapped:)
               forControlEvents:UIControlEventTouchUpInside];
   self.view.autoresizingMask = initialViewAutoresizing;
   self.view.backgroundColor = [UIColor colorWithWhite:0.75 alpha:1.0];
   [self.view addSubview:self.contentArea];
   [self.view addSubview:self.typingShield];
   [super viewDidLoad];
 
@@ skipping 141 matching lines @@
     return;
 
   // Record focused state.
   BOOL isFocusedBeforeReshow = [_findBarController isFocused];
 
   [self hideFindBarWithAnimation:NO];
 
   base::WeakNSObject<BrowserViewController> weakSelf(self);
   void (^completion)(id<UIViewControllerTransitionCoordinatorContext>) = ^(
       id<UIViewControllerTransitionCoordinatorContext> context) {
-    base::scoped_nsobject<BrowserViewController> strongSelf([weakSelf retain]);
+    base::scoped_nsobject<BrowserViewController> strongSelf(weakSelf);
     if (strongSelf)
       [strongSelf showFindBarWithAnimation:NO
                                 selectText:NO
                                shouldFocus:isFocusedBeforeReshow];
   };
 
   BOOL enqueued =
       [coordinator animateAlongsideTransition:nil completion:completion];
   if (!enqueued) {
     completion(nil);
   }
 }
 
 - (void)dismissViewControllerAnimated:(BOOL)flag
                            completion:(void (^)())completion {
   self.dismissingModal = YES;
   base::WeakNSObject<BrowserViewController> weakSelf(self);
   [super dismissViewControllerAnimated:flag
                             completion:^{
                               base::scoped_nsobject<BrowserViewController>
-                                  strongSelf([weakSelf retain]);
+                                  strongSelf(weakSelf);
                               [strongSelf setDismissingModal:NO];
                               [strongSelf setPresenting:NO];
                               if (completion)
                                 completion();
                               [[strongSelf dialogPresenter] tryToPresent];
                             }];
 }
 
 - (void)presentViewController:(UIViewController*)viewControllerToPresent
                      animated:(BOOL)flag
@@ skipping 252 matching lines @@
 #pragma mark - UI Configuration and Layout
 
 - (void)updateWithTabModel:(TabModel*)model
               browserState:(ios::ChromeBrowserState*)browserState {
   DCHECK(model);
   DCHECK(browserState);
   DCHECK(!_model);
   DCHECK(!_browserState);
   _browserState = browserState;
   _isOffTheRecord = browserState->IsOffTheRecord() ? YES : NO;
-  _model.reset([model retain]);
+  _model.reset(model);
   [_model addObserver:self];
 
   if (!_isOffTheRecord) {
     [DefaultIOSWebViewFactory
         registerWebViewFactory:[ChromeWebViewFactory class]];
   }
   NSUInteger count = [_model count];
   for (NSUInteger index = 0; index < count; ++index)
     [self installDelegatesForTab:[_model tabAtIndex:index]];
 
@@ skipping 110 matching lines @@
 
   [self.sideSwipeController addHorizontalGesturesToView:self.view];
 
   infobars::InfoBarManager* infoBarManager =
       [[_model currentTab] infoBarManager];
   _infoBarContainer->ChangeInfoBarManager(infoBarManager);
 
   // Create contextual search views and controller.
   if ([TouchToSearchPermissionsMediator isTouchToSearchAvailableOnDevice] &&
       !_browserState->IsOffTheRecord()) {
-    _contextualSearchMask =
-        [[[ContextualSearchMaskView alloc] init] autorelease];
+    _contextualSearchMask = [[ContextualSearchMaskView alloc] init];
     [self.view insertSubview:_contextualSearchMask
                 belowSubview:[_toolbarController view]];
     _contextualSearchPanel = [self createPanelView];
     [self.view insertSubview:_contextualSearchPanel
                 aboveSubview:[_toolbarController view]];
     _contextualSearchController.reset([[ContextualSearchController alloc]
         initWithBrowserState:_browserState
                     delegate:self]);
     [_contextualSearchController setPanel:_contextualSearchPanel];
     [_contextualSearchController setTab:[_model currentTab]];
@@ skipping 260 matching lines @@
   DCHECK(position <= [_model count]);
 
   web::NavigationManager::WebLoadParams params(URL);
   params.transition_type = transition;
   if (postData) {
     // Extract the content type and post params from |postData| and add them
     // to the load params.
     NSString* contentType = base::SysUTF8ToNSString(postData->first);
     NSData* data = [NSData dataWithBytes:(void*)postData->second.data()
                                   length:postData->second.length()];
-    params.post_data.reset([data retain]);
-    params.extra_headers.reset([@{ @"Content-Type" : contentType } retain]);
+    params.post_data.reset(data);
+    params.extra_headers.reset(@{ @"Content-Type" : contentType });
   }
   Tab* tab = [_model insertTabWithLoadParams:params
                                       opener:nil
                                  openedByDOM:NO
                                      atIndex:position
                                 inBackground:NO];
   return tab;
 }
 
 // Whether the given tab's URL is an application specific URL.
 - (BOOL)isTabNativePage:(Tab*)tab {
   web::WebState* webState = tab.webState;
   if (!webState)
     return NO;
   web::NavigationItem* visibleItem =
       webState->GetNavigationManager()->GetVisibleItem();
   if (!visibleItem)
     return NO;
   return web::GetWebClient()->IsAppSpecificURL(visibleItem->GetURL());
 }
 
 - (void)expectNewForegroundTab {
   _expectingForegroundTab = YES;
 }
 
 - (UIImageView*)pageFullScreenOpenCloseAnimationView {
   CGRect viewBounds, remainder;
   CGRectDivide(self.view.bounds, &remainder, &viewBounds, StatusBarHeight(),
                CGRectMinYEdge);
-  return [[[UIImageView alloc] initWithFrame:viewBounds] autorelease];
+  return [[UIImageView alloc] initWithFrame:viewBounds];
 }
 
 - (UIImageView*)pageOpenCloseAnimationView {
   CGRect frame = [_contentArea bounds];
 
   frame.size.height = frame.size.height - [self headerHeight];
   frame.origin.y = [self headerHeight];
 
-  UIImageView* pageView =
-      [[[UIImageView alloc] initWithFrame:frame] autorelease];
+  UIImageView* pageView = [[UIImageView alloc] initWithFrame:frame];
   CGPoint center = CGPointMake(CGRectGetMidX(frame), CGRectGetMidY(frame));
   pageView.center = center;
 
   pageView.backgroundColor = [UIColor whiteColor];
   return pageView;
 }
 
 - (void)installDelegatesForTab:(Tab*)tab {
   // Unregistration happens when the Tab is removed from the TabModel.
   tab.dialogDelegate = self;
@@ skipping 83 matching lines @@
 - (void)removeExternalFilesImmediately:(BOOL)immediately
                      completionHandler:(ProceduralBlock)completionHandler {
   DCHECK_CURRENTLY_ON(web::WebThread::UI);
   DCHECK(!_isOffTheRecord);
   _externalFileRemover.reset(new ExternalFileRemover(self));
   // Delay the cleanup of the unreferenced files received from other apps
   // to not impact startup performance.
   int delay = immediately ? 0 : kExternalFilesCleanupDelaySeconds;
   _externalFileRemover->RemoveAfterDelay(
       base::TimeDelta::FromSeconds(delay),
-      base::BindBlock(completionHandler ? completionHandler
-                                        : ^{
-                                          }));
+      base::BindBlockArc(completionHandler ? completionHandler
+                                           : ^{
+                                             }));
 }
 
 #pragma mark - SnapshotOverlayProvider methods
 
 - (NSArray*)snapshotOverlaysForTab:(Tab*)tab {
   NSMutableArray* overlays = [NSMutableArray array];
   if (![_model webUsageEnabled]) {
     return overlays;
   }
   UIView* voiceSearchView = [self voiceSearchOverlayViewForTab:tab];
@@ skipping 85 matching lines @@
   }
 }
 
 - (void)ensureVoiceSearchBarCreated {
   if (_voiceSearchBar)
     return;
 
   CGFloat width = CGRectGetWidth([[self view] bounds]);
   CGFloat y = CGRectGetHeight([[self view] bounds]) - kVoiceSearchBarHeight;
   CGRect frame = CGRectMake(0.0, y, width, kVoiceSearchBarHeight);
-  _voiceSearchBar.reset([ios::GetChromeBrowserProvider()
-                             ->GetVoiceSearchProvider()
-                             ->BuildVoiceSearchBar(frame) retain]);
+  _voiceSearchBar.reset(ios::GetChromeBrowserProvider()
+                            ->GetVoiceSearchProvider()
+                            ->BuildVoiceSearchBar(frame));
   [_voiceSearchBar setVoiceSearchBarDelegate:self];
   [_voiceSearchBar setHidden:YES];
   [_voiceSearchBar setAutoresizingMask:UIViewAutoresizingFlexibleTopMargin |
                                        UIViewAutoresizingFlexibleWidth];
   [self.view insertSubview:_voiceSearchBar
               belowSubview:_infoBarContainer->view()];
 }
 
 - (void)updateVoiceSearchBarVisibilityAnimated:(BOOL)animated {
   // Voice search bar exists and is shown/hidden.
@@ skipping 304 matching lines @@
 - (void)webState:(web::WebState*)webState
     runRepostFormDialogWithCompletionHandler:(void (^)(BOOL))handler {
   // Display the action sheet with the arrow pointing at the top center of the
   // web contents.
   Tab* tab = LegacyTabHelper::GetTabForWebState(webState);
   UIView* view = webState->GetView();
   CGPoint dialogLocation =
       CGPointMake(CGRectGetMidX(view.frame),
                   CGRectGetMinY(view.frame) + [self headerHeightForTab:tab]);
   auto* helper = RepostFormTabHelper::FromWebState(webState);
-  helper->PresentDialog(dialogLocation, base::BindBlock(^(bool shouldContinue) {
+  helper->PresentDialog(dialogLocation,
+                        base::BindBlockArc(^(bool shouldContinue) {
                           handler(shouldContinue);
                         }));
 }
 
 - (web::JavaScriptDialogPresenter*)javaScriptDialogPresenterForWebState:
     (web::WebState*)webState {
   return _javaScriptDialogPresenter.get();
 }
 
 - (void)webState:(web::WebState*)webState
@@ skipping 25 matching lines @@
 }
 
 - (const std::vector<HeaderDefinition>)headerViews {
   std::vector<HeaderDefinition> results;
   if (![self isViewLoaded])
     return results;
 
   if (!IsIPadIdiom()) {
     if ([_toolbarController view]) {
       HeaderDefinition header = {
-          base::scoped_nsobject<UIView>([[_toolbarController view] retain]),
-          Hideable, [ToolbarController toolbarDropShadowHeight], 0.0,
+          base::scoped_nsobject<UIView>([_toolbarController view]), Hideable,
+          [ToolbarController toolbarDropShadowHeight], 0.0,
       };
       results.push_back(header);
     }
   } else {
     if ([_tabStripController view]) {
       HeaderDefinition header = {
-          base::scoped_nsobject<UIView>([[_tabStripController view] retain]),
-          Hideable, 0.0, 0.0,
+          base::scoped_nsobject<UIView>([_tabStripController view]), Hideable,
+          0.0, 0.0,
       };
       results.push_back(header);
     }
     if ([_toolbarController view]) {
       HeaderDefinition header = {
-          base::scoped_nsobject<UIView>([[_toolbarController view] retain]),
-          Hideable, [ToolbarController toolbarDropShadowHeight], 0.0,
+          base::scoped_nsobject<UIView>([_toolbarController view]), Hideable,
+          [ToolbarController toolbarDropShadowHeight], 0.0,
       };
       results.push_back(header);
     }
     if ([_findBarController view]) {
       HeaderDefinition header = {
-          base::scoped_nsobject<UIView>([[_findBarController view] retain]),
-          Overlap, 0.0, kIPadFindBarOverlap,
+          base::scoped_nsobject<UIView>([_findBarController view]), Overlap,
+          0.0, kIPadFindBarOverlap,
       };
       results.push_back(header);
     }
   }
   return results;
 }
 
 - (UIView*)footerView {
   return _voiceSearchBar;
 }
@@ skipping 154 matching lines @@
 
 - (id<VoiceSearchBar>)voiceSearchBar {
   return _voiceSearchBar;
 }
 
 #pragma mark - Install OverScrollActionController method.
 - (void)setOverScrollActionControllerToStaticNativeContent:
     (StaticHtmlNativeContent*)nativeContent {
   if (!IsIPadIdiom() && !FirstRun::IsChromeFirstRun()) {
     OverscrollActionsController* controller =
-        [[[OverscrollActionsController alloc]
-            initWithScrollView:[nativeContent scrollView]] autorelease];
+        [[OverscrollActionsController alloc]
+            initWithScrollView:[nativeContent scrollView]];
     [controller setDelegate:self];
     OverscrollStyle style = _isOffTheRecord
                                 ? OverscrollStyle::REGULAR_PAGE_INCOGNITO
                                 : OverscrollStyle::REGULAR_PAGE_NON_INCOGNITO;
     controller.style = style;
     nativeContent.overscrollActionsController = controller;
   }
 }
 
 #pragma mark - OverscrollActionsControllerDelegate methods.
@@ skipping 70 matching lines @@
 - (void)selectedPanelDidChange {
   [self updateToolbar];
 }
 
 #pragma mark - CRWNativeContentProvider methods
 
 - (id<CRWNativeContent>)controllerForURL:(const GURL&)url
                                withError:(NSError*)error
                                   isPost:(BOOL)isPost {
   ErrorPageContent* errorPageContent =
-      [[[ErrorPageContent alloc] initWithLoader:self
-                                   browserState:self.browserState
-                                            url:url
-                                          error:error
-                                         isPost:isPost
-                                    isIncognito:_isOffTheRecord] autorelease];
+      [[ErrorPageContent alloc] initWithLoader:self
+                                  browserState:self.browserState
+                                           url:url
+                                         error:error
+                                        isPost:isPost
+                                   isIncognito:_isOffTheRecord];
   [self setOverScrollActionControllerToStaticNativeContent:errorPageContent];
   return errorPageContent;
 }
 
 - (BOOL)hasControllerForURL:(const GURL&)url {
   std::string host(url.host());
 
   return host == kChromeUINewTabHost || host == kChromeUIBookmarksHost ||
          host == kChromeUITermsHost || host == kChromeUIOfflineHost;
 }
 
 - (id<CRWNativeContent>)controllerForURL:(const GURL&)url
                                 webState:(web::WebState*)webState {
   DCHECK(url.SchemeIs(kChromeUIScheme));
 
   id<CRWNativeContent> nativeController = nil;
   std::string url_host = url.host();
   if (url_host == kChromeUINewTabHost || url_host == kChromeUIBookmarksHost) {
     NewTabPageController* pageController =
-        [[[NewTabPageController alloc] initWithUrl:url
-                                            loader:self
-                                           focuser:_toolbarController
-                                       ntpObserver:self
-                                      browserState:_browserState
-                                        colorCache:_dominantColorCache
-                                webToolbarDelegate:self
-                                          tabModel:_model] autorelease];
+        [[NewTabPageController alloc] initWithUrl:url
+                                           loader:self
+                                          focuser:_toolbarController
+                                      ntpObserver:self
+                                     browserState:_browserState
+                                       colorCache:_dominantColorCache
+                               webToolbarDelegate:self
+                                         tabModel:_model];
     pageController.swipeRecognizerProvider = self.sideSwipeController;
 
     // Panel is always NTP for iPhone.
     NewTabPage::PanelIdentifier panelType = NewTabPage::kMostVisitedPanel;
 
     if (IsIPadIdiom()) {
       // New Tab Page can have multiple panels. Each panel is addressable
       // by a #fragment, e.g. chrome://newtab/#most_visited takes user to
       // the Most Visited page, chrome://newtab/#bookmarks takes user to
       // the Bookmark Manager, etc.
       // The utility functions NewTabPage::IdentifierFromFragment() and
       // FragmentFromIdentifier() map an identifier to/from a #fragment.
       // If the URL is chrome://bookmarks, pre-select the #bookmarks panel
       // without changing the URL since the URL may be chrome://bookmarks/#123.
       // If the URL is chrome://newtab/, pre-select the panel based on the
       // #fragment.
       panelType = url_host == kChromeUIBookmarksHost
                       ? NewTabPage::kBookmarksPanel
                       : NewTabPage::IdentifierFromFragment(url.ref());
     }
     [pageController selectPanel:panelType];
     nativeController = pageController;
   } else if (url_host == kChromeUITermsHost) {
     const std::string& filename = GetTermsOfServicePath();
 
     StaticHtmlNativeContent* staticNativeController =
-        [[[StaticHtmlNativeContent alloc]
+        [[StaticHtmlNativeContent alloc]
             initWithResourcePathResource:base::SysUTF8ToNSString(filename)
                                   loader:self
                             browserState:_browserState
-                                     url:GURL(kChromeUITermsURL)] autorelease];
+                                     url:GURL(kChromeUITermsURL)];
     [self setOverScrollActionControllerToStaticNativeContent:
               staticNativeController];
     nativeController = staticNativeController;
   } else if (url_host == kChromeUIOfflineHost) {
     StaticHtmlNativeContent* staticNativeController =
-        [[[OfflinePageNativeContent alloc] initWithLoader:self
-                                             browserState:_browserState
-                                                 webState:webState
-                                                      URL:url] autorelease];
+        [[OfflinePageNativeContent alloc] initWithLoader:self
+                                            browserState:_browserState
+                                                webState:webState
+                                                     URL:url];
     [self setOverScrollActionControllerToStaticNativeContent:
               staticNativeController];
     nativeController = staticNativeController;
   } else if (url_host == kChromeUIExternalFileHost) {
     // Return an instance of the |ExternalFileController| only if the file is
     // still in the sandbox.
     NSString* filePath = [ExternalFileController pathForExternalFileURL:url];
     if ([[NSFileManager defaultManager] fileExistsAtPath:filePath]) {
-      nativeController = [[[ExternalFileController alloc]
-           initWithURL:url
-          browserState:_browserState] autorelease];
+      nativeController =
+          [[ExternalFileController alloc] initWithURL:url
+                                         browserState:_browserState];
     }
   } else {
     DCHECK(![self hasControllerForURL:url]);
     // In any other case the PageNotAvailableController is returned.
-    nativeController =
-        [[[PageNotAvailableController alloc] initWithUrl:url] autorelease];
+    nativeController = [[PageNotAvailableController alloc] initWithUrl:url];
     if (url_host == kChromeUIHistoryFrameHost) {
       base::mac::ObjCCastStrict<PageNotAvailableController>(nativeController)
           .descriptionText = l10n_util::GetNSStringFWithFixup(
           IDS_IOS_HISTORY_URL_NOT_AVAILABLE,
           base::UTF8ToUTF16(kChromeUIHistoryURL),
           l10n_util::GetStringUTF16(IDS_HISTORY_SHOW_HISTORY));
     }
   }
   // If a native controller is vended before its tab is added to the tab model,
   // use the temporary key and add it under the new tab's tabId in the
@@ skipping 130 matching lines @@
   };
   _imageFetcher->FetchImageDataWebpDecoded(
       url, callback, web::ReferrerHeaderValueForNavigation(url, referrer),
       web::PolicyForNavigation(url, referrer));
 }
 
 - (void)managePermissionAndSaveImage:(NSData*)data
                    withFileExtension:(NSString*)fileExtension {
   switch ([PHPhotoLibrary authorizationStatus]) {
     // User was never asked for permission to access photos.
-    case PHAuthorizationStatusNotDetermined:
+    case PHAuthorizationStatusNotDetermined: {
       [PHPhotoLibrary requestAuthorization:^(PHAuthorizationStatus status) {
         // Call -saveImage again to check if chrome needs to display an error or
         // saves the image.
         if (status != PHAuthorizationStatusNotDetermined)
           [self managePermissionAndSaveImage:data
                            withFileExtension:fileExtension];
       }];
       break;
+    }
 
     // The application doesn't have permission to access photo and the user
     // cannot grant it.
     case PHAuthorizationStatusRestricted:
       [self displayPrivacyErrorAlertOnMainQueue:
                 l10n_util::GetNSString(
                     IDS_IOS_SAVE_IMAGE_RESTRICTED_PRIVACY_ALERT_MESSAGE)];
       break;
 
     // The application doesn't have permission to access photo and the user
     // can grant it.
     case PHAuthorizationStatusDenied:
       [self displayImageErrorAlertWithSettingsOnMainQueue];
       break;
 
     // The application has permission to access the photos.
     default: {
       web::WebThread::PostTask(
-          web::WebThread::FILE, FROM_HERE, base::BindBlock(^{
+          web::WebThread::FILE, FROM_HERE, base::BindBlockArc(^{
             [self saveImage:data withFileExtension:fileExtension];
           }));
       break;
     }
   }
 }
 
 - (void)saveImage:(NSData*)data withFileExtension:(NSString*)fileExtension {
   NSString* fileName = [[[NSProcessInfo processInfo] globallyUniqueString]
       stringByAppendingString:fileExtension];
@@ skipping 15 matching lines @@
   // Save the image to photos.
   [[PHPhotoLibrary sharedPhotoLibrary] performChanges:^{
     [PHAssetChangeRequest creationRequestForAssetFromImageAtFileURL:fileURL];
   }
       completionHandler:^(BOOL success, NSError* error) {
         // Callback for the image saving.
         [self finishSavingImageWithError:error];
 
         // Cleanup the temporary file.
         web::WebThread::PostTask(
-            web::WebThread::FILE, FROM_HERE, base::BindBlock(^{
+            web::WebThread::FILE, FROM_HERE, base::BindBlockArc(^{
               NSError* error = nil;
               [[NSFileManager defaultManager] removeItemAtURL:fileURL
                                                         error:&error];
             }));
       }];
 }
 
 - (void)displayImageErrorAlertWithSettingsOnMainQueue {
   NSURL* settingURL = [NSURL URLWithString:UIApplicationOpenSettingsURLString];
   BOOL canGoToSetting =
@@ skipping 624 matching lines @@
   CGFloat shortAxis = frame.size.width;
   CGFloat shortInset = kCardImageInsets.left + kCardImageInsets.right;
   shortAxis -= shortInset + 2 * ios_internal::page_animation_util::kCardMargin;
   CGFloat aspectRatio = frame.size.height / frame.size.width;
   CGFloat longAxis = std::floor(aspectRatio * shortAxis);
   CGFloat longInset = kCardImageInsets.top + kCardImageInsets.bottom;
   CGSize cardSize = CGSizeMake(shortAxis + shortInset, longAxis + longInset);
   CGRect cardFrame = {frame.origin, cardSize};
 
   CardView* card =
-      [[[CardView alloc] initWithFrame:cardFrame isIncognito:_isOffTheRecord]
-          autorelease];
+      [[CardView alloc] initWithFrame:cardFrame isIncognito:_isOffTheRecord];
   card.closeButtonSide = IsPortrait() ? CardCloseButtonSide::TRAILING
                                       : CardCloseButtonSide::LEADING;
   [_contentArea addSubview:card];
   return card;
 }
 
 #pragma mark - Command Handling
 
 - (IBAction)chromeExecuteCommand:(id)sender {
   NSInteger command = [sender tag];
@@ skipping 499 matching lines @@
 
 #if !defined(NDEBUG)
 - (void)viewSource {
   Tab* tab = [_model currentTab];
   DCHECK(tab);
   CRWWebController* webController = tab.webController;
   NSString* script = @"document.documentElement.outerHTML;";
   base::WeakNSObject<Tab> weakTab(tab);
   base::WeakNSObject<BrowserViewController> weakSelf(self);
   web::JavaScriptResultBlock completionHandlerBlock = ^(id result, NSError*) {
-    base::scoped_nsobject<Tab> strongTab([weakTab retain]);
+    base::scoped_nsobject<Tab> strongTab(weakTab);
     if (!strongTab)
       return;
     if (![result isKindOfClass:[NSString class]])
       result = @"Not an HTML page";
     std::string base64HTML;
     base::Base64Encode(base::SysNSStringToUTF8(result), &base64HTML);
     GURL URL(std::string("data:text/plain;charset=utf-8;base64,") + base64HTML);
     web::Referrer referrer([strongTab url], web::ReferrerPolicyDefault);
 
     [[weakSelf tabModel]
@@ skipping 283 matching lines @@
   CGSize panelContainerSize = self.view.bounds.size;
   if (IsIPadIdiom()) {
     config = [PadPanelConfiguration
         configurationForContainerSize:panelContainerSize
                   horizontalSizeClass:self.traitCollection.horizontalSizeClass];
   } else {
     config = [PhonePanelConfiguration
         configurationForContainerSize:panelContainerSize
                   horizontalSizeClass:self.traitCollection.horizontalSizeClass];
   }
-  ContextualSearchPanelView* newPanel = [[[ContextualSearchPanelView alloc]
-      initWithConfiguration:config] autorelease];
+  ContextualSearchPanelView* newPanel =
+      [[ContextualSearchPanelView alloc] initWithConfiguration:config];
   [newPanel addMotionObserver:self];
   [newPanel addMotionObserver:_contextualSearchMask];
   return newPanel;
 }
 
 #pragma mark - ContextualSearchPanelMotionObserver
 
 - (void)panel:(ContextualSearchPanelView*)panel
     didMoveWithMotion:(ContextualSearch::PanelMotion)motion {
   // If the header is offset, it's offscreen (or moving offscreen) and the
@@ skipping 266 matching lines @@
   NSString* title = l10n_util::GetNSString(titleMessageId);
   NSString* message = l10n_util::GetNSString(messageId);
   [self showErrorAlertWithStringTitle:title message:message];
 }
 
 - (void)showErrorAlertWithStringTitle:(NSString*)title
                               message:(NSString*)message {
   // Dismiss current alert.
   [_alertCoordinator stop];
 
-  _alertCoordinator.reset(
-      [[_dependencyFactory alertCoordinatorWithTitle:title
-                                             message:message
-                                      viewController:self] retain]);
+  _alertCoordinator.reset([_dependencyFactory alertCoordinatorWithTitle:title
+                                                                message:message
+                                                         viewController:self]);
   [_alertCoordinator start];
 }
 
 - (void)showSnackbar:(NSString*)message {
   [_dependencyFactory showSnackbarWithMessage:message];
 }
 
 #pragma mark - Show Mail Composer methods
 
 - (void)showMailComposer:(id)sender {
@@ skipping 101 matching lines @@
 
 - (UIView*)voiceSearchButton {
   return _voiceSearchButton;
 }
 
 - (id<LogoAnimationControllerOwner>)logoAnimationControllerOwner {
   return [self currentLogoAnimationControllerOwner];
 }
 
 @end