Add --headless flag to Windows

headless/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//headless/headless.gni")
 import("//build/util/process_version.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//testing/test.gni")
 import("//tools/grit/grit_rule.gni")
 import("//tools/grit/repack.gni")
 
 config("headless_implementation") {
   defines = [ "HEADLESS_IMPLEMENTATION" ]
 
   if (headless_use_embedded_resources) {
     defines += [ "HEADLESS_USE_EMBEDDED_RESOURCES" ]
   }
 }
 
-group("headless") {
+group("headless_lib") {
   deps = [
-    "//headless:headless_lib",
+    "//headless:headless",
   ]
 }
 
 repack("pak") {
   sources = [
     "$root_gen_dir/blink/public/resources/blink_image_resources_100_percent.pak",
     "$root_gen_dir/blink/public/resources/blink_resources.pak",
     "$root_gen_dir/components/strings/components_strings_en-US.pak",
     "$root_gen_dir/content/app/resources/content_resources_100_percent.pak",
     "$root_gen_dir/content/app/strings/content_strings_en-US.pak",
@@ skipping 147 matching lines @@
   ]
 
   args = [
     "--protocol",
     rebase_path(inputs[0], root_build_dir),
     "--output_dir",
     rebase_path(target_gen_dir) + "/public",
   ]
 }
 
-static_library("headless_lib") {
+component("headless") {

[Sami, 2017/03/27 14:07:58]

Can we still call this headless_lib? That's the component that others would want
to depend on, while "headless" is just the top-level name for this folder.

[dvallet, 2017/03/28 02:35:59]

From the component doc, it looks like it's preferable that the component name
matches the top level folder's name:
https://chromium.googlesource.com/chromium/src/+/master/docs/component_build.md
I've still left the group def as a kind of alias (and also the trybots are
configured for headless_lib). 

I don't mind changing it back, your call.

[Sami, 2017/03/28 11:49:32]

Okay, let's follow established convention then.

   sources = generated_devtools_api + [
               "lib/browser/headless_browser_context_impl.cc",
               "lib/browser/headless_browser_context_impl.h",
               "lib/browser/headless_browser_context_options.cc",
               "lib/browser/headless_browser_context_options.h",
               "lib/browser/headless_browser_impl.cc",
               "lib/browser/headless_browser_impl.h",
               "lib/browser/headless_browser_impl_mac.mm",
               "lib/browser/headless_browser_main_parts_mac.mm",
               "lib/browser/headless_browser_main_parts.cc",
@@ skipping 83 matching lines @@
     ]
   }
 
   deps = [
     ":gen_devtools_client_api",
     ":version_header",
     "//base",
     "//components/crash/content/browser",
     "//components/security_state/content",
     "//components/security_state/core",
-    "//content/public/app:both",
-    "//content/public/browser",
-    "//content/public/child:child",
     "//content/public/common",
     "//content/public/common:service_names",
     "//net",
     "//services/service_manager/public/cpp",
     "//third_party/mesa:osmesa",
     "//ui/base",
     "//ui/compositor",
     "//ui/display",
     "//ui/events/devices",
     "//url",
@@ skipping 35 matching lines @@
     "public/domains/types_unittest.cc",
     "public/util/deterministic_dispatcher_test.cc",
     "public/util/error_reporter_unittest.cc",
     "public/util/expedited_dispatcher_test.cc",
     "public/util/generic_url_request_job_test.cc",
     "public/util/testing/fake_managed_dispatch_url_request_job.cc",
     "public/util/testing/fake_managed_dispatch_url_request_job.h",
   ]
 
   deps = [
-    ":headless_lib",
+    ":headless",
     "//base/test:run_all_unittests",
     "//base/test:test_support",
+    "//net",
     "//testing/gmock",
     "//testing/gtest",
   ]
 }
 
 mojom("embedder_mojo_for_testing") {
   sources = [
     "lib/embedder_test.mojom",
   ]
 }
@@ skipping 54 matching lines @@
     "test/data/",
   ]
 
   defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 
   deps = [
     ":embedder_mojo_for_testing",
     ":headless_browser_tests_pak",
     "//base",
     "//content/test:test_support",
-    "//headless:headless_lib",
+    "//headless:headless",
     "//testing/gmock",
     "//testing/gtest",
   ]
 }
 
 static_library("headless_shell_lib") {
   sources = [
     "app/headless_shell.cc",
     "app/headless_shell.h",
     "app/headless_shell_switches.cc",
     "app/headless_shell_switches.h",
     "app/shell_navigation_request.cc",
     "app/shell_navigation_request.h",
     "public/headless_shell.h",
   ]
 
   deps = [
-    "//headless:headless_lib",
+    ":headless",
+    "//content/public/browser",
+    "//content/public/common",
   ]
 
-  configs += [ ":headless_implementation" ]
+  if (is_win) {
+    deps += [
+      "//content:sandbox_helper_win",
+      "//sandbox",
+    ]
+  }
+}
+
+static_library("headless_shell_child_lib") {

[Sami, 2017/03/27 14:07:58]

Is "child" the right name to be using here since code runs in the browser
(parent) process?

[dvallet, 2017/03/28 02:35:59]

This is only linked in chrome_child DLL, that's why I called it child, it's
basically headless minus the forbidden DEPS for child processes in Win

[Sami, 2017/03/28 11:49:32]

Ah, a little confusing but okay :)

+  sources = [
+    "app/headless_shell.cc",
+    "app/headless_shell.h",
+    "app/headless_shell_switches.cc",
+    "app/headless_shell_switches.h",
+    "app/shell_navigation_request.cc",
+    "app/shell_navigation_request.h",
+    "public/headless_shell.h",
+  ]
+
+  deps = [
+    ":headless",
+    "//content/public/child:child",

[Sami, 2017/03/27 14:07:58]

Where's this dependency coming from? I didn't find it under headless/app/.

[dvallet, 2017/03/28 02:35:59]

This pools the Ppapi plugging, I found it fitting to add it here since is the
child lib. 

I actually forgot to add a dependency for headless_shell and headless_example,
which is needed for non component build, see latest patch

+  ]
 }
 
 executable("headless_shell") {
   sources = [
     "app/headless_shell_main.cc",
   ]
 
   deps = [
-    "//headless:headless_shell_lib",
+    ":headless_shell_lib",
+    "//content/public/app:both",
   ]
-
-  if (is_win) {
-    deps += [
-      "//build/win:default_exe_manifest",
-      "//content:sandbox_helper_win",
-      "//sandbox",
-    ]
-  }
-
-  configs += [ ":headless_implementation" ]
 }
 
 process_version("version_header") {
   template_file = "public/version.h.in"
   sources = [
     "//build/util/LASTCHANGE",
     "//chrome/VERSION",
   ]
   output = "$target_gen_dir/public/version.h"
 }
 
 executable("headless_example") {
   sources = [
     "app/headless_example.cc",
   ]
 
   deps = [
-    "//headless:headless_shell_lib",
+    ":headless_shell_lib",
+    "//content/public/app:both",
   ]
 }