Explicitly specify whether to emit frame pointers by default.

build/config/compiler/compiler.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
+import("//build/config/arm.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/chromecast_build.gni")
 import("//build/config/compiler/pgo/pgo.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/toolchain/goma.gni")
 import("//build/toolchain/toolchain.gni")
 import("//build_overrides/build.gni")
 
 declare_args() {
   # How many symbols to include in the build. This affects the performance of
@@ skipping 42 matching lines @@
   # Note that doing a link repro uses a lot of disk space and slows down the
   # build, so this shouldn't be enabled on too many targets.
   #
   # See crbug.com/669854.
   linkrepro_root_dir = ""
 
   # Whether or not we should use position independent code.
   use_pic = true
 }
 
+# Whether to emit frame pointers by default.
+if (is_mac || is_ios) {
+  enabled_frame_pointers = true
+} else if (is_win) {
+  # 64-bit Windows ABI doesn't support frame pointers.
+  if (target_cpu == "x64") {
+    enabled_frame_pointers = false
+  } else {
+    enabled_frame_pointers = true
+  }
+} else {
+  # Explicitly ask for frame pointers, otherwise:
+  # * Stacks may be missing for sanitizer and profiling builds.
+  # * Debug tcmalloc can crash (crbug.com/636489).
+  # * Stacks may be missing for arm64 crash dumps (crbug.com/391706).
+  enabled_frame_pointers =
+      using_sanitizer || enable_profiling || is_debug || current_cpu == "arm64"
+}
+
+# Unwinding with frame pointers requires that frame pointers are enabled by
+# default for most translation units, and that the architecture isn't thumb, as
+# frame pointers are not correctly emitted for thumb.
+if (enabled_frame_pointers && !(current_cpu == "arm" && arm_use_thumb)) {
+  can_unwind_with_frame_pointers = true
+} else {
+  can_unwind_with_frame_pointers = false
+}
+
 declare_args() {
   # Whether or not the official builds should be built with full WPO. Enabled by
   # default for the PGO and the x64 builds.
   if (chrome_pgo_phase > 0) {
     full_wpo_on_official = true
   } else {
     full_wpo_on_official = false
   }
 }
 
@@ skipping 49 matching lines @@
 }
 
 # Assert that the configuration isn't going to hit https://crbug.com/648948.
 assert(ignore_elf32_limitations || !is_android ||
            (android_64bit_target_cpu && !build_apk_secondary_abi) ||
            is_component_build || symbol_level < 2,
        "Android 32-bit non-component builds cannot have symbol_level=2 " +
            "due to 4GiB file size limit, see https://crbug.com/648948. " +
            "If you really want to try this out, " +
            "set ignore_elf32_limitations=true.")