[ObjC ARC] Converts ios/chrome/browser/ui/omnibox:omnibox_internal to ARC.

ios/chrome/browser/ui/omnibox/page_info_view_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/omnibox/page_info_view_controller.h"
 
 #include "base/bind.h"
 #include "base/location.h"
 #include "base/mac/bundle_locations.h"
 #import "base/mac/foundation_util.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/message_loop/message_loop.h"
 #include "base/single_thread_task_runner.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/threading/thread_task_runner_handle.h"
 #include "components/strings/grit/components_strings.h"
 #import "ios/chrome/browser/ui/animation_util.h"
 #import "ios/chrome/browser/ui/commands/UIKit+ChromeExecuteCommand.h"
 #include "ios/chrome/browser/ui/commands/ios_command_ids.h"
 #import "ios/chrome/browser/ui/fancy_ui/bidi_container_view.h"
 #include "ios/chrome/browser/ui/omnibox/page_info_model.h"
 #import "ios/chrome/browser/ui/popup_menu/popup_menu_view.h"
 #include "ios/chrome/browser/ui/rtl_geometry.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #import "ios/chrome/common/material_timing.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Typography/src/MaterialTypography.h"
 #import "ios/third_party/material_roboto_font_loader_ios/src/src/MaterialRobotoFontLoader.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #import "ui/gfx/ios/NSString+CrStringDrawing.h"
 #import "ui/gfx/ios/uikit_util.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using ios::material::TimingFunction;
 
 namespace {
 
 // The width of the view.
 const CGFloat kViewWidthRegular = 600.0;
 const CGFloat kViewWidthCompact = 288.0;
 const CGFloat kViewWidthiPhoneLandscape = 400.0;
 // Spacing in between sections.
 const CGFloat kVerticalSpacing = 20.0;
@@ skipping 76 matching lines @@
   // can be delivered.
   base::ThreadTaskRunnerHandle::Get()->PostDelayedTask(
       FROM_HERE, base::Bind(&PageInfoModelBubbleBridge::PerformLayout,
                             weak_ptr_factory_.GetWeakPtr()),
       base::TimeDelta::FromMilliseconds(1000 /* milliseconds */));
 }
 
 @interface PageInfoViewController ()<UIGestureRecognizerDelegate> {
   // Scroll View inside the PageInfoView used to display content that exceeds
   // the available space.
-  base::scoped_nsobject<UIScrollView> scrollView_;
+  UIScrollView* scrollView_;
   // Container View added inside the Scroll View. All content is added to this
   // view instead of PopupMenuController.containerView_.
-  base::scoped_nsobject<BidiContainerView> innerContainerView_;
+  BidiContainerView* innerContainerView_;
 
   // Origin of the arrow at the top of the popup window.
   CGPoint origin_;
 
   // Model for the data to display.
   std::unique_ptr<PageInfoModel> model_;
 
   // Thin bridge that pushes model-changed notifications from C++ to Cocoa.
   std::unique_ptr<PageInfoModelObserver> bridge_;
 
   // Width of the view. Depends on the device (iPad/iPhone).
   CGFloat viewWidth_;
 
   // Width of the text fields.
   CGFloat textWidth_;
 
   // YES when the popup has finished animating in. NO otherwise.
   BOOL animateInCompleted_;
-
-  base::mac::ObjCPropertyReleaser propertyReleaser_PageInfoViewController_;
 }
 
 // Adds the state image at a pre-determined x position and the given y. This
 // does not affect the next Y position because the image is placed next to
 // a text field that is larger and accounts for the image's size.
 - (void)addImageViewForInfo:(const PageInfoModel::SectionInfo&)info
                  toSubviews:(NSMutableArray*)subviews
                    atOffset:(CGFloat)offset;
 
 // Adds the title text field at the given x,y position, and returns the y
@@ skipping 10 matching lines @@
 
 // Returns a button with title and action configured for |buttonAction|.
 - (UIButton*)buttonForAction:(PageInfoModel::ButtonAction)buttonAction;
 
 // Adds the the button |buttonAction| that explains the icons. Returns the y
 // position delta for the next offset.
 - (CGFloat)addButton:(PageInfoModel::ButtonAction)buttonAction
           toSubviews:(NSMutableArray*)subviews
             atOffset:(CGFloat)offset;
 
