[sql] Import SQLite 3.17.0.

third_party/sqlite/src/tool/build-all-msvc.bat

 @ECHO OFF
 
 ::
 :: build-all-msvc.bat --
 ::
 :: Multi-Platform Build Tool for MSVC
 ::
 
 REM
 REM This batch script is used to build the SQLite DLL for multiple platforms
 REM and configurations using MSVC.  The built SQLite DLLs, their associated
 REM import libraries, and optionally their symbols files, are placed within
 REM the directory specified on the command line, in sub-directories named for
 REM their respective platforms and configurations.  This batch script must be
 REM run from inside a Visual Studio Command Prompt for the desired version of
 REM Visual Studio ^(the initial platform configured for the command prompt does
 REM not really matter^).  Exactly one command line argument is required, the
 REM name of an existing directory to be used as the final destination directory
 REM for the generated output files, which will be placed in sub-directories
 REM created therein.  Ideally, the directory specified should be empty.
 REM
 REM Example:
 REM
 REM                        CD /D C:\dev\sqlite\core
-REM                        tool\build-all-msvc.bat C:\Temp
+REM                        CALL tool\build-all-msvc.bat C:\Temp
 REM
 REM In the example above, "C:\dev\sqlite\core" represents the root of the
 REM source tree for SQLite and "C:\Temp" represents the final destination
 REM directory for the generated output files.
 REM
 REM Please note that the SQLite build process performed by the Makefile
 REM associated with this batch script requires a Tcl shell to be present
 REM in a directory contained in the PATH environment variable unless a
 REM pre-existing amalgamation file is used.
 REM
@@ skipping 11 matching lines @@
 REM variables may be set to specify the location of the CRT, Universal CRT, and
 REM Windows SDK, respectively, that may be needed to compile executables native
 REM to the architecture of the build machine during any cross-compilation that
 REM may be necessary, depending on the platforms to be built.  These values in
 REM these three variables should be surrounded by double quotes if they contain
 REM spaces.
 REM
 REM There are a few other environment variables that impact the build process
 REM when set ^(to anything^), they are:
 REM
+REM                        USE_AUTOCONF_MAKEFILE
+REM
+REM When set, the "autoconf" Makefile for MSVC will be used instead of the main
+REM Makefile for MSVC.  It must exist at "%ROOT%\autoconf\Makefile.msc".
+REM
 REM                        NOCLEAN
 REM
 REM When set, the "clean" target will not be used during each build iteration.
 REM However, the target binaries, if any, will still be deleted manually prior
 REM to being rebuilt.  Setting this environment variable is only rarely needed
 REM and could cause issues in some circumstances; therefore, setting it is not
 REM recommended.
 REM
 REM                        NOSYMBOLS
 REM
 REM When set, copying of symbol files ^(*.pdb^) created during the build will
 REM be skipped and they will not appear in the final destination directory.
 REM Setting this environment variable is never strictly needed and could cause
 REM issues in some circumstances; therefore, setting it is not recommended.
 REM
+REM                        NOMEMDEBUG
+REM
+REM When set, disables use of MEMDEBUG when building binaries for the "Debug"
+REM configuration.
+REM
 REM                        BUILD_ALL_SHELL
 REM
 REM When set, the command line shell will be built for each selected platform
 REM and configuration as well.  In addition, the command line shell binaries
 REM will be copied, with their symbols, to the final destination directory.
 REM
 REM                        USE_WINV63_NSDKLIBPATH
 REM
 REM When set, modifies how the NSDKLIBPATH environment variable is built, based
 REM on the WindowsSdkDir environment variable.  It forces this batch script to
 REM assume the Windows 8.1 SDK location should be used.
 REM
 REM                        USE_WINV100_NSDKLIBPATH
 REM
 REM When set, modifies how the NSDKLIBPATH environment variable is built, based
 REM on the WindowsSdkDir environment variable.  It causes this batch script to
 REM assume the Windows 10.0 SDK location should be used.
 REM
 REM                        NMAKE_ARGS
+REM                        NMAKE_ARGS_DEBUG
+REM                        NMAKE_ARGS_RETAIL
 REM
