[ObjC ARC] Converts ios/chrome/browser/ui/ntp/recent_tabs:recent_tabs to ARC.

ios/chrome/browser/ui/ntp/recent_tabs/recent_tabs_table_view_controller.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/ntp/recent_tabs/recent_tabs_table_view_controller.h"
 
 #include <memory>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/browser_sync/profile_sync_service.h"
 #include "components/sync/driver/sync_service.h"
 #include "components/sync_sessions/open_tabs_ui_delegate.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #import "ios/chrome/browser/metrics/new_tab_page_uma.h"
 #include "ios/chrome/browser/sessions/tab_restore_service_delegate_impl_ios.h"
 #include "ios/chrome/browser/sessions/tab_restore_service_delegate_impl_ios_factory.h"
@@ skipping 14 matching lines @@
 #import "ios/chrome/browser/ui/ntp/recent_tabs/views/signed_out_view.h"
 #import "ios/chrome/browser/ui/ntp/recent_tabs/views/spacers_view.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #import "ios/chrome/browser/ui/url_loader.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ios/web/public/referrer.h"
 #import "ios/web/public/web_state/context_menu_params.h"
 #include "ui/base/l10n/l10n_util.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 // Key for saving collapsed session state in the UserDefaults.
 NSString* const kCollapsedSectionsKey = @"ChromeRecentTabsCollapsedSections";
 
 // Key for saving whether the Other Device section is collapsed.
 NSString* const kOtherDeviceCollapsedKey = @"OtherDevicesCollapsed";
 
 // Key for saving whether the Recently Closed section is collapsed.
 NSString* const kRecentlyClosedCollapsedKey = @"RecentlyClosedCollapsed";
@@ skipping 24 matching lines @@
   CELL_SESSION_TAB_DATA,
 };
 
 }  // namespace
 
 @interface RecentTabsTableViewController () {
   ios::ChromeBrowserState* _browserState;  // weak
   // The service that manages the recently closed tabs.
   sessions::TabRestoreService* _tabRestoreService;  // weak
   // Loader used to open new tabs.
-  id<UrlLoader> _loader;  // weak
+  __weak id<UrlLoader> _loader;
   // The sync state.
   SessionsSyncUserState _sessionState;
   // The synced sessions.
   std::unique_ptr<synced_sessions::SyncedSessions> _syncedSessions;
   // Handles displaying the context menu for all form factors.
-  base::scoped_nsobject<ContextMenuCoordinator> _contextMenuCoordinator;
+  ContextMenuCoordinator* _contextMenuCoordinator;
 }
 // Returns the type of the section at index |section|.
 - (SectionType)sectionType:(NSInteger)section;
 // Returns the type of the cell at the path |indexPath|.
 - (CellType)cellType:(NSIndexPath*)indexPath;
 // Returns the number of sections before the other devices or session sections.
 - (NSInteger)numberOfSectionsBeforeSessionOrOtherDevicesSections;
 // Dismisses the modal containing the Recent Tabs panel (iPhone only).
 - (void)dismissRecentTabsModal;
 // Dismisses the modal containing the Recent Tabs panel, with completion
@@ skipping 54 matching lines @@
     _browserState = browserState;
     _loader = loader;
     _sessionState = SessionsSyncUserState::USER_SIGNED_OUT;
     _syncedSessions.reset(new synced_sessions::SyncedSessions());
   }
   return self;
 }
 
 - (void)dealloc {
   [self.tableView removeObserver:self forKeyPath:@"contentSize"];
-  [super dealloc];
 }
 
 - (void)viewDidLoad {
   [super viewDidLoad];
   self.view.accessibilityIdentifier = @"recent_tabs_view_controller";
   [self.tableView setSeparatorColor:[UIColor clearColor]];
   [self.tableView setDataSource:self];
   [self.tableView setDelegate:self];
-  base::scoped_nsobject<UILongPressGestureRecognizer> longPress(
+  UILongPressGestureRecognizer* longPress =
       [[UILongPressGestureRecognizer alloc]
           initWithTarget:self
-                  action:@selector(handleLongPress:)]);
-  longPress.get().delegate = self;
+                  action:@selector(handleLongPress:)];
+  longPress.delegate = self;
   [self.tableView addGestureRecognizer:longPress];
 
   [self.tableView addObserver:self
                    forKeyPath:@"contentSize"
                       options:0
                       context:NULL];
 }
 
 - (void)observeValueForKeyPath:(NSString*)keyPath
                       ofObject:(id)object
@@ skipping 182 matching lines @@
                  referrer:web::Referrer()
                transition:ui::PAGE_TRANSITION_TYPED
         rendererInitiated:NO];
   }
 }
 
 - (void)showFullHistory {
   UIViewController* rootViewController =
       self.tableView.window.rootViewController;
   ProceduralBlock openHistory = ^{
-    base::scoped_nsobject<GenericChromeCommand> openHistory(
-        [[GenericChromeCommand alloc] initWithTag:IDC_SHOW_HISTORY]);
+    GenericChromeCommand* openHistory =
+        [[GenericChromeCommand alloc] initWithTag:IDC_SHOW_HISTORY];
     [rootViewController chromeExecuteCommand:openHistory];
   };
   // Dismiss modal, if shown, and open history.
   if (IsIPadIdiom()) {
     openHistory();
   } else {
     [self dismissRecentTabsModalWithCompletion:openHistory];
   }
 }
 
