[ObjC ARC] Converts ios/chrome/browser/ui/bookmarks:bookmarks_arc to ARC.

ios/chrome/browser/ui/bookmarks/bookmark_home_handset_view_controller.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/bookmarks/bookmark_home_handset_view_controller.h"
 
 #include <memory>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
+

[lpromero, 2017/03/10 11:45:18]

Remove empty line.

[stkhapugin, 2017/03/10 12:16:38]

Done.

 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/bookmarks/browser/bookmark_model.h"
 #include "components/strings/grit/components_strings.h"
 #include "google_apis/gaia/google_service_auth_error.h"
 #include "ios/chrome/browser/bookmarks/bookmarks_utils.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #import "ios/chrome/browser/ui/alert_coordinator/action_sheet_coordinator.h"
 #import "ios/chrome/browser/ui/bookmarks/bars/bookmark_editing_bar.h"
@@ skipping 12 matching lines @@
 #import "ios/chrome/browser/ui/bookmarks/bookmark_panel_view.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_position_cache.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_promo_controller.h"
 #import "ios/chrome/browser/ui/bookmarks/bookmark_utils_ios.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using bookmarks::BookmarkNode;
 
 namespace {
 const CGFloat kBookmarkMenuWidth = 264;
 }  // namespace
 
 @interface BookmarkHomeHandsetViewController ()<
     BookmarkEditViewControllerDelegate,
     BookmarkFolderCollectionViewDelegate,
     BookmarkFolderEditorViewControllerDelegate,
     BookmarkFolderViewControllerDelegate,
     BookmarkMenuViewDelegate,
     BookmarkModelBridgeObserver,
     BookmarkPanelViewDelegate,
     BookmarkPromoControllerDelegate> {
   // Bridge to register for bookmark changes.
   std::unique_ptr<bookmarks::BookmarkModelBridge> _bridge;
-  base::mac::ObjCPropertyReleaser
-      _propertyReleaser_BookmarkHomeHandsetViewController;
 }
 
 // This views holds the primary content of this view controller. At any point in
 // time, it contains exactly one of the BookmarkCollectionView subclasses.
-@property(nonatomic, retain) UIView* contentView;
+@property(nonatomic, strong) UIView* contentView;
 // The possible views that can be shown from the menu.
-@property(nonatomic, retain) BookmarkFolderCollectionView* folderView;
+@property(nonatomic, strong) BookmarkFolderCollectionView* folderView;
 // This view is created and used if the model is not fully loaded yet by the
 // time this controller starts.
-@property(nonatomic, retain) BookmarkHomeWaitingView* waitForModelView;
+@property(nonatomic, strong) BookmarkHomeWaitingView* waitForModelView;
 
 // The menu with all the folders and special entries.
-@property(nonatomic, retain) BookmarkMenuView* menuView;
+@property(nonatomic, strong) BookmarkMenuView* menuView;
 // At any point in time, there is exactly one collection view whose view is part
 // of the view hierarchy. This property determine which collection view is
 // visible. Not by accident, this property also reflects the selected menu item
 // in the BookmarkMenuView.
-@property(nonatomic, retain) BookmarkMenuItem* primaryMenuItem;
+@property(nonatomic, strong) BookmarkMenuItem* primaryMenuItem;
 // When the view is first shown on the screen, this property represents the
 // cached value of the y of the content offset of the primary view. This
 // property is set to nil after it is used.
-@property(nonatomic, retain) NSNumber* cachedContentPosition;
+@property(nonatomic, strong) NSNumber* cachedContentPosition;
 
 // The navigation bar sits on top of the main content.
-@property(nonatomic, retain) BookmarkNavigationBar* navigationBar;
+@property(nonatomic, strong) BookmarkNavigationBar* navigationBar;
 // The layout code in this class relies on the assumption that the editingBar
 // has the same frame as the navigationBar.
-@property(nonatomic, retain) BookmarkEditingBar* editingBar;
+@property(nonatomic, strong) BookmarkEditingBar* editingBar;
 
 // The action sheet coordinator used when trying to edit a single bookmark.
-@property(nonatomic, retain) ActionSheetCoordinator* actionSheetCoordinator;
+@property(nonatomic, strong) ActionSheetCoordinator* actionSheetCoordinator;
 // The view controller used to view and edit a single bookmark.
-@property(nonatomic, retain) BookmarkEditViewController* editViewController;
+@property(nonatomic, strong) BookmarkEditViewController* editViewController;
 // The view controller used to pick a folder in which to move the selected
 // bookmarks.
