[ObjC ARC] Converts ios/chrome/browser/ui/bookmarks:bookmarks to ARC.

ios/chrome/browser/ui/bookmarks/bookmark_menu_view.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/bookmarks/bookmark_menu_view.h"
 
 #include <memory>
 
 #include "base/mac/foundation_util.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
+
 #include "components/bookmarks/browser/bookmark_model.h"
 #include "components/bookmarks/browser/bookmark_model_observer.h"
 #include "ios/chrome/browser/bookmarks/bookmark_model_factory.h"
 #include "ios/chrome/browser/bookmarks/bookmarks_utils.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/experimental_flags.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_menu_cell.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_menu_item.h"
 #include "ios/chrome/browser/ui/bookmarks/bookmark_model_bridge_observer.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_utils_ios.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Ink/src/MaterialInk.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/models/tree_node_iterator.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using bookmarks::BookmarkNode;
 
 @interface BookmarkMenuView ()<BookmarkModelBridgeObserver,
                                MDCInkTouchControllerDelegate,
                                UITableViewDataSource,
                                UITableViewDelegate> {
   // A bridge to receive bookmark model observer callbacks.
   std::unique_ptr<bookmarks::BookmarkModelBridge> _modelBridge;
-
-  base::mac::ObjCPropertyReleaser _propertyReleaser_BookmarkMenuView;
 }
 @property(nonatomic, assign) bookmarks::BookmarkModel* bookmarkModel;
 // This array directly represents the rows that show up in the table.
-@property(nonatomic, retain) NSMutableArray* menuItems;
+@property(nonatomic, strong) NSMutableArray* menuItems;
 // The primary menu item is blue instead of gray.
-@property(nonatomic, retain) BookmarkMenuItem* primaryMenuItem;
+@property(nonatomic, strong) BookmarkMenuItem* primaryMenuItem;
 @property(nonatomic, assign) ios::ChromeBrowserState* browserState;
