Add component for feature engagement tracking.

components/feature_engagement_tracker/internal/BUILD.gn

Index: components/feature_engagement_tracker/internal/BUILD.gn
diff --git a/components/feature_engagement_tracker/internal/BUILD.gn b/components/feature_engagement_tracker/internal/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..300db3ef85d4e7ac4f6acb77485a68bbe1fb94a0
--- /dev/null
+++ b/components/feature_engagement_tracker/internal/BUILD.gn
@@ -0,0 +1,72 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+if (is_android) {
+  import("//build/config/android/config.gni")
+  import("//build/config/android/rules.gni")
+}
+
+static_library("internal") {
+  visibility = [
+    ":*",
+    "//components/feature_engagement_tracker",
+  ]
+
+  sources = [
+    "feature_engagement_tracker_impl.cc",
+    "feature_engagement_tracker_impl.h",
+  ]
+
+  deps = [
+    "//base",
+    "//components/feature_engagement_tracker/public",
+    "//components/keyed_service/core",
+  ]
+
+  if (is_android) {
+    sources += [
+      "android/feature_engagement_tracker_impl_android.cc",
+      "android/feature_engagement_tracker_impl_android.h",
+      "android/feature_engagement_tracker_jni_registrar.cc",
+    ]
+
+    deps += [ ":jni_headers" ]
+  }
+}
+
+source_set("unit_tests") {
+  testonly = true
+
+  visibility = [ "//components/feature_engagement_tracker:unit_tests" ]
+
+  sources = [
+    "feature_engagement_tracker_impl_unittest.cc",
+  ]
+
+  deps = [
+    ":internal",
+    "//testing/gtest",
+  ]
+}
+
+if (is_android) {
+  android_library("internal_java") {
+    visibility = [ "//components/feature_engagement_tracker:feature_engagement_tracker_java" ]
+
+    java_files = [ "android/java/src/org/chromium/components/feature_engagement_tracker/internal/FeatureEngagementTrackerImpl.java" ]
+
+    deps = [
+      "//base:base_java",
+      "//components/feature_engagement_tracker/public:public_java",
+    ]
+  }
+
+  generate_jni("jni_headers") {
+    visibility = [ ":*" ]
+    sources = [
+      "android/java/src/org/chromium/components/feature_engagement_tracker/internal/FeatureEngagementTrackerImpl.java",
+    ]
+    jni_package = "components/feature_engagement_tracker/internal"
+  }
+}