[ios] Improve toolbar in tab_grid

ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.mm

Index: ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.mm
diff --git a/ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.mm b/ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.mm
new file mode 100644
index 0000000000000000000000000000000000000000..8f583b4a2250204f12ba610555a88961efd7487a
--- /dev/null
+++ b/ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.mm
@@ -0,0 +1,57 @@
+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/clean/chrome/browser/ui/tab_grid/tab_grid_toolbar.h"
+
+#import "ios/clean/chrome/browser/ui/tab_grid/ui_stack_view+cr_tab_grid.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+const CGFloat kToolbarHeight = 44.0f;
+}
+
+@implementation TabGridToolbar
+
+- (instancetype)init {
+  if (self = [super init]) {
+    UIVisualEffect* blurEffect =
+        [UIBlurEffect effectWithStyle:UIBlurEffectStyleDark];
+    UIVisualEffectView* toolbarView =
+        [[UIVisualEffectView alloc] initWithEffect:blurEffect];
+    toolbarView.autoresizingMask =
+        UIViewAutoresizingFlexibleWidth | UIViewAutoresizingFlexibleHeight;
+    [self addSubview:toolbarView];
+
+    UIStackView* toolbarContent = [UIStackView cr_tabGridToolbarStackView];
+    [toolbarView.contentView addSubview:toolbarContent];
+
+    // Sets the stackview to a fixed height, anchored to the bottom of the
+    // blur view.
+    toolbarContent.translatesAutoresizingMaskIntoConstraints = NO;
+    [NSLayoutConstraint activateConstraints:@[
+      [toolbarContent.heightAnchor constraintEqualToConstant:kToolbarHeight],

[marq (ping after 24h), 2017/03/02 06:04:54]

Is this constraint necessary, or can we just have |toolbarContent| also just
fill its superview vi autoresize mask, relying on the intrinsic content size of
|self| to end up with the correct height everywhere?

[edchin, 2017/03/02 07:12:44]

The VC which uses TabGridToolbar wants to visually position the toolbar below 
the status bar. If a status bar exists, the VC will expand the size of the
toolbar 
to include the height of the status bar. So the content must be anchored to the 
bottom of the canvas, so that the content is properly positioned even in the 
expanded view. And the content cannot just fill it's superview.

Keep in mind that UINavigationBar, UISearchBar, and UIToolbar automagically
handle the status bar height for you. But you then you have to use content 
such as UIBarButtonItem, rather than our custom content. This CL attempts to 
create the same status bar behavior as those classes. 

There may be a more idiomatic way to encapsulate this behavior through 
the UIBarPositioning protocol. The classes mentioned above rely on this 
protocol, and are able to grow/shrink their background based on the 
existence of a status bar. Currently, I do not know their internal
implementation,
and may explore this approach in the future.

+      [toolbarContent.leadingAnchor
+          constraintEqualToAnchor:toolbarView.contentView.leadingAnchor],
+      [toolbarContent.trailingAnchor
+          constraintEqualToAnchor:toolbarView.contentView.trailingAnchor],
+      [toolbarContent.bottomAnchor
+          constraintEqualToAnchor:toolbarView.contentView.bottomAnchor]
+    ]];
+  }
+  return self;
+}
+
+#pragma mark - UIView
+
+// Returns an intrinsic height so that explicit height constraints are
+// not necessary. Status bar conditional logic can be set using this
+// intrinsic size.
+- (CGSize)intrinsicContentSize {
+  return CGSizeMake(UIViewNoIntrinsicMetric, kToolbarHeight);
+}
+
+@end