[Android Webview] Refactor LoadUrlTest and work on embedded_test_server custom handler

android_webview/test/embedded_test_server/BUILD.gn

Index: android_webview/test/embedded_test_server/BUILD.gn
diff --git a/android_webview/test/embedded_test_server/BUILD.gn b/android_webview/test/embedded_test_server/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..ba86f9ad7c41aa67396aec3f42d6867dcc80cf39
--- /dev/null
+++ b/android_webview/test/embedded_test_server/BUILD.gn
@@ -0,0 +1,72 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/config.gni")
+import("//build/config/android/rules.gni")
+
+android_library("aw_net_java_test_support") {
+  testonly = true
+  java_files = [
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServer.java",
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerImpl.java",
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerService.java",
+  ]
+  deps = [
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//net/android:net_java",
+    "//net/android:net_java_test_support",
+  ]
+}
+
+generate_jni("aw_net_jni_headers") {
+  sources = [
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerImpl.java",
+  ]
+  jni_package = "android_webview/test"
+}
+
+source_set("aw_java_test_native_support") {
+  testonly = true
+  sources = [
+    "../../../net/test/android/net_test_jni_onload.cc",
+    "../../../net/test/android/net_test_jni_onload.h",
+    "../../../net/test/embedded_test_server/android/embedded_test_server_android.cc",
+    "../../../net/test/embedded_test_server/android/embedded_test_server_android.h",

[sgurun-gerrit only, 2017/03/29 18:19:27]

should not be included this way. It should be part of a net library that we
depend on. you already have a test_support as deps, doesn't it include these
files?

[shenghuazhang, 2017/04/11 01:38:27]

'//net/android:java_test_native_support' includes these files.

And it also involves the c++ file '//net/test/android/net_test_entry_point.cc',
it will cause multiple definition of 'JNI_OnLoad' error with
"aw_test_entry_point.cc". S.t have to add the source files in these separate
way.

If would like to not include //net files in this way, need to split the source
set 
'java_test_native_support' in //net/android/BUILD.gn to something like:

source_set("java_test_native_jni_support") {
  testonly = true
  sources = [
    "../test/android/net_test_jni_onload.cc",
    "../test/android/net_test_jni_onload.h",
    "../test/embedded_test_server/android/embedded_test_server_android.cc",
    "../test/embedded_test_server/android/embedded_test_server_android.h",
  ]

  deps = [
    "//net:test_support",
  ]
  public_deps = [
    "//net:net_test_jni_headers",
  ]
}

source_set("java_test_native_support") {
  testonly = true
  sources = [
    "../test/android/net_test_entry_point.cc",
  ]

  deps = [
    ":java_test_native_jni_support",
  ]
}

And add the '//net/android/java_test_native_jni_support' as one of the deps
here. But those are kind of weird looking as separate supporting sets in
//net/android/BUILD.gn.

The current way and the split way, which one is preferred?

+    "aw_embedded_test_server.cc",
+    "aw_embedded_test_server.h",
+    "aw_test_entry_point.cc",
+    "aw_test_jni_onload.cc",
+    "aw_test_jni_onload.h",
+  ]
+  deps = [
+    "//net:test_support",
+  ]
+  public_deps = [
+    ":aw_net_jni_headers",
+    "//net:net_test_jni_headers",
+  ]
+}
+
+shared_library("aw_net_java_test_native_support") {
+  testonly = true
+  deps = [
+    ":aw_java_test_native_support",
+    "//net:test_support",
+  ]
+}
+
+android_apk("aw_net_test_support_apk") {
+  testonly = true
+
+  # Used as an additional_apk in test scripts.
+  never_incremental = true
+  deps = [
+    ":aw_net_java_test_support",
+    "//base:base_java",
+  ]
+  android_manifest = "java/AndroidManifest.xml"
+  apk_name = "ChromiumNetTestAwSupport"
+  shared_libraries = [ ":aw_net_java_test_native_support" ]
+}