-@property(nonatomic, retain) BookmarkFolderViewController* folderSelector;
+@property(nonatomic, strong) BookmarkFolderViewController* folderSelector;
 // The view controller to present when editing the current folder.
-@property(nonatomic, retain) BookmarkFolderEditorViewController* folderEditor;
+@property(nonatomic, strong) BookmarkFolderEditorViewController* folderEditor;
 #pragma mark Specific to this class.
 
 // The panel view slides on top of the content to display the menu.
-@property(nonatomic, retain) BookmarkPanelView* panelView;
+@property(nonatomic, strong) BookmarkPanelView* panelView;
 
 // Either the menu or the primaryView can scrollToTop.
 @property(nonatomic, assign) BOOL scrollingMenuToTop;
 // The controller managing the display of the promo cell and the promo view
 // controller.
-@property(nonatomic, retain) BookmarkPromoController* bookmarkPromoController;
+@property(nonatomic, strong) BookmarkPromoController* bookmarkPromoController;
 
 #pragma mark View loading and switching
 // This method is called if the view needs to be loaded and the model is not
 // ready yet.
 - (void)loadWaitingView;
 // This method should be called at most once in the life-cycle of the
 // class. It should be called at the soonest possible time after the
 // view has been loaded, and the bookmark model is loaded.
 - (void)loadBookmarkViews;
 // If the view doesn't exist, create it.
@@ skipping 110 matching lines @@
 @synthesize folderEditor = _folderEditor;
 
 @synthesize panelView = _panelView;
 @synthesize scrollingMenuToTop = _scrollingMenuToTop;
 @synthesize bookmarkPromoController = _bookmarkPromoController;
 
 - (instancetype)initWithLoader:(id<UrlLoader>)loader
                   browserState:(ios::ChromeBrowserState*)browserState {
   self = [super initWithLoader:loader browserState:browserState];
   if (self) {
-    _propertyReleaser_BookmarkHomeHandsetViewController.Init(
-        self, [BookmarkHomeHandsetViewController class]);
-
     _bridge.reset(new bookmarks::BookmarkModelBridge(self, self.bookmarks));
     // It is important to initialize the promo controller with the browser state
     // passed in, as it could be incognito.
     _bookmarkPromoController =
         [[BookmarkPromoController alloc] initWithBrowserState:browserState
                                                      delegate:self];
   }
   return self;
 }
 
 - (void)dealloc {
   _folderView.delegate = nil;
 
   _menuView.delegate = nil;
 
   _editViewController.delegate = nil;
   _folderSelector.delegate = nil;
 
   _panelView.delegate = nil;
-  [super dealloc];
 }
 
 - (void)removeEditNode:(const BookmarkNode*)node
                   cell:(UICollectionViewCell*)cell {
   [super removeEditNode:node atIndexPath:[self indexPathForCell:cell]];
   if (_editNodes.size() == 0)
     [self setEditing:NO animated:YES];
   else
     [self updateEditingStateAnimated:YES];
 }
 
 #pragma mark - UIViewController methods
 
 - (void)viewDidLoad {
   [super viewDidLoad];
 
-  base::scoped_nsobject<BookmarkNavigationBar> bar(
-      [[BookmarkNavigationBar alloc] initWithFrame:[self navigationBarFrame]]);
+  BookmarkNavigationBar* bar =
+      [[BookmarkNavigationBar alloc] initWithFrame:[self navigationBarFrame]];
   self.navigationBar = bar;
   [self.navigationBar setEditTarget:self
                              action:@selector(navigationBarWantsEditing:)];
   [self.navigationBar setMenuTarget:self
                              action:@selector(navigationBarToggledMenu:)];
   [self.navigationBar setBackTarget:self action:@selector(navigationBarBack:)];
   [self.navigationBar setCancelTarget:self
                                action:@selector(navigationBarCancel:)];
 
   [self.view addSubview:self.navigationBar];
@@ skipping 16 matching lines @@
   return YES;
 }
 
 #pragma mark - Methods duplicated from BookmarkHomeTabletNTPController.
 
 - (void)loadWaitingView {
   DCHECK(!self.waitForModelView);
   DCHECK([self isViewLoaded]);
 
   // Present a waiting view.
-  base::scoped_nsobject<BookmarkHomeWaitingView> waitingView(
-      [[BookmarkHomeWaitingView alloc] initWithFrame:self.view.bounds]);
+  BookmarkHomeWaitingView* waitingView =
+      [[BookmarkHomeWaitingView alloc] initWithFrame:self.view.bounds];
   self.waitForModelView = waitingView;
   [self.view addSubview:self.waitForModelView];
   [self.waitForModelView startWaiting];
 }
 
 - (void)loadBookmarkViews {
   DCHECK(self.bookmarks->loaded());
   DCHECK([self isViewLoaded]);
 
-  self.panelView = base::scoped_nsobject<BookmarkPanelView>(
+  self.panelView =
       [[BookmarkPanelView alloc] initWithFrame:[self frameForPrimaryView]
-                                 menuViewWidth:kBookmarkMenuWidth]);
+                                 menuViewWidth:kBookmarkMenuWidth];
   self.panelView.autoresizingMask =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
   self.panelView.delegate = self;
   [self.view insertSubview:self.panelView atIndex:0];
 
