[ObjC ARC] Converts ios/chrome/browser/ui/bookmarks:bookmarks_arc to ARC.

ios/chrome/browser/ui/bookmarks/bookmark_folder_view_controller.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/bookmarks/bookmark_folder_view_controller.h"
 
 #include <memory>
 #include <vector>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/bookmarks/browser/bookmark_model.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_folder_editor_view_controller.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_folder_table_view_cell.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_model_bridge_observer.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_navigation_controller.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_utils_ios.h"
 #import "ios/chrome/browser/ui/icons/chrome_icon.h"
 #import "ios/chrome/browser/ui/material_components/utils.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/AppBar/src/MaterialAppBar.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using bookmarks::BookmarkNode;
 
 namespace {
 
 // The height of every folder cell.
 const CGFloat kFolderCellHeight = 48.0;
 
 // Height of section headers/footers.
 const CGFloat kSectionHeaderHeight = 8.0;
 const CGFloat kSectionFooterHeight = 8.0;
@@ skipping 10 matching lines @@
 }  // namespace
 
 @interface BookmarkFolderViewController ()<
     BookmarkFolderEditorViewControllerDelegate,
     BookmarkModelBridgeObserver,
     UITableViewDataSource,
     UITableViewDelegate> {
   std::set<const BookmarkNode*> _editedNodes;
   std::vector<const BookmarkNode*> _folders;
   std::unique_ptr<bookmarks::BookmarkModelBridge> _modelBridge;
-  base::scoped_nsobject<MDCAppBar> _appBar;
-  base::mac::ObjCPropertyReleaser
-      _propertyReleaser_BookmarkFolderViewController;
+  MDCAppBar* _appBar;
 }
 
 // Should the controller setup Cancel and Done buttons instead of a back button.
 @property(nonatomic, assign) BOOL allowsCancel;
 
 // Should the controller setup a new-folder button.
 @property(nonatomic, assign) BOOL allowsNewFolders;
 
 // Reference to the main bookmark model.
 @property(nonatomic, assign) bookmarks::BookmarkModel* bookmarkModel;
 
 // The currently selected folder.
 @property(nonatomic, readonly) const BookmarkNode* selectedFolder;
 
 // The view controller to present when creating a new folder.
-@property(nonatomic, retain)
+@property(nonatomic, strong)
     BookmarkFolderEditorViewController* folderAddController;
 
 // A linear list of folders.
 @property(nonatomic, assign, readonly)
     const std::vector<const BookmarkNode*>& folders;
 
 // The table view that displays the options and folders.
-@property(nonatomic, retain) UITableView* tableView;
+@property(nonatomic, strong) UITableView* tableView;
 
 // Returns the cell for the default section and the given |row|.
 - (BookmarkFolderTableViewCell*)defaultSectionCellForRow:(NSInteger)row;
 
 // Returns a folder cell for the folder at |row| in |self.folders|.
 - (BookmarkFolderTableViewCell*)folderSectionCellForRow:(NSInteger)row;
 
 // Reloads the folder list.
 - (void)reloadFolders;
 