-@property(nonatomic, retain) UIView* containerView;
-@property(nonatomic, retain) UIView* popupContainer;
+@property(nonatomic, strong) UIView* containerView;
+@property(nonatomic, strong) UIView* popupContainer;
 @end
 
 @implementation PageInfoViewController
 
 @synthesize containerView = containerView_;
 @synthesize popupContainer = popupContainer_;
 
 - (id)initWithModel:(PageInfoModel*)model
              bridge:(PageInfoModelObserver*)bridge
         sourceFrame:(CGRect)source
          parentView:(UIView*)parent {
   DCHECK(parent);
   self = [super init];
   if (self) {
-    propertyReleaser_PageInfoViewController_.Init(
-        self, [PageInfoViewController class]);
-
-    scrollView_.reset(
-        [[UIScrollView alloc] initWithFrame:CGRectMake(0, 0, 240, 128)]);
+    scrollView_ =
+        [[UIScrollView alloc] initWithFrame:CGRectMake(0, 0, 240, 128)];
     [scrollView_ setMultipleTouchEnabled:YES];
     [scrollView_ setClipsToBounds:YES];
     [scrollView_ setShowsHorizontalScrollIndicator:NO];
     [scrollView_ setIndicatorStyle:UIScrollViewIndicatorStyleBlack];
     [scrollView_
         setAutoresizingMask:(UIViewAutoresizingFlexibleTrailingMargin() |
                              UIViewAutoresizingFlexibleTopMargin)];
 
-    innerContainerView_.reset(
-        [[BidiContainerView alloc] initWithFrame:CGRectMake(0, 0, 194, 327)]);
+    innerContainerView_ =
+        [[BidiContainerView alloc] initWithFrame:CGRectMake(0, 0, 194, 327)];
     [innerContainerView_ setBackgroundColor:[UIColor clearColor]];
     [innerContainerView_
         setAccessibilityLabel:@"Page Security Info Scroll Container"];
     [innerContainerView_
         setAutoresizingMask:(UIViewAutoresizingFlexibleTrailingMargin() |
                              UIViewAutoresizingFlexibleBottomMargin)];
 
     model_.reset(model);
     bridge_.reset(bridge);
     origin_ = CGPointMake(CGRectGetMidX(source), CGRectGetMaxY(source));
 
     UIInterfaceOrientation orientation =
         [[UIApplication sharedApplication] statusBarOrientation];
     viewWidth_ = IsCompact() ? kViewWidthCompact : kViewWidthRegular;
     // Special case iPhone landscape.
     if (!IsIPadIdiom() && UIInterfaceOrientationIsLandscape(orientation))
       viewWidth_ = kViewWidthiPhoneLandscape;
 
     textWidth_ = viewWidth_ - (kImageSize + kImageSpacing + kFramePadding * 2 +
                                kScrollViewInset * 2);
 
-    base::scoped_nsobject<UILongPressGestureRecognizer> touchDownRecognizer(
+    UILongPressGestureRecognizer* touchDownRecognizer =
         [[UILongPressGestureRecognizer alloc]
             initWithTarget:self
-                    action:@selector(rootViewTapped:)]);
+                    action:@selector(rootViewTapped:)];
     // Setting the duration to .001 makes this similar to a control event
     // UIControlEventTouchDown.
     [touchDownRecognizer setMinimumPressDuration:.001];
     [touchDownRecognizer setDelegate:self];
 
     containerView_ = [[UIView alloc] initWithFrame:[parent bounds]];
     [containerView_ addGestureRecognizer:touchDownRecognizer];
     [containerView_
         setBackgroundColor:[UIColor colorWithWhite:0 alpha:kShieldAlpha]];
     [containerView_ setTag:IDC_HIDE_PAGE_INFO];
@@ skipping 136 matching lines @@
 
   for (UIView* view in [innerContainerView_ subviews]) {
     [view removeFromSuperview];
   }
 
   for (UIView* view in subviews) {
     [innerContainerView_ addSubview:view];
     [innerContainerView_ setSubviewNeedsAdjustmentForRTL:view];
   }
 
-  [scrollView_ setContentSize:innerContainerView_.get().frame.size];
+  [scrollView_ setContentSize:innerContainerView_.frame.size];
 }
 
 - (void)dismiss {
   [self animatePageInfoViewOut];
   UIAccessibilityPostNotification(UIAccessibilityLayoutChangedNotification,
                                   nil);
 }
 
 #pragma mark - Helper methods to create subviews.
 
 - (void)addImageViewForInfo:(const PageInfoModel::SectionInfo&)info
                  toSubviews:(NSMutableArray*)subviews
                    atOffset:(CGFloat)offset {
   CGRect frame = CGRectMake(kFramePadding, offset, kImageSize, kImageSize);
-  base::scoped_nsobject<UIImageView> imageView(
-      [[UIImageView alloc] initWithFrame:frame]);
+  UIImageView* imageView = [[UIImageView alloc] initWithFrame:frame];
   [imageView setImage:model_->GetIconImage(info.icon_id)->ToUIImage()];
-  [subviews addObject:imageView.get()];
+  [subviews addObject:imageView];
 }
 
 - (CGFloat)addHeadlineViewForInfo:(const PageInfoModel::SectionInfo&)info
                        toSubviews:(NSMutableArray*)subviews
                           atPoint:(CGPoint)point {
   CGRect frame = CGRectMake(point.x, point.y, textWidth_, kHeadlineHeight);
-  base::scoped_nsobject<UILabel> label([[UILabel alloc] initWithFrame:frame]);
+  UILabel* label = [[UILabel alloc] initWithFrame:frame];
   [label setTextAlignment:NSTextAlignmentNatural];
   [label setText:base::SysUTF16ToNSString(info.headline)];
   [label setTextColor:PageInfoTextColor()];
   [label setFont:PageInfoHeadlineFont()];
   [label setBackgroundColor:[UIColor clearColor]];
   [label setFrame:frame];
   [label setLineBreakMode:NSLineBreakByTruncatingHead];
-  [subviews addObject:label.get()];
+  [subviews addObject:label];
   return CGRectGetHeight(frame);
 }
 
 - (CGFloat)addDescriptionViewForInfo:(const PageInfoModel::SectionInfo&)info
                           toSubviews:(NSMutableArray*)subviews
                              atPoint:(CGPoint)point {
   CGRect frame = CGRectMake(point.x, point.y, textWidth_, kImageSize);
-  base::scoped_nsobject<UILabel> label([[UILabel alloc] initWithFrame:frame]);
+  UILabel* label = [[UILabel alloc] initWithFrame:frame];
   [label setTextAlignment:NSTextAlignmentNatural];
   NSString* description = base::SysUTF16ToNSString(info.description);
   UIFont* font = [MDCTypography captionFont];
   [label setTextColor:PageInfoTextColor()];
   [label setText:description];
   [label setFont:font];
   [label setNumberOfLines:0];
   [label setBackgroundColor:[UIColor clearColor]];
 
   // If the text is oversized, resize the text field.
   CGSize constraintSize = CGSizeMake(textWidth_, CGFLOAT_MAX);
   CGSize sizeToFit =
       [description cr_boundingSizeWithSize:constraintSize font:font];
   frame.size.height = sizeToFit.height;
   [label setFrame:frame];
-  [subviews addObject:label.get()];
+  [subviews addObject:label];
   return CGRectGetHeight(frame);
 }
 
 - (UIButton*)buttonForAction:(PageInfoModel::ButtonAction)buttonAction {
   if (buttonAction == PageInfoModel::BUTTON_NONE) {
     return nil;
   }
-  UIButton* button = [[[UIButton alloc] initWithFrame:CGRectZero] autorelease];
+  UIButton* button = [[UIButton alloc] initWithFrame:CGRectZero];
   int messageId = IDS_IOS_PAGE_INFO_RELOAD;
   NSInteger tag = IDC_RELOAD;
   NSString* accessibilityID = @"Reload button";
   switch (buttonAction) {
     case PageInfoModel::BUTTON_NONE:
       NOTREACHED();
       return nil;
     case PageInfoModel::BUTTON_SHOW_SECURITY_HELP:
       messageId = IDS_LEARN_MORE;
       tag = IDC_SHOW_SECURITY_HELP;
@@ skipping 154 matching lines @@
   [opacityAnimation setFromValue:@1];
   [opacityAnimation setToValue:@0];
   [[containerView_ layer] addAnimation:opacityAnimation forKey:@"animateOut"];
 
   [popupContainer_ setAlpha:0];
   [containerView_ setAlpha:0];
   [CATransaction commit];
 }
 
 @end