[Android Webview] Refactor LoadUrlTest and work on embedded_test_server custom handler

android_webview/test/embeddedtestserver/BUILD.gn

Index: android_webview/test/embeddedtestserver/BUILD.gn
diff --git a/android_webview/test/embeddedtestserver/BUILD.gn b/android_webview/test/embeddedtestserver/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..4e9ed450e01a8eed1f9e0f6f3fa9278c4a2b9854
--- /dev/null
+++ b/android_webview/test/embeddedtestserver/BUILD.gn
@@ -0,0 +1,83 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.

[jbudorick, 2017/03/13 23:32:54]

nit: move this directory from android_webview/test/embeddedtestserver to
android_webview/test/embedded_test_server to match what //net does.

[shenghuazhang, 2017/03/17 01:07:15]

Done.

+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/config.gni")
+import("//build/config/android/rules.gni")
+
+android_library("aw_net_java_test_support") {
+  testonly = true
+  java_files = [
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServer.java",
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerImpl.java",
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerService.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/DummySpnegoAuthenticator.java",

[jbudorick, 2017/03/13 23:32:54]

This shouldn't be listing java files from //net. Instead, you should add
//net/android:net_java_test_support to deps below.

[shenghuazhang, 2017/03/17 01:07:14]

Done.

+    "../../../net/test/android/javatests/src/org/chromium/net/test/DummySpnegoAuthenticatorService.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/EmbeddedTestServer.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/EmbeddedTestServerImpl.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/EmbeddedTestServerService.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/util/CertTestUtil.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/util/NetworkChangeNotifierTestUtil.java",
+    "../../../net/test/android/javatests/src/org/chromium/net/test/util/TestWebServer.java",
+  ]
+  deps = [
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//net/android:net_java",
+    "//third_party/android_tools:android_support_annotations_java",
+    "//third_party/android_tools:legacy_http_javalib",
+  ]
+  srcjar_deps = [
+    "//net/android:embedded_test_server_aidl",
+    "//net/android:net_java_test_support_enums_srcjar",
+  ]
+}
+
+generate_jni("aw_net_jni_headers") {
+  sources = [
+    "java/src/org/chromium/android_webview/test/AwEmbeddedTestServerImpl.java",
+  ]
+  jni_package = "android_webview/test"
+}
+
+source_set("aw_java_test_native_support") {
+  testonly = true
+  sources = [
+    "../../../net/test/embedded_test_server/android/embedded_test_server_android.cc",

[jbudorick, 2017/03/13 23:32:54]

Similarly, this should depend on //net/android:java_test_native_support.

[shenghuazhang, 2017/03/17 01:07:15]

'//net/android:java_test_native_support' involves the c++ file
'//net/test/android/net_test_entry_point.cc', it will cause multiple definition
of 'JNI_OnLoad' error with "aw_test_entry_point.cc". Have to add the source
files in '//net/android:java_test_native_support' individually here except for
'net_test_entry_point.cc' :(

+    "../../../net/test/embedded_test_server/android/embedded_test_server_android.h",
+    "aw_test_entry_point.cc",
+    "aw_test_jni_onload.cc",
+    "aw_test_jni_onload.h",
+    "custom_handlers.cc",
+    "custom_handlers.h",
+  ]
+  deps = [
+    "//net:test_support",
+  ]
+  public_deps = [
+    ":aw_net_jni_headers",
+    "//net:net_test_jni_headers",
+  ]
+}
+
+shared_library("aw_net_java_test_native_support") {
+  testonly = true
+  deps = [
+    ":aw_java_test_native_support",
+    "//net:test_support",
+  ]
+}
+
+android_apk("aw_net_test_support_apk") {
+  testonly = true
+
+  # Used as an additional_apk in test scripts.
+  never_incremental = true
+  deps = [
+    ":aw_net_java_test_support",
+    "//base:base_java",
+  ]
+  android_manifest = "java/AndroidManifest.xml"
+  apk_name = "ChromiumNetTestAwSupport"
+  shared_libraries = [ ":aw_net_java_test_native_support" ]
+}