-REM When set, the value is expanded and passed to the NMAKE command line, after
-REM its other arguments.  This is used to specify additional NMAKE options, for
-REM example:
+REM When set, these values are expanded and passed to the NMAKE command line,
+REM after its other arguments.  These may be used to specify additional NMAKE
+REM options, for example:
 REM
 REM                        SET NMAKE_ARGS=FOR_WINRT=1
+REM                        SET NMAKE_ARGS_DEBUG=MEMDEBUG=1
+REM                        SET NMAKE_ARGS_RETAIL=WIN32HEAP=1
 REM
 REM Using the above command before running this tool will cause the compiled
 REM binaries to target the WinRT environment, which provides a subset of the
 REM Win32 API.
 REM
+REM                        DLL_FILE_NAME
+REM                        DLL_PDB_FILE_NAME
+REM                        LIB_FILE_NAME
+REM                        EXE_FILE_NAME
+REM                        EXE_PDB_FILE_NAME
+REM
+REM When set, these values will override the associated target file name used
+REM for the build.
+REM
 SETLOCAL
 
 REM SET __ECHO=ECHO
 REM SET __ECHO2=ECHO
 REM SET __ECHO3=ECHO
 IF NOT DEFINED _AECHO (SET _AECHO=REM)
 IF NOT DEFINED _CECHO (SET _CECHO=REM)
 IF NOT DEFINED _VECHO (SET _VECHO=REM)
 
 SET REDIRECT=^>
@@ skipping 85 matching lines @@
   SET CONFIGURATIONS=Debug Retail
 )
 
 %_VECHO% Configurations = '%CONFIGURATIONS%'
 
 REM
 REM NOTE: If the command used to invoke NMAKE is not already set, use the
 REM       default.
 REM
 IF NOT DEFINED NMAKE_CMD (
-  SET NMAKE_CMD=nmake -B -f Makefile.msc
+  IF DEFINED USE_AUTOCONF_MAKEFILE (
+    SET NMAKE_CMD=nmake -B -f autoconf\Makefile.msc
+  ) ELSE (
+    SET NMAKE_CMD=nmake -B -f Makefile.msc
+  )
 )
 
 %_VECHO% NmakeCmd = '%NMAKE_CMD%'
 %_VECHO% NmakeArgs = '%NMAKE_ARGS%'
+%_VECHO% NmakeArgsDebug = '%NMAKE_ARGS_DEBUG%'
+%_VECHO% NmakeArgsRetail = '%NMAKE_ARGS_RETAIL%'
 
 REM
 REM NOTE: Setup environment variables to translate between the MSVC platform
 REM       names and the names to be used for the platform-specific binary
 REM       directories.
 REM
 SET amd64_NAME=x64
 SET arm_NAME=ARM
 SET x64_NAME=x64
 SET x86_NAME=x86
@@ skipping 10 matching lines @@
 %_VECHO% x86_x64_Name = '%x86_x64_NAME%'
 
 REM
 REM NOTE: Check for the external tools needed during the build process ^(i.e.
 REM       those that do not get compiled as part of the build process itself^)
 REM       along the PATH.
 REM
 IF DEFINED TCLSH_CMD (
   SET TCLSH_FILE=%TCLSH_CMD%
 ) ELSE (
-  SET TCLSH_FILE=tclsh85.exe
+  SET TCLSH_FILE=tclsh.exe
 )
 
 FOR %%T IN (%TCLSH_FILE%) DO (
   SET %%T_PATH=%%~dp$PATH:T
 )
 
 REM
 REM NOTE: A Tcl shell executable is required during the SQLite build process
 REM       unless a pre-existing amalgamation file is used.
 REM
 IF NOT DEFINED %TCLSH_FILE%_PATH (
   ECHO The Tcl shell executable "%TCLSH_FILE%" is required to be in the PATH.
   GOTO errors
 )
 
 REM