-  self.contentView = base::scoped_nsobject<UIView>([[UIView alloc] init]);
+  self.contentView = [[UIView alloc] init];
   self.contentView.frame = self.panelView.contentView.bounds;
   self.contentView.autoresizingMask =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
   [self.panelView.contentView addSubview:self.contentView];
 
   // The user can swipe the BookmarkPanelView to show the menuView.
   // Therefore, it must be created here.
-  self.menuView =
-      base::scoped_nsobject<BookmarkMenuView>([[BookmarkMenuView alloc]
-          initWithBrowserState:self.browserState
-                         frame:self.panelView.menuView.bounds]);
+  self.menuView = [[BookmarkMenuView alloc]
+      initWithBrowserState:self.browserState
+                     frame:self.panelView.menuView.bounds];
   self.menuView.delegate = self;
   [self.panelView.menuView addSubview:self.menuView];
   self.menuView.autoresizingMask =
       UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
 
   // Load the last primary menu item which the user had active.
   BookmarkMenuItem* item = nil;
   CGFloat position = 0;
   BOOL found =
       bookmark_utils_ios::GetPositionCache(self.bookmarks, &item, &position);
@@ skipping 12 matching lines @@
       // out.
       self.cachedContentPosition = [NSNumber numberWithFloat:position];
     }
   }
 }
 
 - (void)ensureFolderViewExists {
   if (self.folderView)
     return;
 
-  base::scoped_nsobject<BookmarkFolderCollectionView> view(
-      [[BookmarkFolderCollectionView alloc]
-          initWithBrowserState:self.browserState
-                         frame:[self frameForPrimaryView]]);
+  BookmarkFolderCollectionView* view = [[BookmarkFolderCollectionView alloc]
+      initWithBrowserState:self.browserState
+                     frame:[self frameForPrimaryView]];
   self.folderView = view;
   self.folderView.delegate = self;
   [self.folderView setEditing:self.editing animated:NO];
   self.folderView.autoresizingMask =
       UIViewAutoresizingFlexibleHeight | UIViewAutoresizingFlexibleWidth;
 }
 
 - (void)updatePrimaryMenuItem:(BookmarkMenuItem*)menuItem
                      animated:(BOOL)animated {
   DCHECK(menuItem.type == bookmarks::MenuItemFolder);
@@ skipping 35 matching lines @@
 
 - (void)updateEditingStateAnimated:(BOOL)animated {
   if (!self.editing) {
     [self hideEditingBarAnimated:animated];
     [self updateEditBarShadow];
     [self.panelView enableSideSwiping:YES];
     return;
   }
 
   if (!self.editingBar) {
-    self.editingBar = base::scoped_nsobject<BookmarkEditingBar>(
-        [[BookmarkEditingBar alloc] initWithFrame:self.navigationBar.frame]);
+    self.editingBar =
+        [[BookmarkEditingBar alloc] initWithFrame:self.navigationBar.frame];
     [self.editingBar setCancelTarget:self action:@selector(editingBarCancel)];
     [self.editingBar setDeleteTarget:self action:@selector(editingBarDelete)];
     [self.editingBar setMoveTarget:self action:@selector(editingBarMove)];
     [self.editingBar setEditTarget:self action:@selector(editingBarEdit)];
 
     [self.view addSubview:self.editingBar];
     self.editingBar.alpha = 0;
   }
 
   int bookmarkCount = 0;
@@ skipping 142 matching lines @@
       selectedUrlForNavigation:(const GURL&)url {
   [self delegateDismiss:url];
 }
 
 - (void)bookmarkCollectionView:(BookmarkCollectionView*)collectionView
           wantsMenuForBookmark:(const BookmarkNode*)node
                         onView:(UIView*)view
                        forCell:(BookmarkItemCell*)cell {
   DCHECK(!self.editViewController);
   DCHECK(!self.actionSheetCoordinator);
-  self.actionSheetCoordinator = [[[ActionSheetCoordinator alloc]
-      initWithBaseViewController:self
-                           title:nil
-                         message:nil
-                            rect:CGRectZero
-                            view:nil] autorelease];
-  base::WeakNSObject<BookmarkHomeHandsetViewController> weakSelf(self);
+  self.actionSheetCoordinator =
+      [[ActionSheetCoordinator alloc] initWithBaseViewController:self
+                                                           title:nil
+                                                         message:nil
+                                                            rect:CGRectZero
+                                                            view:nil];
+  __weak BookmarkHomeHandsetViewController* weakSelf = self;
 
   // Select action.
   [self.actionSheetCoordinator
       addItemWithTitle:l10n_util::GetNSString(IDS_IOS_BOOKMARK_ACTION_SELECT)
                 action:^{
                   [weakSelf selectFirstNode:node withCell:cell];
-                  weakSelf.get().actionSheetCoordinator = nil;
+                  weakSelf.actionSheetCoordinator = nil;
                 }
                  style:UIAlertActionStyleDefault];
 
   // Edit action.
   [self.actionSheetCoordinator
       addItemWithTitle:l10n_util::GetNSString(IDS_IOS_BOOKMARK_ACTION_EDIT)
                 action:^{
                   [weakSelf editNode:node];
-                  weakSelf.get().actionSheetCoordinator = nil;
+                  weakSelf.actionSheetCoordinator = nil;
                 }
                  style:UIAlertActionStyleDefault];
 
   // Move action.
   [self.actionSheetCoordinator
       addItemWithTitle:l10n_util::GetNSString(IDS_IOS_BOOKMARK_ACTION_MOVE)
                 action:^{
                   std::set<const BookmarkNode*> nodes;
                   nodes.insert(node);
                   [weakSelf moveNodes:nodes];
-                  weakSelf.get().actionSheetCoordinator = nil;
+                  weakSelf.actionSheetCoordinator = nil;
                 }
                  style:UIAlertActionStyleDefault];
 
   // Delete action.
   [self.actionSheetCoordinator
       addItemWithTitle:l10n_util::GetNSString(IDS_IOS_BOOKMARK_ACTION_DELETE)
                 action:^{
                   std::set<const BookmarkNode*> nodes;
                   nodes.insert(node);
                   [weakSelf deleteNodes:nodes];
-                  weakSelf.get().actionSheetCoordinator = nil;
+                  weakSelf.actionSheetCoordinator = nil;
                 }
                  style:UIAlertActionStyleDestructive];
 
   // Cancel action.
   [self.actionSheetCoordinator
       addItemWithTitle:l10n_util::GetNSString(IDS_CANCEL)
                 action:^{
-                  weakSelf.get().actionSheetCoordinator = nil;
+                  weakSelf.actionSheetCoordinator = nil;
                 }
                  style:UIAlertActionStyleCancel];
 
   [self.actionSheetCoordinator start];
 }
 
 - (void)bookmarkCollectionView:(BookmarkCollectionView*)view
               didLongPressCell:(UICollectionViewCell*)cell
                    forBookmark:(const BookmarkNode*)node {
   [self selectFirstNode:node withCell:cell];
@@ skipping 28 matching lines @@
   if (node->is_folder()) {
     BookmarkFolderEditorViewController* folderEditor =
         [BookmarkFolderEditorViewController
             folderEditorWithBookmarkModel:self.bookmarks
                                    folder:node
                              browserState:self.browserState];
     folderEditor.delegate = self;
     self.folderEditor = folderEditor;
     editorController = folderEditor;
   } else {
-    base::scoped_nsobject<BookmarkEditViewController> controller([
-        [BookmarkEditViewController alloc] initWithBookmark:node
-                                               browserState:self.browserState]);
+    BookmarkEditViewController* controller =
+        [[BookmarkEditViewController alloc] initWithBookmark:node
+                                                browserState:self.browserState];
     self.editViewController = controller;
     self.editViewController.delegate = self;
     editorController = self.editViewController;
   }
   DCHECK(editorController);
-  base::scoped_nsobject<UINavigationController> navController(
-      [[BookmarkNavigationController alloc]
-          initWithRootViewController:editorController]);
+  UINavigationController* navController = [[BookmarkNavigationController alloc]
+      initWithRootViewController:editorController];
   [navController setModalPresentationStyle:UIModalPresentationFormSheet];
   [self presentViewController:navController animated:YES completion:NULL];
 }
 
 - (void)moveNodes:(const std::set<const BookmarkNode*>&)nodes {
   DCHECK(!self.folderSelector);
   DCHECK(nodes.size() > 0);
   const BookmarkNode* editedNode = *(nodes.begin());
   const BookmarkNode* selectedFolder = editedNode->parent();
-  self.folderSelector = base::scoped_nsobject<BookmarkFolderViewController>(
-      [[BookmarkFolderViewController alloc]
-          initWithBookmarkModel:self.bookmarks
-               allowsNewFolders:YES
-                    editedNodes:nodes
-                   allowsCancel:YES
-                 selectedFolder:selectedFolder]);
+  self.folderSelector = [[BookmarkFolderViewController alloc]
+      initWithBookmarkModel:self.bookmarks
+           allowsNewFolders:YES
+                editedNodes:nodes
+               allowsCancel:YES
+             selectedFolder:selectedFolder];
   self.folderSelector.delegate = self;
-  base::scoped_nsobject<UINavigationController> navController(
-      [[BookmarkNavigationController alloc]
-          initWithRootViewController:self.folderSelector]);
+  UINavigationController* navController = [[BookmarkNavigationController alloc]
+      initWithRootViewController:self.folderSelector];
   [navController setModalPresentationStyle:UIModalPresentationFormSheet];
   [self presentViewController:navController animated:YES completion:NULL];
 }
 
 - (void)deleteNodes:(const std::set<const BookmarkNode*>&)nodes {
   DCHECK_GE(nodes.size(), 1u);
   bookmark_utils_ios::DeleteBookmarksWithUndoToast(nodes, self.bookmarks,
                                                    self.browserState);
 }
 
@@ skipping 144 matching lines @@
   DCHECK(self.primaryMenuItem.type == bookmarks::MenuItemFolder);
   const BookmarkNode* folder = self.primaryMenuItem.folder;
   BookmarkFolderEditorViewController* folderEditor =
       [BookmarkFolderEditorViewController
           folderEditorWithBookmarkModel:self.bookmarks
                                  folder:folder
                            browserState:self.browserState];
   folderEditor.delegate = self;
   self.folderEditor = folderEditor;
 
-  base::scoped_nsobject<BookmarkNavigationController> navController(
+  BookmarkNavigationController* navController =
       [[BookmarkNavigationController alloc]
-          initWithRootViewController:self.folderEditor]);
+          initWithRootViewController:self.folderEditor];
   [navController setModalPresentationStyle:UIModalPresentationFormSheet];
   [self presentViewController:navController animated:YES completion:NULL];
 }
 
 - (void)navigationBarCancel:(id)sender {
   [self delegateDismiss:GURL()];
 }
 
 - (void)navigationBarToggledMenu:(id)sender {
   if ([self.panelView userDrivenAnimationInProgress])
@@ skipping 95 matching lines @@
     [self.navigationBar updateEditButtonVisibility:0];
 }
 
 #pragma mark - BookmarkModelBridgeObserver
 
 - (void)bookmarkModelLoaded {
   if (![self isViewLoaded])
     return;
 
   DCHECK(self.waitForModelView);
-  base::WeakNSObject<BookmarkHomeHandsetViewController> weakSelf(self);
+  __weak BookmarkHomeHandsetViewController* weakSelf = self;
   [self.waitForModelView stopWaitingWithCompletion:^{
-    base::scoped_nsobject<BookmarkHomeHandsetViewController> strongSelf(
-        [weakSelf retain]);
+    BookmarkHomeHandsetViewController* strongSelf = weakSelf;
     // Early return if the controller has been deallocated.
     if (!strongSelf)
       return;
     [UIView animateWithDuration:0.2
         animations:^{
-          strongSelf.get().waitForModelView.alpha = 0.0;
+          strongSelf.waitForModelView.alpha = 0.0;
         }
         completion:^(BOOL finished) {
-          [strongSelf.get().waitForModelView removeFromSuperview];
-          strongSelf.get().waitForModelView = nil;
+          [strongSelf.waitForModelView removeFromSuperview];
+          strongSelf.waitForModelView = nil;
         }];
     [strongSelf loadBookmarkViews];
   }];
 }
 
 - (void)bookmarkNodeChanged:(const BookmarkNode*)node {
   // The title of the folder may have changed.
   if (self.primaryMenuItem.type == bookmarks::MenuItemFolder &&
       self.primaryMenuItem.folder == node) {
     UIInterfaceOrientation orient = GetInterfaceOrientation();
@@ skipping 83 matching lines @@
 }
 
 - (NSIndexPath*)indexPathForCell:(UICollectionViewCell*)cell {
   DCHECK([self primaryView].collectionView);
   NSIndexPath* indexPath =
       [[self primaryView].collectionView indexPathForCell:cell];
   return indexPath;
 }
 
 @end