@@ skipping 25 matching lines @@
                      allowsNewFolders:(BOOL)allowsNewFolders
                           editedNodes:
                               (const std::set<const BookmarkNode*>&)nodes
                          allowsCancel:(BOOL)allowsCancel
                        selectedFolder:(const BookmarkNode*)selectedFolder {
   DCHECK(bookmarkModel);
   DCHECK(bookmarkModel->loaded());
   DCHECK(selectedFolder == NULL || selectedFolder->is_folder());
   self = [super initWithNibName:nil bundle:nil];
   if (self) {
-    _propertyReleaser_BookmarkFolderViewController.Init(
-        self, [BookmarkFolderViewController class]);
     _allowsCancel = allowsCancel;
     _allowsNewFolders = allowsNewFolders;
     _bookmarkModel = bookmarkModel;
     _editedNodes = nodes;
     _selectedFolder = selectedFolder;
 
     // Set up the bookmark model oberver.
     _modelBridge.reset(
         new bookmarks::BookmarkModelBridge(self, _bookmarkModel));
 
-    _appBar.reset([[MDCAppBar alloc] init]);
+    _appBar = [[MDCAppBar alloc] init];
     [self addChildViewController:[_appBar headerViewController]];
   }
   return self;
 }
 
 - (void)changeSelectedFolder:(const BookmarkNode*)selectedFolder {
   DCHECK(selectedFolder);
   DCHECK(selectedFolder->is_folder());
   _selectedFolder = selectedFolder;
   [self.tableView reloadData];
 }
 
 - (void)dealloc {
   _tableView.dataSource = nil;
   _tableView.delegate = nil;
   _folderAddController.delegate = nil;
-  [super dealloc];
 }
 
 - (UIStatusBarStyle)preferredStatusBarStyle {
   return UIStatusBarStyleDefault;
 }
 
 #pragma mark - View lifecycle
 
 - (void)viewDidLoad {
   [super viewDidLoad];
   if ([self respondsToSelector:@selector(setEdgesForExtendedLayout:)]) {
     [self setEdgesForExtendedLayout:UIRectEdgeNone];
   }
   self.view.backgroundColor = [UIColor whiteColor];
   self.view.accessibilityIdentifier = @"Folder Picker";
 
   self.title = l10n_util::GetNSString(IDS_IOS_BOOKMARK_CHOOSE_GROUP_BUTTON);
 
-  base::scoped_nsobject<UIBarButtonItem> doneItem([[UIBarButtonItem alloc]
+  UIBarButtonItem* doneItem = [[UIBarButtonItem alloc]
       initWithTitle:l10n_util::GetNSString(
                         IDS_IOS_BOOKMARK_EDIT_MODE_EXIT_MOBILE)
               style:UIBarButtonItemStylePlain
              target:self
-             action:@selector(done:)]);
-  doneItem.get().accessibilityIdentifier = @"Done";
+             action:@selector(done:)];
+  doneItem.accessibilityIdentifier = @"Done";
   self.navigationItem.rightBarButtonItem = doneItem;
 
   if (self.allowsCancel) {
     UIBarButtonItem* cancelItem =
         [ChromeIcon templateBarButtonItemWithImage:[ChromeIcon closeIcon]
                                             target:self
                                             action:@selector(cancel:)];
     cancelItem.accessibilityLabel =
         l10n_util::GetNSString(IDS_IOS_BOOKMARK_NEW_CANCEL_BUTTON_LABEL);
     cancelItem.accessibilityIdentifier = @"Cancel";
     self.navigationItem.leftBarButtonItem = cancelItem;
   } else {
     UIBarButtonItem* backItem =
         [ChromeIcon templateBarButtonItemWithImage:[ChromeIcon backIcon]
                                             target:self
                                             action:@selector(back:)];
     backItem.accessibilityLabel =
         l10n_util::GetNSString(IDS_IOS_BOOKMARK_NEW_BACK_LABEL);
     backItem.accessibilityIdentifier = @"Back";
     self.navigationItem.leftBarButtonItem = backItem;
   }
 
   // The table view.
-  base::scoped_nsobject<UITableView> tableView([[UITableView alloc]
-      initWithFrame:self.view.bounds
-              style:UITableViewStylePlain]);
-  tableView.get().dataSource = self;
-  tableView.get().delegate = self;
-  tableView.get().autoresizingMask =
+  UITableView* tableView =
+      [[UITableView alloc] initWithFrame:self.view.bounds
+                                   style:UITableViewStylePlain];
+  tableView.dataSource = self;
+  tableView.delegate = self;
+  tableView.autoresizingMask =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
-  tableView.get().separatorStyle = UITableViewCellSeparatorStyleNone;
+  tableView.separatorStyle = UITableViewCellSeparatorStyleNone;
   [self.view addSubview:tableView];
   [self.view sendSubviewToBack:tableView];
   self.tableView = tableView;
 
   // Add the app bar to the view hierarchy.  This must be done last, so that the
   // app bar's views are the frontmost.
   ConfigureAppBarWithCardStyle(_appBar);
   [_appBar headerViewController].headerView.trackingScrollView = self.tableView;
   [_appBar addSubviewsToParent];
 }