+REM NOTE: Setup the default names for the build targets we are creating.  Any
+REM       ^(or all^) of these may end up being overridden.
+REM
+IF NOT DEFINED DLL_FILE_NAME (
+  SET DLL_FILE_NAME=sqlite3.dll
+)
+
+IF NOT DEFINED DLL_PDB_FILE_NAME (
+  SET DLL_PDB_FILE_NAME=sqlite3.pdb
+)
+
+IF NOT DEFINED LIB_FILE_NAME (
+  SET LIB_FILE_NAME=sqlite3.lib
+)
+
+IF NOT DEFINED EXE_FILE_NAME (
+  SET EXE_FILE_NAME=sqlite3.exe
+)
+
+IF NOT DEFINED EXE_PDB_FILE_NAME (
+  SET EXE_PDB_FILE_NAME=sqlite3sh.pdb
+)
+
+REM
 REM NOTE: Set the TOOLPATH variable to contain all the directories where the
 REM       external tools were found in the search above.
 REM
 CALL :fn_CopyVariable %TCLSH_FILE%_PATH TOOLPATH
 
 %_VECHO% ToolPath = '%TOOLPATH%'
 
 REM
 REM NOTE: Setting the Windows SDK library path is only required for MSVC
 REM       2012, 2013, and 2015.
@@ skipping 158 matching lines @@
         REM       disable all compiler optimizations and prevent use of the
         REM       NDEBUG define.  Additionally, both SQLITE_ENABLE_API_ARMOR
         REM       and SQLITE_DEBUG defines should be enabled.
         REM
         SET DEBUG=3
 
         REM
         REM NOTE: Setting this to non-zero should enable the SQLITE_MEMDEBUG
         REM       define.
         REM
-        SET MEMDEBUG=1
+        IF NOT DEFINED NOMEMDEBUG (
+          SET MEMDEBUG=1
+        )
       ) ELSE (
         CALL :fn_UnsetVariable DEBUG
         CALL :fn_UnsetVariable MEMDEBUG
       )
 
       REM
+      REM NOTE: Copy the extra NMAKE arguments for this configuration into the
+      REM       common variable used by the actual commands.
+      REM
+      CALL :fn_CopyVariable NMAKE_ARGS_%%B NMAKE_ARGS_CFG
+
+      REM
       REM NOTE: Launch a nested command shell to perform the following steps:
       REM
       REM       1. Setup the MSVC environment for this platform using the
       REM          official batch file.
       REM
       REM       2. Make sure that no stale build output files are present.
       REM
       REM       3. Build the "sqlite3.dll" and "sqlite3.lib" binaries for this
       REM          platform.
       REM
@@ skipping 85 matching lines @@
           )
         )
 
         REM
         REM NOTE: Unless prevented from doing so, invoke NMAKE with the MSVC
         REM       makefile to clean any stale build output from previous
         REM       iterations of this loop and/or previous runs of this batch
         REM       file, etc.
         REM
         IF NOT DEFINED NOCLEAN (
-          %__ECHO% %NMAKE_CMD% clean
+          CALL :fn_MakeClean %%D
 
           IF ERRORLEVEL 1 (
             ECHO Failed to clean for platform %%P.
             GOTO errors
           )
         ) ELSE (
           REM
           REM NOTE: Even when the cleaning step has been disabled, we still
           REM       need to remove the build output for all the files we are
           REM       specifically wanting to build for each platform.
           REM
           %_AECHO% Cleaning final core library output files only...
-          %__ECHO% DEL /Q *.lo sqlite3.dll sqlite3.lib sqlite3.pdb 2%REDIRECT% NUL
+          %__ECHO% DEL /Q *.lo "%DLL_FILE_NAME%" "%LIB_FILE_NAME%" "%DLL_PDB_FILE_NAME%" 2%REDIRECT% NUL
         )
 
         REM
         REM NOTE: Call NMAKE with the MSVC makefile to build the "sqlite3.dll"
         REM       binary.  The x86 compiler will be used to compile the native
         REM       command line tools needed during the build process itself.
         REM       Also, disable looking for and/or linking to the native Tcl
         REM       runtime library.
         REM
-        %__ECHO% %NMAKE_CMD% sqlite3.dll XCOMPILE=1 USE_NATIVE_LIBPATHS=1 NO_TCL=1 %NMAKE_ARGS%
+        CALL :fn_MakeDll %%D
 
         IF ERRORLEVEL 1 (
-          ECHO Failed to build %%B "sqlite3.dll" for platform %%P.
+          ECHO Failed to build %%B "%DLL_FILE_NAME%" for platform %%P.
           GOTO errors
         )
 
         REM
         REM NOTE: Copy the "sqlite3.dll" file to the appropriate directory for
         REM       the build and platform beneath the binary directory.
         REM
