Rewrite implementation of ClipboardRecentContent in Objective C.

components/open_from_clipboard/BUILD.gn

Index: components/open_from_clipboard/BUILD.gn
diff --git a/components/open_from_clipboard/BUILD.gn b/components/open_from_clipboard/BUILD.gn
index fe46837a69abecb892c0d7406bb953cc30035c1a..3049faa75c5dfb6d9ead5990927d027c05ff4f71 100644
--- a/components/open_from_clipboard/BUILD.gn
+++ b/components/open_from_clipboard/BUILD.gn
@@ -12,8 +12,26 @@ static_library("open_from_clipboard") {
 
   deps = [
     "//base",
+    "//net",
     "//url",
   ]
+
+  public_deps = [
+    ":open_from_clipboard_ios_impl",

[sdefresne, 2017/04/03 09:27:16]

This should be "deps", not "public_deps" (as no code using
//components/open_from_clipboard should use clipboard_recent_content_ios_impl.h
directly).

[lody, 2017/04/04 13:42:17]

Done.

+  ]
+}
+
+static_library("open_from_clipboard_ios_impl") {

[sdefresne, 2017/04/03 09:27:16]

This can be a source_set.

[lody, 2017/04/04 13:42:18]

Done.

+  sources = [
+    "clipboard_recent_content_ios_impl.h",
+    "clipboard_recent_content_ios_impl.mm",
+  ]
+
+  deps = [
+    "//base",
+  ]
+
+  configs += [ "//build/config/compiler:enable_arc" ]

[sdefresne, 2017/04/03 09:27:16]

You'll need to put this configs behind "if (is_ios)" because it is only defined
if the current host is "mac" (i.e. only for mac/ios builds).

Why not put the whole target behind "if (is_ios)"? We want to avoid having
target being conditionally defined as it make the rest of the code harder to
read/write (you have to put conditional everywhere the target is used).

So, change this to something like this.

static_library("open_from_clipboard") {
  sources = [
    "clipboard_recent_content.cc",
    "clipboard_recent_content.h",
    "clipboard_recent_content_ios.h",
    "clipboard_recent_content_ios.mm",
  ]
  deps = [
    ":open_from_clipboard_helper",
    "//base",
    "//net",
    "//url",
  ]
}

# Helper classes used by "open_from_clipboard" target. Those classes have
# no dependencies on "//base:i18n".
source_set("open_from_clipboard_helper") {
  sources = [
    "clipboard_recent_content_helper_ios.h"
    "clipboard_recent_content_helper_ios.mm"
  ]
  deps = [
    "//base",
  ]
  assert_no_deps = [
    "//base:i18n",
  ]
  if (is_ios) {
    configs += [ "//build/config/compiler:enable_arc" ]
  }
}

Note: open_from_clipboard_helper and clipboard_recent_content_helper_ios.* are
placeholder names (I'm terrible at naming). They should make sense if you use
the internal API.

Note: //components/open_from_clipboard is used on other platforms for the tests
(to have omnibox component tests be the same on all platforms, even if there is
no production use/implementation of the component on other platforms).

Note: the automatic filtering of file only look for "_ios" as a suffix, so
"foo_ios_impl.h" will not be filtered on other platforms, but "foo_impl_ios.h"
will.

[lody, 2017/04/04 13:42:17]

Done.

 }
 
 static_library("test_support") {