Adding mediator for Sign-in promo

ios/chrome/browser/ui/authentication/signin_promo_item.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/authentication/signin_promo_item.h"
+
+#include "base/logging.h"
+#import "ios/chrome/browser/ui/authentication/signin_promo_view.h"
+#import "ios/chrome/browser/ui/uikit_ui_util.h"
+#include "ios/chrome/grit/ios_chromium_strings.h"
+#include "ui/base/l10n/l10n_util.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@implementation SigninPromoItem
+
+@synthesize signinPromoViewConfigurator = _signinPromoViewConfigurator;
+
+- (instancetype)initWithType:(NSInteger)type
+    signinPromoViewConfigurator:
+        (id<SigninPromoViewConfigurator>)signinPromoViewConfigurator {
+  self = [super initWithType:type];
+  if (self) {
+    self.cellClass = [SigninPromoCell class];
+    _signinPromoViewConfigurator = signinPromoViewConfigurator;
+  }
+  return self;
+}
+
+- (instancetype)initWithType:(NSInteger)type {

[lpromero, 2017/03/24 10:36:19]

No need for this runtime check. The compiler already covers us. (It was not the
case in earlier SDKs I think.)

[jlebel, 2017/03/24 20:59:08]

Done.

+  NOTREACHED();
+  return nil;
+}
+
+#pragma mark - CollectionViewItem
+
+- (void)configureCell:(SigninPromoCell*)cell {
+  [super configureCell:cell];
+  cell.signinPromoView.textLabel.text =
+      l10n_util::GetNSString(IDS_IOS_SIGNIN_PROMO_SETTINGS);
+  [_signinPromoViewConfigurator configureSigninPromoView:cell.signinPromoView];
+}
+
+@end
+
+@implementation SigninPromoCell
+
+@synthesize signinPromoView = _signinPromoView;
+
+- (instancetype)initWithFrame:(CGRect)frame {
+  self = [super initWithFrame:frame];
+  if (self) {
+    [self addSubviews];

[msarda, 2017/03/22 12:18:38]

I think calling this method from the constructor is risky. Take the case that
somebody subclasses SigninPromoCell and adds its own method named addSubviews
(this is not impossible as adding subviews is common in a cell). When the
SigninPromoCellSubclass initializes the superclass, it will end up calling
addSubviews of the subclass and that will call a function of an partially
initialized object.

Seeing that the method addSubviews is very small and trivial (and never called
apart from the constructor), I would suggest inlining it here.

[lpromero, 2017/03/24 10:36:19]

Agreed. We have some instances of cells that use such helper methods, I should
have pushed back back then.

[jlebel, 2017/03/24 20:59:08]

Done.

+  }
+  return self;
+}
+
+- (void)addSubviews {
+  UIView* contentView = self.contentView;
+

[msarda, 2017/03/22 12:18:38]

Optional nit: Kill empty line.

[jlebel, 2017/03/24 20:59:08]

Done.

+  _signinPromoView = [[SigninPromoView alloc] initWithFrame:self.bounds];
+  [contentView addSubview:_signinPromoView];
+  AddSameSizeConstraint(_signinPromoView, contentView);
+}
+
+// Implements -layoutSubviews as per instructions in documentation for
+// +[MDCCollectionViewCell cr_preferredHeightForWidth:forItem:].
+- (void)layoutSubviews {
+  [super layoutSubviews];

[msarda, 2017/03/22 12:18:38]

Louis: Please take a look at this double call of layoutSubviews and let us know
if this is a common pattern for MDC (I have personally never seen this before).

[lpromero, 2017/03/24 10:36:19]

Correct, this is common pattern, as explained in the previous comment. The
reason is that this cell needs to support self-sizing, with labels of unlimited
number of lines.
https://www.objc.io/issues/3-views/advanced-auto-layout-toolbox/#intrinsic-co...

[jlebel, 2017/03/24 20:59:08]

Acknowledged.

+
+  // Adjust the text label preferredMaxLayoutWidth when the parent's width
+  // changes, for instance on screen rotation.

[lpromero, 2017/03/24 10:36:19]

Did you check in the material_cell_catalog that rotations (back and forth)
update correctly the layout and never clip the text? Consider testing with the
Double Length Strings pseudo language:
https://developer.apple.com/library/content/documentation/MacOSX/Conceptual/B...

[jlebel, 2017/03/24 20:59:08]

Nice tip! But it works like a charm (everything is centered).

+  CGFloat parentWidth = CGRectGetWidth(self.bounds);
+  _signinPromoView.textLabel.preferredMaxLayoutWidth =
+      parentWidth - 2 * _signinPromoView.horizontalPadding;
+
+  // Re-layout with the new preferred width to allow the label to adjust its
+  // height.
+  [super layoutSubviews];
+}
+
+@end