-@property(nonatomic, retain) UITableView* tableView;
-@property(nonatomic, retain) MDCInkTouchController* inkTouchController;
+@property(nonatomic, strong) UITableView* tableView;
+@property(nonatomic, strong) MDCInkTouchController* inkTouchController;
 
 // Updates the data model, and the UI.
 - (void)reloadData;
 
 // Creates the views for this class.
 - (void)createViews;
 
 @end
 
 @implementation BookmarkMenuView
 @synthesize bookmarkModel = _bookmarkModel;
 @synthesize delegate = _delegate;
 @synthesize menuItems = _menuItems;
 @synthesize primaryMenuItem = _primaryMenuItem;
 @synthesize browserState = _browserState;
 @synthesize tableView = _tableView;
 @synthesize inkTouchController = _inkTouchController;
 
 - (id)initWithFrame:(CGRect)frame {
   NOTREACHED();
   return nil;
 }
 
 - (instancetype)initWithBrowserState:(ios::ChromeBrowserState*)browserState
                                frame:(CGRect)frame {
   self = [super initWithFrame:frame];
   if (self) {
-    _propertyReleaser_BookmarkMenuView.Init(self, [BookmarkMenuView class]);
-
     _browserState = browserState;
 
     // Set up connection to the BookmarkModel.
     _bookmarkModel =
         ios::BookmarkModelFactory::GetForBrowserState(_browserState);
     // Set up observers.
     _modelBridge.reset(
         new bookmarks::BookmarkModelBridge(self, _bookmarkModel));
 
     self.menuItems = [NSMutableArray array];
 
     [self createViews];
   }
   return self;
 }
 
 - (void)dealloc {
   self.tableView.delegate = nil;
   self.tableView.dataSource = nil;
-  [super dealloc];
 }
 
 - (void)createViews {
   // Make the table view.
-  self.tableView = base::scoped_nsobject<UITableView>(
-      [[UITableView alloc] initWithFrame:self.bounds]);
+  self.tableView = [[UITableView alloc] initWithFrame:self.bounds];
   [self addSubview:self.tableView];
   self.tableView.separatorStyle = UITableViewCellSeparatorStyleNone;
   self.tableView.delegate = self;
   self.tableView.dataSource = self;
   self.tableView.scrollsToTop = NO;
   [self reloadData];
 
   // Set up ink touch controller.
-  base::scoped_nsobject<MDCInkTouchController> inkTouchController(
-      [[MDCInkTouchController alloc] initWithView:self.tableView]);
+  MDCInkTouchController* inkTouchController =
+      [[MDCInkTouchController alloc] initWithView:self.tableView];
   self.inkTouchController = inkTouchController;
   self.inkTouchController.delegate = self;
   self.inkTouchController.delaysInkSpread = YES;
 }
 
 - (void)layoutSubviews {
   [super layoutSubviews];
   self.tableView.frame = self.bounds;
 }
 
 - (void)reloadData {
   if (!self.bookmarkModel->loaded())
     return;
 
   BookmarkMenuItem* primaryItem = [self.primaryMenuItem parentItem];
 
   [self.menuItems removeAllObjects];
 
   const BookmarkNode* mobileBookmarks = self.bookmarkModel->mobile_node();
   const BookmarkNode* bookmarkBar = self.bookmarkModel->bookmark_bar_node();
   const BookmarkNode* otherBookmarks = self.bookmarkModel->other_node();
 
   // The first section is always visible.
-  base::scoped_nsobject<NSMutableArray> topSection(
-      [[NSMutableArray alloc] init]);
+  NSMutableArray* topSection = [[NSMutableArray alloc] init];
   [self.menuItems addObject:topSection];
 
   // Mobile bookmark is shown even if empty.
   [topSection
       addObject:[BookmarkMenuItem folderMenuItemForNode:mobileBookmarks
                                            rootAncestor:mobileBookmarks]];
   // Bookmarks Bar and Other Bookmarks are special folders and are shown at the
   // top if they contain anything.
   if (!bookmarkBar->empty()) {
     [topSection addObject:[BookmarkMenuItem folderMenuItemForNode:bookmarkBar
                                                      rootAncestor:bookmarkBar]];
   }
   if (!otherBookmarks->empty()) {
     [topSection
         addObject:[BookmarkMenuItem folderMenuItemForNode:otherBookmarks
                                              rootAncestor:otherBookmarks]];
   }
 
   // The second section contains all the top level folders (except for the
   // permanent nodes).
-  base::scoped_nsobject<NSMutableArray> folderSection(
-      [[NSMutableArray alloc] init]);
+  NSMutableArray* folderSection = [[NSMutableArray alloc] init];
   std::vector<const BookmarkNode*> rootLevelFolders =
       RootLevelFolders(self.bookmarkModel);
   bookmark_utils_ios::SortFolders(&rootLevelFolders);
   for (auto* node : rootLevelFolders) {
     [folderSection addObject:[BookmarkMenuItem folderMenuItemForNode:node
                                                         rootAncestor:node]];
   }
   if ([folderSection count]) {
     // Add the title and the divider at the top of the section.
     [folderSection
@@ skipping 135 matching lines @@
   [self reloadData];
 }
 
 #pragma mark UITableViewDataSource
 
 - (UITableViewCell*)tableView:(UITableView*)tableView
         cellForRowAtIndexPath:(NSIndexPath*)indexPath {
   BookmarkMenuCell* cell = [tableView
       dequeueReusableCellWithIdentifier:[BookmarkMenuCell reuseIdentifier]];
   if (!cell) {
-    cell = [[[BookmarkMenuCell alloc]
+    cell = [[BookmarkMenuCell alloc]
           initWithStyle:UITableViewCellStyleDefault
-        reuseIdentifier:[BookmarkMenuCell reuseIdentifier]] autorelease];
+        reuseIdentifier:[BookmarkMenuCell reuseIdentifier]];
   }
   cell.selectionStyle = UITableViewCellSelectionStyleNone;
   BookmarkMenuItem* menuItem = [self menuItemAtIndexPath:indexPath];
   BOOL primary =
       [[self.primaryMenuItem parentItem] isEqual:[menuItem parentItem]];
   [cell updateWithBookmarkMenuItem:menuItem primary:primary];
   if (primary && bookmark_utils_ios::bookmarkMenuIsInSlideInPanel()) {
     [tableView selectRowAtIndexPath:indexPath
                            animated:NO
                      scrollPosition:UITableViewScrollPositionNone];
@@ skipping 36 matching lines @@
 }
 
 - (CGFloat)tableView:(UITableView*)tableView
     heightForFooterInSection:(NSInteger)section {
   BOOL isLastSection = [tableView numberOfSections] == (section + 1);
   return isLastSection ? 8.0 : 0.0;
 }
 
 - (UIView*)tableView:(UITableView*)tableView
     viewForHeaderInSection:(NSInteger)section {
-  return [[[UIView alloc] initWithFrame:CGRectZero] autorelease];
+  return [[UIView alloc] initWithFrame:CGRectZero];
 }
 
 - (UIView*)tableView:(UITableView*)tableView
     viewForFooterInSection:(NSInteger)section {
-  return [[[UIView alloc] initWithFrame:CGRectZero] autorelease];
+  return [[UIView alloc] initWithFrame:CGRectZero];
 }
 
 #pragma mark MDCInkTouchControllerDelegate
 
 - (BOOL)inkTouchController:(MDCInkTouchController*)inkTouchController
     shouldProcessInkTouchesAtTouchLocation:(CGPoint)location {
   NSIndexPath* indexPath = [self.tableView indexPathForRowAtPoint:location];
   BookmarkMenuItem* menuItem = [self menuItemAtIndexPath:indexPath];
   return menuItem.type == bookmarks::MenuItemFolder;
 }
@@ skipping 14 matching lines @@
 
   self.primaryMenuItem = menuItem;
   [self.tableView reloadData];
 }
 
 - (void)setScrollsToTop:(BOOL)scrollsToTop {
   self.tableView.scrollsToTop = scrollsToTop;
 }
 
 @end