[Mac] Add XPC alerts to GetDisplayedNotifications

chrome/browser/notifications/notification_platform_bridge_mac.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/notifications/notification_platform_bridge_mac.h"
 
 #include <utility>
 
 #include "base/bind.h"
 #include "base/bind_helpers.h"
@@ skipping 109 matching lines @@
 // A Cocoa class that represents the delegate of NSUserNotificationCenter and
 // can forward commands to C++.
 @interface NotificationCenterDelegate
     : NSObject<NSUserNotificationCenterDelegate> {
 }
 @end
 
 // Interface to communicate with the Alert XPC service.
 @interface AlertDispatcherImpl : NSObject<AlertDispatcher>
 
-// Deliver a notification to the XPC service to be displayed as an alert.
-- (void)dispatchNotification:(NSDictionary*)data;
-
-// Close a notification for a given |notificationId| and |profileId|.
-- (void)closeNotificationWithId:(NSString*)notificationId
-                  withProfileId:(NSString*)profileId;
-
-// Close all notifications.
-- (void)closeAllNotifications;
-
 @end
 
 // /////////////////////////////////////////////////////////////////////////////
 NotificationPlatformBridgeMac::NotificationPlatformBridgeMac(
     NSUserNotificationCenter* notification_center,
     id<AlertDispatcher> alert_dispatcher)
     : delegate_([NotificationCenterDelegate alloc]),
       notification_center_([notification_center retain]),
       alert_dispatcher_([alert_dispatcher retain]) {
   [notification_center_ setDelegate:delegate_.get()];
@@ skipping 136 matching lines @@
   if (!notification_removed) {
     [alert_dispatcher_ closeNotificationWithId:candidate_id
                                  withProfileId:current_profile_id];
   }
 #endif  // ENABLE_XPC_NOTIFICATIONS
 }
 
 void NotificationPlatformBridgeMac::GetDisplayed(
     const std::string& profile_id,
     bool incognito,
-    const DisplayedNotificationsCallback& callback) const {
+    const GetDisplayedNotificationsCallback& callback) const {
+#if BUILDFLAG(ENABLE_XPC_NOTIFICATIONS)
+  [alert_dispatcher_
+      getDisplayedAlertsForProfileId:base::SysUTF8ToNSString(profile_id)
+                           incognito:incognito
+                  notificationCenter:notification_center_
+                            callback:callback];
+
+#else
+
   auto displayed_notifications = base::MakeUnique<std::set<std::string>>();
   NSString* current_profile_id = base::SysUTF8ToNSString(profile_id);
   for (NSUserNotification* toast in
        [notification_center_ deliveredNotifications]) {
     NSString* toast_profile_id = [toast.userInfo
         objectForKey:notification_constants::kNotificationProfileId];
-    if ([toast_profile_id isEqualToString:current_profile_id]) {
+    BOOL incognito_notification = [[toast.userInfo
+        objectForKey:notification_constants::kNotificationIncognito] boolValue];
+    if ([toast_profile_id isEqualToString:current_profile_id] &&
+        incognito == incognito_notification) {
       displayed_notifications->insert(base::SysNSStringToUTF8([toast.userInfo
           objectForKey:notification_constants::kNotificationId]));
     }
   }
   content::BrowserThread::PostTask(
       content::BrowserThread::UI, FROM_HERE,
       base::Bind(callback, base::Passed(&displayed_notifications),
                  true /* supports_synchronization */));
+
+#endif  // ENABLE_XPC_NOTIFICATIONS
 }
 
 // static
 void NotificationPlatformBridgeMac::ProcessNotificationResponse(
     NSDictionary* response) {
   if (!NotificationPlatformBridgeMac::VerifyNotificationData(response))
     return;
 
   NSNumber* button_index =
       [response objectForKey:notification_constants::kNotificationButtonIndex];
@@ skipping 161 matching lines @@
 
     xpcConnection_.get().exportedInterface =
         [NSXPCInterface interfaceWithProtocol:@protocol(NotificationReply)];
     xpcConnection_.get().exportedObject = self;
     [xpcConnection_ resume];
   }
 
   return self;
 }
 
+// AlertDispatcher:
 - (void)dispatchNotification:(NSDictionary*)data {
   [[self serviceProxy] deliverNotification:data];
 }
 
 - (void)closeNotificationWithId:(NSString*)notificationId
                   withProfileId:(NSString*)profileId {
   [[self serviceProxy] closeNotificationWithId:notificationId
                                  withProfileId:profileId];
 }
 
 - (void)closeAllNotifications {
   [[self serviceProxy] closeAllNotifications];
 }
 
+- (void)
+getDisplayedAlertsForProfileId:(NSString*)profileId
+                     incognito:(BOOL)incognito
+            notificationCenter:(NSUserNotificationCenter*)notificationCenter
+                      callback:(GetDisplayedNotificationsCallback)callback {
+  auto reply = ^(NSArray* alerts) {
+    std::unique_ptr<std::set<std::string>> displayedNotifications =
+        base::MakeUnique<std::set<std::string>>();
+
+    for (NSUserNotification* toast in
+         [notificationCenter deliveredNotifications]) {
+      NSString* toastProfileId = [toast.userInfo
+          objectForKey:notification_constants::kNotificationProfileId];
+      BOOL incognitoNotification = [[toast.userInfo
+          objectForKey:notification_constants::kNotificationIncognito]
+          boolValue];
+      if ([toastProfileId isEqualToString:profileId] &&
+          incognito == incognitoNotification) {
+        displayedNotifications->insert(base::SysNSStringToUTF8([toast.userInfo
+            objectForKey:notification_constants::kNotificationId]));
+      }
+    }
+
+    for (NSString* alert in alerts)
+      displayedNotifications->insert(base::SysNSStringToUTF8(alert));
+
+    content::BrowserThread::PostTask(
+        content::BrowserThread::UI, FROM_HERE,
+        base::Bind(callback, base::Passed(&displayedNotifications),
+                   true /* supports_synchronization */));
+  };
+
+  [[self serviceProxy] getDisplayedAlertsForProfileId:profileId
+                                         andIncognito:incognito
+                                            withReply:reply];
+}
+
 // NotificationReply:
 - (void)notificationClick:(NSDictionary*)notificationResponseData {
   NotificationPlatformBridgeMac::ProcessNotificationResponse(
       notificationResponseData);
 }
 
 // Private methods:
 
 // Retrieves the connection's remoteObjectProxy. Always use this as opposed
 // to going directly through the connection, since this will ensure that the
 // service has its exception port configured for crash reporting.
 - (id<NotificationDelivery>)serviceProxy {
   id<NotificationDelivery> proxy = [xpcConnection_ remoteObjectProxy];
 
   if (!setExceptionPort_) {
     base::mac::ScopedMachSendRight exceptionPort(
         crash_reporter::GetCrashpadClient().GetHandlerMachPort());
     base::scoped_nsobject<CrXPCMachPort> xpcPort(
         [[CrXPCMachPort alloc] initWithMachSendRight:std::move(exceptionPort)]);
     [proxy setMachExceptionPort:xpcPort];
     setExceptionPort_ = YES;
   }
 
   return proxy;
 }
 
 @end