@@ skipping 105 matching lines @@
   }
   NOTREACHED();
   return 0;
 }
 
 - (UIView*)tableView:(UITableView*)tableView
     viewForHeaderInSection:(NSInteger)section {
   CGRect headerViewFrame =
       CGRectMake(0, 0, CGRectGetWidth(tableView.frame),
                  [self tableView:tableView heightForHeaderInSection:section]);
-  UIView* headerView =
-      [[[UIView alloc] initWithFrame:headerViewFrame] autorelease];
+  UIView* headerView = [[UIView alloc] initWithFrame:headerViewFrame];
   if (section == BookmarkFolderSectionFolders &&
       [self shouldShowDefaultSection]) {
     CGRect separatorFrame =
         CGRectMake(0, 0, CGRectGetWidth(headerView.bounds),
                    1.0 / [[UIScreen mainScreen] scale]);  // 1-pixel divider.
-    base::scoped_nsobject<UIView> separator(
-        [[UIView alloc] initWithFrame:separatorFrame]);
-    separator.get().autoresizingMask = UIViewAutoresizingFlexibleBottomMargin |
-                                       UIViewAutoresizingFlexibleWidth;
-    separator.get().backgroundColor = bookmark_utils_ios::separatorColor();
+    UIView* separator = [[UIView alloc] initWithFrame:separatorFrame];
+    separator.autoresizingMask = UIViewAutoresizingFlexibleBottomMargin |
+                                 UIViewAutoresizingFlexibleWidth;
+    separator.backgroundColor = bookmark_utils_ios::separatorColor();
     [headerView addSubview:separator];
   }
   return headerView;
 }
 
 - (CGFloat)tableView:(UITableView*)tableView
     heightForFooterInSection:(NSInteger)section {
   switch (static_cast<BookmarkFolderSection>(section)) {
     case BookmarkFolderSectionDefault:
       return [self shouldShowDefaultSection] ? kSectionFooterHeight : 0;
 
     case BookmarkFolderSectionFolders:
       return kSectionFooterHeight;
   }
   NOTREACHED();
   return 0;
 }
 
 - (UIView*)tableView:(UITableView*)tableView
     viewForFooterInSection:(NSInteger)section {
-  return [[[UIView alloc] init] autorelease];
+  return [[UIView alloc] init];
 }
 
 - (void)tableView:(UITableView*)tableView
     didSelectRowAtIndexPath:(NSIndexPath*)indexPath {
   [tableView deselectRowAtIndexPath:indexPath animated:YES];
   switch (static_cast<BookmarkFolderSection>(indexPath.section)) {
     case BookmarkFolderSectionDefault:
       [self pushFolderAddViewController];
       break;
 
@@ skipping 148 matching lines @@
       [BookmarkFolderEditorViewController
           folderCreatorWithBookmarkModel:self.bookmarkModel
                             parentFolder:self.selectedFolder];
   folderCreator.delegate = self;
   [self.navigationController pushViewController:folderCreator animated:YES];
   self.folderAddController = folderCreator;
 }
 
 - (void)delayedNotifyDelegateOfSelection {
   self.view.userInteractionEnabled = NO;
-  base::WeakNSObject<BookmarkFolderViewController> weakSelf(self);
+  __weak BookmarkFolderViewController* weakSelf = self;
   dispatch_after(
       dispatch_time(DISPATCH_TIME_NOW, (int64_t)(0.3 * NSEC_PER_SEC)),
       dispatch_get_main_queue(), ^{
-        base::scoped_nsobject<BookmarkFolderViewController> strongSelf(
-            [weakSelf retain]);
+        BookmarkFolderViewController* strongSelf = weakSelf;
         // Early return if the controller has been deallocated.
         if (!strongSelf)
           return;
-        strongSelf.get().view.userInteractionEnabled = YES;
+        strongSelf.view.userInteractionEnabled = YES;
         [strongSelf done:nil];
       });
 }
 
 @end