-        %__ECHO% XCOPY sqlite3.dll "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
+        %__ECHO% XCOPY "%DLL_FILE_NAME%" "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
 
         IF ERRORLEVEL 1 (
-          ECHO Failed to copy "sqlite3.dll" to "%BINARYDIRECTORY%\%%B\%%D\".
+          ECHO Failed to copy "%DLL_FILE_NAME%" to "%BINARYDIRECTORY%\%%B\%%D\".
           GOTO errors
         )
 
         REM
         REM NOTE: Copy the "sqlite3.lib" file to the appropriate directory for
         REM       the build and platform beneath the binary directory.
         REM
-        %__ECHO% XCOPY sqlite3.lib "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
+        %__ECHO% XCOPY "%LIB_FILE_NAME%" "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
 
         IF ERRORLEVEL 1 (
-          ECHO Failed to copy "sqlite3.lib" to "%BINARYDIRECTORY%\%%B\%%D\".
+          ECHO Failed to copy "%LIB_FILE_NAME%" to "%BINARYDIRECTORY%\%%B\%%D\".
           GOTO errors
         )
 
         REM
         REM NOTE: Copy the "sqlite3.pdb" file to the appropriate directory for
         REM       the build and platform beneath the binary directory unless we
         REM       are prevented from doing so.
         REM
         IF NOT DEFINED NOSYMBOLS (
-          %__ECHO% XCOPY sqlite3.pdb "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
+          IF EXIST "%DLL_PDB_FILE_NAME%" (
+            %__ECHO% XCOPY "%DLL_PDB_FILE_NAME%" "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
 
-          IF ERRORLEVEL 1 (
-            ECHO Failed to copy "sqlite3.pdb" to "%BINARYDIRECTORY%\%%B\%%D\".
-            GOTO errors
+            IF ERRORLEVEL 1 (
+              ECHO Failed to copy "%DLL_PDB_FILE_NAME%" to "%BINARYDIRECTORY%\%%B\%%D\".
+              GOTO errors
+            )
           )
         )
 
         REM
         REM NOTE: If requested, also build the shell executable.
         REM
         IF DEFINED BUILD_ALL_SHELL (
           REM
           REM NOTE: If necessary, make sure any previous build output for the
           REM       shell executable is deleted.
           REM
           IF DEFINED NOCLEAN (
             REM
             REM NOTE: Even when the cleaning step has been disabled, we still
             REM       need to remove the build output for all the files we are
             REM       specifically wanting to build for each platform.
             REM
             %_AECHO% Cleaning final shell executable output files only...
-            %__ECHO% DEL /Q sqlite3.exe sqlite3sh.pdb 2%REDIRECT% NUL
+            %__ECHO% DEL /Q "%EXE_FILE_NAME%" "%EXE_PDB_FILE_NAME%" 2%REDIRECT% NUL
           )
 
           REM
           REM NOTE: Call NMAKE with the MSVC makefile to build the "sqlite3.exe"
           REM       binary.  The x86 compiler will be used to compile the native
           REM       command line tools needed during the build process itself.
           REM       Also, disable looking for and/or linking to the native Tcl
           REM       runtime library.
           REM
-          %__ECHO% %NMAKE_CMD% sqlite3.exe XCOMPILE=1 USE_NATIVE_LIBPATHS=1 NO_TCL=1 %NMAKE_ARGS%
+          CALL :fn_MakeExe %%D
 
           IF ERRORLEVEL 1 (
-            ECHO Failed to build %%B "sqlite3.exe" for platform %%P.
+            ECHO Failed to build %%B "%EXE_FILE_NAME%" for platform %%P.
             GOTO errors
           )
 
           REM
           REM NOTE: Copy the "sqlite3.exe" file to the appropriate directory
           REM       for the build and platform beneath the binary directory.
           REM
-          %__ECHO% XCOPY sqlite3.exe "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
+          %__ECHO% XCOPY "%EXE_FILE_NAME%" "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
 
           IF ERRORLEVEL 1 (
-            ECHO Failed to copy "sqlite3.exe" to "%BINARYDIRECTORY%\%%B\%%D\".
+            ECHO Failed to copy "%EXE_FILE_NAME%" to "%BINARYDIRECTORY%\%%B\%%D\".
             GOTO errors
           )
 
           REM
           REM NOTE: Copy the "sqlite3sh.pdb" file to the appropriate directory
           REM       for the build and platform beneath the binary directory
           REM       unless we are prevented from doing so.
           REM
           IF NOT DEFINED NOSYMBOLS (
-            %__ECHO% XCOPY sqlite3sh.pdb "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
+            IF EXIST "%EXE_PDB_FILE_NAME%" (
+              %__ECHO% XCOPY "%EXE_PDB_FILE_NAME%" "%BINARYDIRECTORY%\%%B\%%D\" %FFLAGS% %DFLAGS%
 
-            IF ERRORLEVEL 1 (
-              ECHO Failed to copy "sqlite3sh.pdb" to "%BINARYDIRECTORY%\%%B\%%D\".
-              GOTO errors
+              IF ERRORLEVEL 1 (
+                ECHO Failed to copy "%EXE_PDB_FILE_NAME%" to "%BINARYDIRECTORY%\%%B\%%D\".
+                GOTO errors
+              )
             )
           )
         )
       )
     )
   )
 
   REM
   REM NOTE: Handle any errors generated during the nested command shell.
   REM
