[ObjC ARC] Converts ios/chrome/browser/payments:payments to ARC.

ios/chrome/browser/payments/payment_request_coordinator.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/payments/payment_request_coordinator.h"
 
 #include <unordered_set>
 #include <vector>
 
-#import "base/ios/weak_nsobject.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/memory/weak_ptr.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/autofill/core/browser/autofill_client.h"
 #include "components/autofill/core/browser/autofill_data_util.h"
 #include "components/autofill/core/browser/autofill_profile.h"
 #include "components/autofill/core/browser/credit_card.h"
 #include "components/autofill/core/browser/field_types.h"
 #include "components/autofill/core/browser/payments/full_card_request.h"
 #include "components/autofill/core/browser/personal_data_manager.h"
 #include "components/autofill/core/browser/ui/card_unmask_prompt_controller_impl.h"
 #include "ios/chrome/browser/application_context.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/payments/payment_request.h"
 #include "ios/chrome/browser/payments/payment_request_util.h"
 #include "ios/chrome/browser/ui/autofill/card_unmask_prompt_view_bridge.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 // The unmask prompt UI for Payment Request.
 class PRCardUnmaskPromptViewBridge
     : public autofill::CardUnmaskPromptViewBridge {
  public:
   explicit PRCardUnmaskPromptViewBridge(
       autofill::CardUnmaskPromptController* controller,
       UIViewController* base_view_controller)
       : autofill::CardUnmaskPromptViewBridge(controller),
         base_view_controller_(base_view_controller){};

[sdefresne, 2017/02/21 17:22:35]

nit: remove trailing ;

[stkhapugin, 2017/02/22 17:47:06]

Done.

 
   // autofill::CardUnmaskPromptView:
   void Show() override {
     view_controller_.reset(
         [[CardUnmaskPromptViewController alloc] initWithBridge:this]);
     [base_view_controller_ presentViewController:view_controller_
                                         animated:YES
                                       completion:nil];
   };
 
  private:
-  UIViewController* base_view_controller_;  // Weak.
+  __weak UIViewController* base_view_controller_;
   DISALLOW_COPY_AND_ASSIGN(PRCardUnmaskPromptViewBridge);
 };
 
 // Receives the full credit card details. Also displays the unmask prompt UI.
 class FullCardRequester
     : public autofill::payments::FullCardRequest::ResultDelegate,
       public autofill::payments::FullCardRequest::UIDelegate,
       public base::SupportsWeakPtr<FullCardRequester> {
  public:
   explicit FullCardRequester(PaymentRequestCoordinator* owner,
@@ skipping 39 matching lines @@
         card, reason, delegate);
   }
 
   // payments::FullCardRequest::UIDelegate:
   void OnUnmaskVerificationResult(
       autofill::AutofillClient::PaymentsRpcResult result) override {
     unmask_controller_.OnVerificationResult(result);
   }
 
  private:
-  PaymentRequestCoordinator* owner_;        // Weak. Owns this instance.
-  UIViewController* base_view_controller_;  // Weak.
+  __weak PaymentRequestCoordinator* owner_;
+  __weak UIViewController* base_view_controller_;
   autofill::CardUnmaskPromptControllerImpl unmask_controller_;
 
   DISALLOW_COPY_AND_ASSIGN(FullCardRequester);
 };
 
