Statically link libprotobuf_lite on Linux component builds

third_party/protobuf/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 config("protobuf_config") {
   include_dirs = [ "src" ]
   defines = [
     "GOOGLE_PROTOBUF_NO_RTTI",
     "GOOGLE_PROTOBUF_NO_STATIC_INITIALIZER",
   ]
@@ skipping 118 matching lines @@
     "/wd4244",  # implicit conversion, possible loss of data
     "/wd4267",  # size_t to int truncation
     "/wd4291",  # no matching operator delete for a placement new.
     "/wd4305",  # double to float truncation
     "/wd4355",  # 'this' used in base member initializer list
     "/wd4506",  # no definition for inline function (protobuf issue #240)
     "/wd4715",  # not all control paths return a value (fixed in trunk)
   ]
 }
 
-component("protobuf_lite") {
+# Do not allow libprotobuf_lite to be dynamically linked on Linux.  Later
+# versions of Ubuntu like Xenial and Yakkety link in the system
+# libprotobuf_lite by the following dependency chain: chrome -> gtk ->
+# libmirclient -> libmirprotobuf -> libprotobuf-lite.  Trying to load
+# the system libprotobuf-lite after already having loaded the libprotobuf_lite
+# component will result in an immediate crash. (crbug.com/700120)
+if (is_linux && !is_chromeos) {
+  link_target_type = "static_library"
+} else {
+  link_target_type = "component"
+}
+
+if (is_component_build && is_linux && !is_chromeos) {
+  # Even though protobuf is statically linked on Linux, global data must
+  # be shared across different copies of the library in each component.
+  # protobuf_globals is a shared library that provides this state, but is
+  # careful to prefix all exported symbols with 'cr_' so they don't conflict
+  # with other versions of protobuf.
+  component("protobuf_globals") {
+    configs += [
+      ":protobuf_config",
+      ":protobuf_use_dlls",
+    ]
+    defines = [ "LIBPROTOBUF_EXPORTS" ]
+    sources = [
+      "src/google/protobuf/globals.cc",
+      "src/google/protobuf/stubs/atomicops_internals_x86_gcc.cc",
+    ]
+  }
+}
+
+target(link_target_type, "protobuf_lite") {
   sources = protobuf_lite_sources
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [
     "//build/config/compiler:no_chromium_code",
 
     # Must be after no_chromium_code for warning flags to be ordered
     # correctly.
     ":protobuf_warnings",
   ]
 
   if (is_win) {
     configs -= [ "//build/config/win:lean_and_mean" ]
   }
 
   public_configs = [
     ":protobuf_config",
 
     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
     "//build/config/compiler:no_size_t_to_int_warning",
   ]
 
   deps = [
     "//build/config/sanitizers:deps",
   ]
 
   cflags = protobuf_lite_cflags
 
+  if (is_component_build && is_linux && !is_chromeos) {
+    deps += [ ":protobuf_globals" ]
+  } else {
+    sources += [ "src/google/protobuf/globals.cc" ]
+  }
+
   # Required for component builds. See http://crbug.com/172800.
-  if (is_component_build) {
+  if (is_component_build && (!is_linux || is_chromeos)) {
     public_configs += [ ":protobuf_use_dlls" ]
     defines = [ "LIBPROTOBUF_EXPORTS" ]
   }
 }
 
 # This is the full, heavy protobuf lib that's needed for c++ .protos that don't
 # specify the LITE_RUNTIME option. The protocol compiler itself (protoc) falls
 # into that category. Do not use in Chrome code.
 static_library("protobuf_full") {
   # Prevent people from depending on this outside our file.
@@ skipping 28 matching lines @@
     "src/google/protobuf/dynamic_message.h",
     "src/google/protobuf/empty.pb.cc",
     "src/google/protobuf/empty.pb.h",
     "src/google/protobuf/extension_set_heavy.cc",
     "src/google/protobuf/field_mask.pb.cc",
     "src/google/protobuf/field_mask.pb.h",
     "src/google/protobuf/generated_enum_reflection.h",
     "src/google/protobuf/generated_enum_util.h",
     "src/google/protobuf/generated_message_reflection.cc",
     "src/google/protobuf/generated_message_reflection.h",
+    "src/google/protobuf/globals.cc",
 
     # gzip_stream.cc pulls in zlib, but it's not actually used by protoc, just
     # by test code, so instead of compiling zlib for the host, let's just
     # exclude this.
     # "src/google/protobuf/io/gzip_stream.cc",
     # "src/google/protobuf/io/gzip_stream.h",
 
     "src/google/protobuf/io/printer.cc",
     "src/google/protobuf/io/printer.h",
     "src/google/protobuf/io/strtod.cc",
@@ skipping 420 matching lines @@
     ":copy_google_protobuf_internal",
     ":copy_six",
   ]
 
   # Targets that depend on this should depend on the copied data files.
   data = get_target_outputs(":copy_google")
   data += get_target_outputs(":copy_six")
   data += get_target_outputs(":copy_google_protobuf")
   data += get_target_outputs(":copy_google_protobuf_internal")
 }