@@ skipping 10 matching lines @@
 IF ERRORLEVEL 1 (
   ECHO Could not restore directory.
   GOTO errors
 )
 
 REM
 REM NOTE: If we get to this point, we have succeeded.
 REM
 GOTO no_errors
 
+:fn_MakeClean
+  %__ECHO% %NMAKE_CMD% clean "PLATFORM=%1" XCOMPILE=1 USE_NATIVE_LIBPATHS=1 NO_TCL=1 %NMAKE_ARGS% %NMAKE_ARGS_CFG%
+  GOTO :EOF
+
+:fn_MakeDll
+  %__ECHO% %NMAKE_CMD% "%DLL_FILE_NAME%" "PLATFORM=%1" XCOMPILE=1 USE_NATIVE_LIBPATHS=1 NO_TCL=1 %NMAKE_ARGS% %NMAKE_ARGS_CFG%
+  GOTO :EOF
+
+:fn_MakeExe
+  %__ECHO% %NMAKE_CMD% "%EXE_FILE_NAME%" "PLATFORM=%1" XCOMPILE=1 USE_NATIVE_LIBPATHS=1 NO_TCL=1 %NMAKE_ARGS% %NMAKE_ARGS_CFG%
+  GOTO :EOF
+
 :fn_ShowVariable
   SETLOCAL
   SET __ECHO_CMD=ECHO %%%2%%
   FOR /F "delims=" %%V IN ('%__ECHO_CMD%') DO (
     IF NOT "%%V" == "" (
       IF NOT "%%V" == "%%%2%%" (
         %_VECHO% %1 = '%%V'
       )
     )
   )
@@ skipping 13 matching lines @@
   IF "%2" == "" GOTO :EOF
   SETLOCAL
   SET __ECHO_CMD=ECHO %%%1%%
   FOR /F "delims=" %%V IN ('%__ECHO_CMD%') DO (
     SET VALUE=%%V
   )
   ENDLOCAL && SET %2=%VALUE%
   GOTO :EOF
 
 :fn_UnsetVariable
-  IF NOT "%1" == "" (
-    SET %1=
-    CALL :fn_ResetErrorLevel
+  SETLOCAL
+  SET VALUE=%1
+  IF DEFINED VALUE (
+    SET VALUE=
+    ENDLOCAL
+    SET %VALUE%=
+  ) ELSE (
+    ENDLOCAL
   )
+  CALL :fn_ResetErrorLevel
   GOTO :EOF
 
 :fn_AppendVariable
   SET __ECHO_CMD=ECHO %%%1%%
   IF DEFINED %1 (
     FOR /F "delims=" %%V IN ('%__ECHO_CMD%') DO (
       SET %1=%%V%~2
     )
   ) ELSE (
     SET %1=%~2
@@ skipping 17 matching lines @@
 
 :no_errors
   CALL :fn_ResetErrorLevel
   ENDLOCAL
   ECHO.
   ECHO Success, no errors were encountered.
   GOTO end_of_file
 
 :end_of_file
 %__ECHO% EXIT /B %ERRORLEVEL%