-@interface PaymentRequestCoordinator () {
-  base::WeakNSProtocol<id<PaymentRequestCoordinatorDelegate>> _delegate;
-  base::scoped_nsobject<UINavigationController> _navigationController;
-  base::scoped_nsobject<PaymentRequestViewController> _viewController;
-  base::scoped_nsobject<PaymentItemsDisplayCoordinator>
-      _itemsDisplayCoordinator;
-  base::scoped_nsobject<ShippingAddressSelectionCoordinator>
-      _shippingAddressSelectionCoordinator;
-  base::scoped_nsobject<ShippingOptionSelectionCoordinator>
-      _shippingOptionSelectionCoordinator;
-  base::scoped_nsobject<PaymentMethodSelectionCoordinator>
-      _methodSelectionCoordinator;
+@implementation PaymentRequestCoordinator {
+  UINavigationController* _navigationController;
+  PaymentRequestViewController* _viewController;
+  PaymentItemsDisplayCoordinator* _itemsDisplayCoordinator;
+  ShippingAddressSelectionCoordinator* _shippingAddressSelectionCoordinator;
+  ShippingOptionSelectionCoordinator* _shippingOptionSelectionCoordinator;
+  PaymentMethodSelectionCoordinator* _methodSelectionCoordinator;
 
   // Receiver of the full credit card details. Also displays the unmask prompt
   // UI.
   std::unique_ptr<FullCardRequester> _fullCardRequester;
 
-  base::mac::ObjCPropertyReleaser _propertyReleaser_PaymentRequestCoordinator;
-}
-
-@end
-
-@implementation PaymentRequestCoordinator {
   // The selected shipping address, pending approval from the page.
   autofill::AutofillProfile* _pendingShippingAddress;
 }
 
 @synthesize paymentRequest = _paymentRequest;
 @synthesize autofillManager = _autofillManager;
 @synthesize browserState = _browserState;
 @synthesize pageFavicon = _pageFavicon;
 @synthesize pageTitle = _pageTitle;
 @synthesize pageHost = _pageHost;
+@synthesize delegate = _delegate;
 
-- (instancetype)initWithBaseViewController:
-    (UIViewController*)baseViewController {
-  if ((self = [super initWithBaseViewController:baseViewController])) {
-    _propertyReleaser_PaymentRequestCoordinator.Init(
-        self, [PaymentRequestCoordinator class]);
-  }
-  return self;
-}
-
-- (id<PaymentRequestCoordinatorDelegate>)delegate {
-  return _delegate.get();
-}
-
-- (void)setDelegate:(id<PaymentRequestCoordinatorDelegate>)delegate {
-  _delegate.reset(delegate);
+- (instancetype)initWithBaseViewController:(UIViewController*)viewController {

[sdefresne, 2017/02/21 17:22:35]

maybe remove this method as you're just forwarding to the base class now

[marq (ping after 24h), 2017/02/22 11:55:58]

+1

[stkhapugin, 2017/02/22 17:47:06]

I originally tried doing this (see patchset 2). However, because it's marked as
NS_DESIGNATED_INITIALIZER here but not on superclass, clang issues an error for
not explicitly implementing it. Since I assume NS_DESIGNATED_INITIALIZER is
desired, but is not desired on superclass, I didn't want to change the API so
I've implemented an empty init here. 

+  return [super initWithBaseViewController:viewController];
 }
 
 - (void)start {
-  _viewController.reset([[PaymentRequestViewController alloc]
-      initWithPaymentRequest:_paymentRequest]);
+  _viewController = [[PaymentRequestViewController alloc]
+      initWithPaymentRequest:_paymentRequest];
   [_viewController setPageFavicon:_pageFavicon];
   [_viewController setPageTitle:_pageTitle];
   [_viewController setPageHost:_pageHost];
   [_viewController setDelegate:self];
   [_viewController loadModel];
 
-  _navigationController.reset([[UINavigationController alloc]
-      initWithRootViewController:_viewController]);
+  _navigationController = [[UINavigationController alloc]
+      initWithRootViewController:_viewController];
   [_navigationController setNavigationBarHidden:YES];
 
   [[self baseViewController] presentViewController:_navigationController
                                           animated:YES
                                         completion:nil];
 }
 
 - (void)stop {
   [[_navigationController presentingViewController]
       dismissViewControllerAnimated:YES
                          completion:nil];
-  _itemsDisplayCoordinator.reset();
-  _shippingAddressSelectionCoordinator.reset();
-  _shippingOptionSelectionCoordinator.reset();
-  _methodSelectionCoordinator.reset();
-  _navigationController.reset();
-  _viewController.reset();
+  _itemsDisplayCoordinator = nil;
+  _shippingAddressSelectionCoordinator = nil;
+  _shippingOptionSelectionCoordinator = nil;
+  _methodSelectionCoordinator = nil;
+  _navigationController = nil;
+  _viewController = nil;
 }
 
 - (void)sendPaymentResponse {
   DCHECK(_paymentRequest->selected_credit_card());
   autofill::CreditCard* card = _paymentRequest->selected_credit_card();
   _fullCardRequester = base::MakeUnique<FullCardRequester>(
       self, _navigationController, _browserState);
   _fullCardRequester->GetFullCard(card, _autofillManager);
 }
 
@@ skipping 46 matching lines @@
 
     if (_shippingAddressSelectionCoordinator) {
       // Set the selected shipping address and update the selected shipping
       // address in the payment request summary view.
       _paymentRequest->set_selected_shipping_profile(_pendingShippingAddress);
       _pendingShippingAddress = nil;
       [_viewController updateSelectedShippingAddressUI];
 
       // Dismiss the shipping address selection view.
       [_shippingAddressSelectionCoordinator stop];
-      _shippingAddressSelectionCoordinator.reset();
+      _shippingAddressSelectionCoordinator = nil;
     } else if (_shippingOptionSelectionCoordinator) {
       // Update the selected shipping option in the payment request summary
       // view. The updated selection is already reflected in |_paymentRequest|.
       [_viewController updateSelectedShippingOptionUI];
 
       // Dismiss the shipping option selection view.
       [_shippingOptionSelectionCoordinator stop];
-      _shippingOptionSelectionCoordinator.reset();
+      _shippingOptionSelectionCoordinator = nil;
     }
   }
 }
 
 #pragma mark - PaymentRequestViewControllerDelegate
 
 - (void)paymentRequestViewControllerDidCancel:
     (PaymentRequestViewController*)controller {
   [_delegate paymentRequestCoordinatorDidCancel:self];
 }
 
 - (void)paymentRequestViewControllerDidConfirm:
     (PaymentRequestViewController*)controller {
   [self sendPaymentResponse];
 }
 
 - (void)paymentRequestViewControllerDidSelectPaymentSummaryItem:
     (PaymentRequestViewController*)controller {
-  _itemsDisplayCoordinator.reset([[PaymentItemsDisplayCoordinator alloc]
-      initWithBaseViewController:_viewController]);
+  _itemsDisplayCoordinator = [[PaymentItemsDisplayCoordinator alloc]
+      initWithBaseViewController:_viewController];
   [_itemsDisplayCoordinator setPaymentRequest:_paymentRequest];
   [_itemsDisplayCoordinator setDelegate:self];
 
   [_itemsDisplayCoordinator start];
 }
 
 - (void)paymentRequestViewControllerDidSelectShippingAddressItem:
     (PaymentRequestViewController*)controller {
-  _shippingAddressSelectionCoordinator.reset(
+  _shippingAddressSelectionCoordinator =
       [[ShippingAddressSelectionCoordinator alloc]
-          initWithBaseViewController:_viewController]);
+          initWithBaseViewController:_viewController];
   [_shippingAddressSelectionCoordinator setPaymentRequest:_paymentRequest];
   [_shippingAddressSelectionCoordinator setDelegate:self];
 
   [_shippingAddressSelectionCoordinator start];
 }
 
 - (void)paymentRequestViewControllerDidSelectShippingOptionItem:
     (PaymentRequestViewController*)controller {
-  _shippingOptionSelectionCoordinator.reset(
+  _shippingOptionSelectionCoordinator =
       [[ShippingOptionSelectionCoordinator alloc]
-          initWithBaseViewController:_viewController]);
+          initWithBaseViewController:_viewController];
   [_shippingOptionSelectionCoordinator setPaymentRequest:_paymentRequest];
   [_shippingOptionSelectionCoordinator setDelegate:self];
 
   [_shippingOptionSelectionCoordinator start];
 }
 
 - (void)paymentRequestViewControllerDidSelectPaymentMethodItem:
     (PaymentRequestViewController*)controller {
-  _methodSelectionCoordinator.reset([[PaymentMethodSelectionCoordinator alloc]
-      initWithBaseViewController:_viewController]);
+  _methodSelectionCoordinator = [[PaymentMethodSelectionCoordinator alloc]
+      initWithBaseViewController:_viewController];
   [_methodSelectionCoordinator setPaymentRequest:_paymentRequest];
   [_methodSelectionCoordinator setDelegate:self];
 
   [_methodSelectionCoordinator start];
 }
 
 #pragma mark - PaymentItemsDisplayCoordinatorDelegate
 
 - (void)paymentItemsDisplayCoordinatorDidReturn:
     (PaymentItemsDisplayCoordinator*)coordinator {
   // Clear the 'Updated' label on the payment summary item, if there is one.
   [_viewController updatePaymentSummaryWithTotalValueChanged:NO];
 
   [_itemsDisplayCoordinator stop];
-  _itemsDisplayCoordinator.reset();
+  _itemsDisplayCoordinator = nil;
 }
 
 - (void)paymentItemsDisplayCoordinatorDidConfirm:
     (PaymentItemsDisplayCoordinator*)coordinator {
   [self sendPaymentResponse];
 }
 
 #pragma mark - ShippingAddressSelectionCoordinatorDelegate
 
 - (void)shippingAddressSelectionCoordinator:
             (ShippingAddressSelectionCoordinator*)coordinator
                    didSelectShippingAddress:
                        (autofill::AutofillProfile*)shippingAddress {
   _pendingShippingAddress = shippingAddress;
 
   web::PaymentAddress address =
       payment_request_util::PaymentAddressFromAutofillProfile(shippingAddress);
   [_delegate paymentRequestCoordinator:self didSelectShippingAddress:address];
 }
 
 - (void)shippingAddressSelectionCoordinatorDidReturn:
     (ShippingAddressSelectionCoordinator*)coordinator {
   // Clear the 'Updated' label on the payment summary item, if there is one.
   [_viewController updatePaymentSummaryWithTotalValueChanged:NO];
 
   [_shippingAddressSelectionCoordinator stop];
-  _shippingAddressSelectionCoordinator.reset();
+  _shippingAddressSelectionCoordinator = nil;
 }
 
 #pragma mark - ShippingOptionSelectionCoordinatorDelegate
 
 - (void)shippingOptionSelectionCoordinator:
             (ShippingOptionSelectionCoordinator*)coordinator
                    didSelectShippingOption:
                        (web::PaymentShippingOption*)shippingOption {
   [_delegate paymentRequestCoordinator:self
                didSelectShippingOption:*shippingOption];
 }
 
 - (void)shippingOptionSelectionCoordinatorDidReturn:
     (ShippingAddressSelectionCoordinator*)coordinator {
   // Clear the 'Updated' label on the payment summary item, if there is one.
   [_viewController updatePaymentSummaryWithTotalValueChanged:NO];
 
   [_shippingOptionSelectionCoordinator stop];
-  _shippingOptionSelectionCoordinator.reset();
+  _shippingOptionSelectionCoordinator = nil;
 }
 
 #pragma mark - PaymentMethodSelectionCoordinatorDelegate
 
 - (void)paymentMethodSelectionCoordinator:
             (PaymentMethodSelectionCoordinator*)coordinator
                    didSelectPaymentMethod:(autofill::CreditCard*)creditCard {
   _paymentRequest->set_selected_credit_card(creditCard);
 
   [_viewController updateSelectedPaymentMethodUI];
 
   // Clear the 'Updated' label on the payment summary item, if there is one.
   [_viewController updatePaymentSummaryWithTotalValueChanged:NO];
 
   [_methodSelectionCoordinator stop];
-  _methodSelectionCoordinator.reset();
+  _methodSelectionCoordinator = nil;
 }
 
 - (void)paymentMethodSelectionCoordinatorDidReturn:
     (PaymentMethodSelectionCoordinator*)coordinator {
   // Clear the 'Updated' label on the payment summary item, if there is one.
   [_viewController updatePaymentSummaryWithTotalValueChanged:NO];
 
   [_methodSelectionCoordinator stop];
-  _methodSelectionCoordinator.reset();
+  _methodSelectionCoordinator = nil;
 }
 
 @end