@@ skipping 193 matching lines @@
     CellType cellType = [self cellType:indexPath];
     if (cellType != CELL_SESSION_SECTION_HEADER) {
       NOTREACHED();
       return;
     }
 
     web::ContextMenuParams params;
     // Get view coordinates in local space.
     CGPoint viewCoordinate = [longPressGesture locationInView:self.tableView];
     params.location = viewCoordinate;
-    params.view.reset([self.tableView retain]);
+    params.view.reset(self.tableView);
 
     // Present sheet/popover using controller that is added to view hierarchy.
     UIViewController* topController = [params.view window].rootViewController;
     while (topController.presentedViewController)
       topController = topController.presentedViewController;
 
-    _contextMenuCoordinator.reset([[ContextMenuCoordinator alloc]
-        initWithBaseViewController:topController
-                            params:params]);
+    _contextMenuCoordinator =
+        [[ContextMenuCoordinator alloc] initWithBaseViewController:topController
+                                                            params:params];
 
     // Fill the sheet/popover with buttons.
-    base::WeakNSObject<RecentTabsTableViewController> weakSelf(self);
+    __weak RecentTabsTableViewController* weakSelf = self;
 
     // "Open all tabs" button.
     NSString* openAllButtonLabel =
         l10n_util::GetNSString(IDS_IOS_RECENT_TABS_OPEN_ALL_MENU_OPTION);
     [_contextMenuCoordinator
         addItemWithTitle:openAllButtonLabel
                   action:^{
                     [weakSelf openTabsFromSessionAtIndexPath:indexPath];
                   }];
 
