Make patch_sdk step invoke fasta's compile_platform to generate patched_sdk/platform.dill.

runtime/vm/BUILD.gn

 # Copyright (c) 2014, the Dart project authors.  Please see the AUTHORS file
 # for details. All rights reserved. Use of this source code is governed by a
 # BSD-style license that can be found in the LICENSE file.
 
 import("../../build/executable_suffix.gni")
 import("../../build/prebuilt_dart_sdk.gni")
 import("gypi_contents.gni")
 import("../runtime_args.gni")
 
 config("libdart_vm_config") {
@@ skipping 388 matching lines @@
 
     # We list all files which make up the sdk (modulo patches) and get them
     # back as a GN list object.
     shared_sdk_sources = exec_script("../../tools/list_dart_files.py",
                                      [
                                        "absolute",
                                        rebase_path("../../sdk/lib"),
                                      ],
                                      "list lines")
 
+    front_end_sources = exec_script("../../tools/list_dart_files.py",
+                                    [
+                                      "absolute",
+                                      rebase_path("../../pkg/front_end"),
+                                    ],
+                                    "list lines")
+
+    kernel_sources = exec_script("../../tools/list_dart_files.py",

[kustermann, 2017/03/02 12:14:14]

These exec_script things have just broken the buildbot

The underlying issue that when one of the files returned here gets renamed or
removed, GN doesn't know it needs to rerun (and generate new ninja files)

It's described here:

https://chromium.googlesource.com/chromium/src/tools/gn/+/HEAD/docs/reference.md

Script input gotchas

  It may be tempting to write a script that enumerates all files in a directory
  as inputs. Don't do this! Even if you specify all the files in the inputs or
  sources in the GN target (or worse, enumerate the files in an exec_script
  call when running GN, which will be slow), the dependencies will be broken.

  The problem happens if a file is ever removed because the inputs are not
  listed on the command line to the script. Because the script hasn't changed
  and all inputs are up to date, the script will not re-run and you will get a
  stale build. Instead, either list all inputs on the command line to the
  script, or if there are many, create a separate list file that the script
  reads. As long as this file is listed in the inputs, the build will detect
  when it has changed in any way and the action will re-run.

+                                 [
+                                   "absolute",
+                                   rebase_path("../../pkg/kernel"),
+                                 ],
+                                 "list lines")
+
     # We list the `patch_sdk.dart` tool here because the [script] (which is
     # implicitly an input) will call it.
     inputs = [
       "../../tools/patch_sdk.dart",
     ]
 
     # Files below are not patches, they will not be in [concatenation_files]
     # but the `patch_sdk.dart` script will copy them into the patched sdk.
     inputs += [
       "../bin/builtin.dart",
       "../bin/vmservice/vmservice_io.dart",
       "../bin/vmservice/loader.dart",
       "../bin/vmservice/server.dart",
     ]
 
     # Add all the normal sdk sources.
     inputs += shared_sdk_sources
 
     # Add all the concatenated patch files.
     inputs += concatenation_files
 
+    # Add some front-end dependencies
+    inputs += front_end_sources
+    inputs += kernel_sources
+
     outputs = [
       # Instead of listing all outputs we list a single well-known one.
       "${patched_sdk_dir}/lib/core/core.dart",
     ]
 
     args = [ "--quiet" ]
     if (!prebuilt_dart_exe_works) {
       dart_out_dir = get_label_info("../bin:dart_bootstrap($host_toolchain)",
                                     "root_out_dir")
       dart_bootstrap =
           rebase_path("$dart_out_dir/dart_bootstrap$executable_suffix")
       args += [
         "--dart-executable",
         dart_bootstrap,
       ]
     }
     args += [
       "vm",
       rebase_path("../../sdk"),
       rebase_path(patches_dir, root_build_dir),
       rebase_path(patched_sdk_dir, root_build_dir),
+      rebase_path("../../.packages"),
     ]
   }
 }
 
 generate_patched_sdk("patched_sdk") {
   libraries = [
     [
       "async",
       processed_gypis.async_runtime_sources,
       "../lib",
@@ skipping 53 matching lines @@
       processed_gypis.vmservice_runtime_sources,
       "../lib",
     ],
     [
       "io",
       processed_gypis.bin_io_sources,
       "../bin",
     ],
   ]
 }