Add JavaScript prompts support to CWVUIDelegate.

ios/web_view/internal/web_view_java_script_dialog_presenter.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/web_view/internal/web_view_java_script_dialog_presenter.h"
+
+#import "ios/web_view/public/cwv_ui_delegate.h"
+#import "net/base/mac/url_conversions.h"
+
+WebViewJavaScriptDialogPresenter::WebViewJavaScriptDialogPresenter(
+    CWVWebView* web_view,
+    id<CWVUIDelegate> ui_delegate)
+    : ui_delegate_(ui_delegate), web_view_(web_view) {}
+
+WebViewJavaScriptDialogPresenter::~WebViewJavaScriptDialogPresenter() = default;
+
+void WebViewJavaScriptDialogPresenter::RunJavaScriptDialog(
+    web::WebState* web_state,
+    const GURL& origin_url,
+    web::JavaScriptDialogType dialog_type,
+    NSString* message_text,
+    NSString* default_prompt_text,
+    const web::DialogClosedCallback& callback) {
+  switch (dialog_type) {
+    case web::JAVASCRIPT_DIALOG_TYPE_ALERT: {
+      if ([ui_delegate_ respondsToSelector:@selector

[Eugene But (OOO till 7-30), 2017/02/27 18:30:52]

This is quite a long method. Do you want to move the body of each case into
separate methods?

[michaeldo, 2017/02/27 21:35:51]

Done.

+                        (webView:runJavaScriptAlertPanelWithMessage:pageURL
+                                   :completionHandler:)]) {
+        web::DialogClosedCallback scoped_callback = callback;
+        [ui_delegate_ webView:web_view_
+            runJavaScriptAlertPanelWithMessage:message_text
+                                       pageURL:net::NSURLWithGURL(origin_url)
+                             completionHandler:^{
+                               if (!scoped_callback.is_null()) {
+                                 scoped_callback.Run(YES, nil);
+                               }
+                             }];
+      } else {
+        callback.Run(NO, nil);
+      }
+      break;
+    }
+    case web::JAVASCRIPT_DIALOG_TYPE_CONFIRM: {
+      if ([ui_delegate_ respondsToSelector:@selector
+                        (webView:runJavaScriptConfirmPanelWithMessage:pageURL
+                                   :completionHandler:)]) {
+        web::DialogClosedCallback scoped_callback = callback;
+        [ui_delegate_ webView:web_view_
+            runJavaScriptConfirmPanelWithMessage:message_text
+                                         pageURL:net::NSURLWithGURL(origin_url)
+                               completionHandler:^(BOOL is_confirmed) {
+                                 if (!scoped_callback.is_null()) {
+                                   scoped_callback.Run(is_confirmed, nil);
+                                 }
+                               }];
+      } else {
+        callback.Run(NO, nil);
+      }
+      break;
+    }
+    case web::JAVASCRIPT_DIALOG_TYPE_PROMPT: {
+      if ([ui_delegate_ respondsToSelector:@selector
+                        (webView:runJavaScriptTextInputPanelWithPrompt
+                                   :defaultText:pageURL:completionHandler:)]) {
+        web::DialogClosedCallback scoped_callback = callback;
+        [ui_delegate_ webView:web_view_
+            runJavaScriptTextInputPanelWithPrompt:message_text
+                                      defaultText:default_prompt_text
+                                          pageURL:net::NSURLWithGURL(origin_url)
+                                completionHandler:^(NSString* text_input) {
+                                  if (!scoped_callback.is_null()) {
+                                    if (text_input == nil) {
+                                      scoped_callback.Run(NO, nil);
+                                    } else {
+                                      scoped_callback.Run(YES, text_input);
+                                    }
+                                  }
+                                }];
+      } else {
+        callback.Run(NO, nil);
+      }
+      break;
+    }
+    default:
+      break;
+  }
+}
+
+void WebViewJavaScriptDialogPresenter::CancelDialogs(web::WebState* web_state) {
+  if ([ui_delegate_ respondsToSelector:@selector(cancelDialogsForWebView:)]) {
+    [ui_delegate_ cancelDialogsForWebView:web_view_];
+  }
+}
+
+void WebViewJavaScriptDialogPresenter::SetUIDelegate(
+    id<CWVUIDelegate> ui_delegate) {
+  ui_delegate_.reset(ui_delegate);
+}