@@ skipping 100 matching lines @@
         return 1;
       else
         return distantSession->tabs.size() + 1;
     }
   }
 }
 
 - (UITableViewCell*)tableView:(UITableView*)tableView
         cellForRowAtIndexPath:(NSIndexPath*)indexPath {
   UITableViewCell* cell =
-      [[[UITableViewCell alloc] initWithStyle:UITableViewCellStyleDefault
-                              reuseIdentifier:nil] autorelease];
+      [[UITableViewCell alloc] initWithStyle:UITableViewCellStyleDefault
+                             reuseIdentifier:nil];
   UIView* contentView = cell.contentView;
 
-  base::scoped_nsobject<UIView> subview;
+  UIView* subview;
   CellType cellType = [self cellType:indexPath];
   switch (cellType) {
     case CELL_CLOSED_TAB_SECTION_HEADER: {
       BOOL collapsed = [self sectionIsCollapsed:kRecentlyClosedCollapsedKey];
-      subview.reset([[GenericSectionHeaderView alloc]
+      subview = [[GenericSectionHeaderView alloc]
                 initWithType:recent_tabs::RECENTLY_CLOSED_TABS_SECTION_HEADER
-          sectionIsCollapsed:collapsed]);
+          sectionIsCollapsed:collapsed];
       [subview setTag:kSectionHeader];
       break;
     }
     case CELL_CLOSED_TAB_DATA: {
-      base::scoped_nsobject<SessionTabDataView> genericTabData(
-          [[SessionTabDataView alloc] initWithFrame:CGRectZero]);
+      SessionTabDataView* genericTabData =
+          [[SessionTabDataView alloc] initWithFrame:CGRectZero];
       [genericTabData
           updateWithTabRestoreEntry:[self tabRestoreEntryAtIndex:indexPath]
                        browserState:_browserState];
-      subview.reset([genericTabData.get() retain]);
+      subview = genericTabData;
       break;
     }
     case CELL_SHOW_FULL_HISTORY:
-      subview.reset([[ShowFullHistoryView alloc] initWithFrame:CGRectZero]);
+      subview = [[ShowFullHistoryView alloc] initWithFrame:CGRectZero];
       break;
     case CELL_SEPARATOR:
-      subview.reset(
-          [[RecentlyClosedSectionFooter alloc] initWithFrame:CGRectZero]);
+      subview = [[RecentlyClosedSectionFooter alloc] initWithFrame:CGRectZero];
       [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
       break;
     case CELL_OTHER_DEVICES_SECTION_HEADER: {
       BOOL collapsed = [self sectionIsCollapsed:kOtherDeviceCollapsedKey];
-      subview.reset([[GenericSectionHeaderView alloc]
+      subview = [[GenericSectionHeaderView alloc]
                 initWithType:recent_tabs::OTHER_DEVICES_SECTION_HEADER
-          sectionIsCollapsed:collapsed]);
+          sectionIsCollapsed:collapsed];
       [subview setTag:kSectionHeader];
       break;
     }
     case CELL_OTHER_DEVICES_SIGNED_OUT:
-      subview.reset([[SignedOutView alloc] initWithFrame:CGRectZero]);
+      subview = [[SignedOutView alloc] initWithFrame:CGRectZero];
       [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
       break;
     case CELL_OTHER_DEVICES_SIGNED_IN_SYNC_OFF:
-      subview.reset([[SignedInSyncOffView alloc] initWithFrame:CGRectZero
-                                                  browserState:_browserState]);
+      subview = [[SignedInSyncOffView alloc] initWithFrame:CGRectZero
+                                              browserState:_browserState];
       [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
       break;
     case CELL_OTHER_DEVICES_SIGNED_IN_SYNC_ON_NO_SESSIONS:
-      subview.reset(
-          [[SignedInSyncOnNoSessionsView alloc] initWithFrame:CGRectZero]);
+      subview = [[SignedInSyncOnNoSessionsView alloc] initWithFrame:CGRectZero];
       [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
       break;
     case CELL_OTHER_DEVICES_SYNC_IN_PROGRESS:
-      subview.reset(
-          [[SignedInSyncInProgressView alloc] initWithFrame:CGRectZero]);
+      subview = [[SignedInSyncInProgressView alloc] initWithFrame:CGRectZero];
       [cell setSelectionStyle:UITableViewCellSelectionStyleNone];
       break;
     case CELL_SESSION_SECTION_HEADER: {
       synced_sessions::DistantSession const* distantSession =
           [self sessionAtIndexPath:indexPath];
       NSString* key = [self keyForDistantSession:distantSession];
       BOOL collapsed = [self sectionIsCollapsed:key];
-      base::scoped_nsobject<SessionSectionHeaderView> sessionSectionHeader(
+      SessionSectionHeaderView* sessionSectionHeader =
           [[SessionSectionHeaderView alloc] initWithFrame:CGRectZero
-                                       sectionIsCollapsed:collapsed]);
+                                       sectionIsCollapsed:collapsed];
       [sessionSectionHeader updateWithSession:distantSession];
-      subview.reset(sessionSectionHeader.release());
+      subview = sessionSectionHeader;
       [subview setTag:kSectionHeader];
       break;
     }
     case CELL_SESSION_TAB_DATA: {
-      base::scoped_nsobject<SessionTabDataView> genericTabData(
-          [[SessionTabDataView alloc] initWithFrame:CGRectZero]);
+      SessionTabDataView* genericTabData =
+          [[SessionTabDataView alloc] initWithFrame:CGRectZero];
       [genericTabData updateWithDistantTab:[self distantTabAtIndex:indexPath]
                               browserState:_browserState];
-      subview.reset([genericTabData.get() retain]);
+      subview = genericTabData;
       break;
     }
   }
 
   DCHECK(subview);
   [contentView addSubview:subview];
 
   // Sets constraints on the subview.
   [subview setTranslatesAutoresizingMaskIntoConstraints:NO];
 
-  NSDictionary* viewsDictionary = @{ @"view" : subview.get() };
+  NSDictionary* viewsDictionary = @{ @"view" : subview };
   // This set of constraints should match the constraints set on the
   // RecentlyClosedSectionFooter.
   // clang-format off
   NSArray* constraints = @[
     @"V:|-0-[view]-0-|",
     @"H:|-(>=0)-[view(<=548)]-(>=0)-|",
     @"H:[view(==548@500)]"
   ];
   // clang-format on
   [contentView addConstraint:[NSLayoutConstraint
@@ skipping 89 matching lines @@
     case CELL_OTHER_DEVICES_SECTION_HEADER:
       return [GenericSectionHeaderView desiredHeightInUITableViewCell];
     case CELL_OTHER_DEVICES_SYNC_IN_PROGRESS:
       return [SignedInSyncInProgressView desiredHeightInUITableViewCell];
   }
 }
 
 - (UIView*)tableView:(UITableView*)tableView
     viewForHeaderInSection:(NSInteger)section {
   if ([self sectionType:section] == CLOSED_TAB_SECTION) {
-    return [[[RecentlyTabsTopSpacingHeader alloc] initWithFrame:CGRectZero]
-        autorelease];
+    return [[RecentlyTabsTopSpacingHeader alloc] initWithFrame:CGRectZero];
   }
   return nil;
 }
 
 - (CGFloat)tableView:(UITableView*)tableView
     heightForHeaderInSection:(NSInteger)section {
   if ([self sectionType:section] == CLOSED_TAB_SECTION) {
     return [RecentlyTabsTopSpacingHeader desiredHeightInUITableViewCell];
   }
   return 0;
 }
 
 #pragma mark - UIScrollViewDelegate
 
 - (void)scrollViewDidScroll:(UIScrollView*)scrollView {
   [delegate_ recentTabsTableViewContentMoved:self.tableView];
 }
 
 @end