Add Category wrapper for ContentSuggestions on iOS

ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.mm

Index: ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.mm
diff --git a/ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.mm b/ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.mm
new file mode 100644
index 0000000000000000000000000000000000000000..c7c2b7488003ac7bb0609d30609e642c12a20c5c
--- /dev/null
+++ b/ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.mm
@@ -0,0 +1,56 @@
+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/content_suggestions/content_suggestions_category_wrapper.h"
+
+#include "base/mac/foundation_util.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@implementation ContentSuggestionsCategoryWrapper {
+  int _categoryID;

[stkhapugin, 2017/02/13 12:19:18]

Since this is a primitive and not a C++ object, you can use a property instead
of an ivar for a more modern syntax. 

[gambard, 2017/02/13 14:51:41]

Done.

+}
+
+- (instancetype)initWithCategory:(ntp_snippets::Category)category {
+  self = [super init];
+  if (self) {
+    _categoryID = category.id();
+  }
+  return self;
+}
+
+- (BOOL)isEqual:(id)object {
+  if (self == object) {
+    return YES;
+  }
+
+  if (![object isKindOfClass:[ContentSuggestionsCategoryWrapper class]]) {

[stkhapugin, 2017/02/13 12:19:18]

s/isKindOfClass/isMemberOfClass

[lpromero, 2017/02/13 12:34:55]

Why? Subclassing would mean two objects couldn't be equals as is.

[stkhapugin, 2017/02/13 13:31:38]

Since subclasses are generally different from their superclasses, I've been
always taught that the default behaviour should be subclass != parent, unless
you know you have a special case. But I see now that both opinions are popular
and there's no particular consensus in ObjC community. 

[lpromero, 2017/02/13 13:55:32]

I don't have any particular point of view on this. It's what semantic you want
to give to equality.

If self and class are both instances of a same subclass, the isMemberOfClass
impl breaks too. If the semantic you want is having the same class, then the
check should be self.class == object.class.
One issue I have with that is that it means that subclassing breaks the parent
behavior. It breaks the Open/closed principle I think.

(http://nshipster.com/equality/ uses isKIndOfClass, which like here, is check to
early return before casting.)

[gambard, 2017/02/13 14:51:41]

I keep it this way.

+    return NO;
+  }
+
+  ContentSuggestionsCategoryWrapper* other =
+      base::mac::ObjCCastStrict<ContentSuggestionsCategoryWrapper>(object);
+
+  return self.category == other.category;
+}
+
+- (NSUInteger)hash {

[stkhapugin, 2017/02/13 12:19:18]

-hash and -isEqual are usually put in a #pragma mark - comparison

[gambard, 2017/02/13 14:51:41]

Done.

+  return _categoryID;
+}
+
+- (ntp_snippets::Category)category {
+  return ntp_snippets::Category::FromIDValue(_categoryID);
+}
+
+#pragma mark - NSCopying
+
+- (id)copyWithZone:(nullable NSZone*)zone {
+  ContentSuggestionsCategoryWrapper* copy =
+      [[[self class] allocWithZone:zone] initWithCategory:self.category];
+  return copy;
+}
+
+@end