Remove CWV class and move setting User Agent to CWVWebViewConfiguration.

ios/web_view/internal/cwv_web_view_configuration.mm

 // Copyright 2017 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web_view/public/cwv_web_view_configuration.h"
 #import "ios/web_view/internal/cwv_web_view_configuration_internal.h"
 
+#include "base/memory/ptr_util.h"
+#include "base/strings/sys_string_conversions.h"
+#include "ios/web/public/app/web_main.h"
 #import "ios/web_view/internal/cwv_user_content_controller_internal.h"
 #import "ios/web_view/internal/web_view_browser_state.h"
 #import "ios/web_view/internal/web_view_web_client.h"
+#import "ios/web_view/internal/web_view_web_main_delegate.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 @interface CWVWebViewConfiguration ()
 // Initialize configuration with the specified browser state.
 - (instancetype)initWithBrowserState:
     (ios_web_view::WebViewBrowserState*)browserState;
 @end
 
+// The name of the product to be used in the User Agent string.
+static NSString* userAgentProductName;
+
 @implementation CWVWebViewConfiguration {
   // TODO(crbug.com/690182): CWVWebViewConfiguration should own _browserState.
   ios_web_view::WebViewBrowserState* _browserState;
 }
 
 @synthesize userContentController = _userContentController;
 
 + (instancetype)defaultConfiguration {
   static dispatch_once_t once;
   static CWVWebViewConfiguration* configuration;
   dispatch_once(&once, ^{
+    [self setupWebClientIfNeeded];
+
     ios_web_view::WebViewWebClient* client =
         static_cast<ios_web_view::WebViewWebClient*>(web::GetWebClient());
     configuration = [[self alloc] initWithBrowserState:client->browser_state()];
   });
   return configuration;
 }
 
 + (instancetype)incognitoConfiguration {
   static dispatch_once_t once;
   static CWVWebViewConfiguration* configuration;
   dispatch_once(&once, ^{
+    [self setupWebClientIfNeeded];
+
     ios_web_view::WebViewWebClient* client =
         static_cast<ios_web_view::WebViewWebClient*>(web::GetWebClient());
     configuration = [[self alloc]
         initWithBrowserState:client->off_the_record_browser_state()];
   });
   return configuration;
 }
 
++ (void)setupWebClientIfNeeded {

[Eugene But (OOO till 7-30), 2017/04/04 21:50:26]

Does this method need a different name? It does not do anything with
"WebClient".

[Eugene But (OOO till 7-30), 2017/04/04 21:50:26]

Please add comments.

[michaeldo, 2017/04/07 22:31:35]

PTAL, in newest patch, I renamed to webClient and it returns the value.

+  static std::unique_ptr<ios_web_view::WebViewWebMainDelegate> webMainDelegate;
+  static std::unique_ptr<web::WebMain> webMain;
+
+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    webMainDelegate = base::MakeUnique<ios_web_view::WebViewWebMainDelegate>(
+        base::SysNSStringToUTF8(userAgentProductName));
+    web::WebMainParams params(webMainDelegate.get());
+    webMain = base::MakeUnique<web::WebMain>(params);
+  });
+}
+
++ (void)setUserAgentProductName:(NSString*)productName {
+  userAgentProductName = productName;
+}
+
 - (instancetype)initWithBrowserState:
     (ios_web_view::WebViewBrowserState*)browserState {
   self = [super init];
   if (self) {
     _browserState = browserState;
     _userContentController =
         [[CWVUserContentController alloc] initWithConfiguration:self];
   }
   return self;
 }
 
 - (BOOL)isPersistent {
   return !_browserState->IsOffTheRecord();
 }
 
 - (ios_web_view::WebViewBrowserState*)browserState {
   return _browserState;
 }
 
 // NSCopying
 
 - (id)copyWithZone:(NSZone*)zone {
   return [[[self class] allocWithZone:zone] initWithBrowserState:_browserState];
 }
 
 @end