Config changes to support target_os="fuchsia"

build/config/fuchsia/BUILD.gn

+# Copyright 2017 The Fuchsia Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/sysroot.gni")
+
+assert(is_fuchsia)
+assert(is_posix)
+
+config("werror") {
+  cflags = [
+    "-Werror",
+
+    # Declarations marked as deprecated should cause build failures, rather
+    # they should emit warnings to notify developers about the use of
+    # deprecated interfaces.

[Nico, 2017/05/11 15:03:16]

This is not good. We've tried this setup before a few times and it just doesn't
work, it just causes lots of warnings to be printed. Deprecation annotations are
mostly useless in practice. If someone wants to deprecate something, they should
update the codebase so that their thing is no longer used, and then delete their
thing. Nothing else works.

[scottmg, 2017/05/11 16:36:10]

Removed. (I think I just copy-pasta'd that from elsewhere.)

[Nico, 2017/05/11 16:42:04]

Thanks. Complained at all places I could find you could've copied this from too.

+    "-Wno-error=deprecated-declarations",
+
+    # Do not add additional -Wno-error to this config.
+  ]
+}
+
+config("icf") {
+  # This changes C/C++ semantics and might be incompatible with third-party
+  # code that relies on function pointers comparison.
+  ldflags = [ "-Wl,--icf=all" ]
+}
+
+config("compiler") {
+  cflags = []
+  cflags_c = [ "-std=c11" ]
+  cflags_cc = [ "-std=c++14" ]
+  ldflags = [ "-Wl,--threads" ]
+  configs = [
+    ":compiler_sysroot",
+    ":compiler_target",
+    ":icf",
+    ":werror",
+  ]
+  asmflags = cflags + cflags_c
+
+  libs = [
+    "mxio",
+    "magenta",
+    "unwind",
+  ]
+}
+
+config("compiler_sysroot") {
+  # The sole purpose of SYSROOT_VERSION is to change the command line on every
+  # sysroot update so as to force rebuilds.
+  defines = [ "SYSROOT_VERSION=$sysroot_version" ]
+  cflags = [ "--sysroot=" + rebase_path(sysroot, root_build_dir) ]
+  ldflags = [ "--sysroot=" + rebase_path(sysroot, root_build_dir) ]
+  asmflags = cflags
+}
+
+config("compiler_target") {
+  cflags = []
+  ldflags = []
+  if (current_cpu == "arm64") {
+    cflags += [ "--target=aarch64-fuchsia" ]
+    ldflags += [ "--target=aarch64-fuchsia" ]
+  } else if (current_cpu == "x64") {
+    cflags += [ "--target=x86_64-fuchsia" ]
+    ldflags += [ "--target=x86_64-fuchsia" ]
+  } else {
+    assert(false, "Unsupported architecture")
+  }
+  asmflags = cflags
+}