Global Resource Coordinator: Basic service internals

services/resource_coordinator/BUILD.gn

 # Copyright 2017 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-# There should be only one memory instrumentaiton coordinator. It is currently
+# There should be only one resource coordinator. It is currently
 # in the browser process. So, only //content/browser should link to this target.
 # Others modules should only need the public targets.
+import("//services/catalog/public/tools/catalog.gni")
+import("//services/service_manager/public/cpp/service.gni")
+import("//services/service_manager/public/service_manifest.gni")
+import("//services/service_manager/public/tools/test/service_test.gni")
+
 source_set("lib") {
   sources = [
+    "coordination_unit/coordination_unit_impl.cc",
+    "coordination_unit/coordination_unit_impl.h",
+    "coordination_unit/coordination_unit_provider_impl.cc",
+    "coordination_unit/coordination_unit_provider_impl.h",
     "memory/coordinator/coordinator_impl.cc",
     "memory/coordinator/coordinator_impl.h",
+    "resource_coordinator_service.cc",
+    "resource_coordinator_service.h",
   ]
 
   public_deps = [
     "//base",
     "//mojo/public/cpp/bindings",
     "//services/resource_coordinator/public/cpp",
     "//services/resource_coordinator/public/interfaces",
   ]
+
+  data_deps = [
+    ":manifest",
+  ]
+}
+
+service_manifest("manifest") {
+  name = "resource_coordinator"
+  source = "manifest.json"
+}
+
+service("resource_coordinator") {
+  sources = [
+    "service_main.cc",
+  ]
+
+  deps = [
+    ":lib",
+    "//mojo/public/cpp/system",
+  ]
 }
 
 source_set("tests") {
   testonly = true
 
   sources = [
+    "coordination_unit/coordination_unit_impl_unittest.cc",
     "memory/coordinator/coordinator_impl_unittest.cc",
     "public/cpp/memory/memory_dump_manager_delegate_impl_unittest.cc",
   ]
 
   deps = [
     ":lib",
     "//base",
     "//mojo/public/cpp/bindings",
     "//services/resource_coordinator/public/cpp",
     "//services/resource_coordinator/public/interfaces",
     "//testing/gtest",
   ]
 }
+
+service_test("resource_coordinator_unittests") {
+  sources = [
+    "resource_coordinator_service_unittest.cc",
+  ]
+
+  catalog = ":resource_coordinator_unittests_catalog"
+
+  deps = [
+    "//base",
+    "//mojo/public/cpp/bindings",
+    "//services/resource_coordinator/public/cpp",
+    "//services/resource_coordinator/public/interfaces",
+    "//services/service_manager/public/cpp",
+    "//services/service_manager/public/cpp:service_test_support",
+    "//services/service_manager/public/interfaces",
+    "//testing/gtest",
+  ]
+
+  data_deps = [
+    ":resource_coordinator",
+    "//content/shell:content_shell",
+  ]
+}
+
+service_manifest("unittest_manifest") {
+  name = "resource_coordinator_unittests"
+  source = "unittest_manifest.json"
+}
+
+catalog("resource_coordinator_unittests_catalog") {
+  embedded_services = [ ":unittest_manifest" ]
+  standalone_services = [ ":manifest" ]
+}