[Android Webview] Refactor LoadUrlTest and work on embedded_test_server custom handler

android_webview/embeddedtestserver/BUILD.gn

+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/config.gni")
+import("//build/config/android/rules.gni")
+
+android_aidl("aw_embedded_test_server_aidl") {
+  interface_file =
+      "java/src/org/chromium/net/test/IAwEmbeddedTestServerInterface.aidl"
+  sources = [
+    "java/src/org/chromium/net/test/IAwEmbeddedTestServerImpl.aidl",
+  ]
+}
+
+if (is_android) {
+  generate_jni("aw_test_jni_headers") {
+    sources = [
+      "java/src/org/chromium/net/test/AwEmbeddedTestServerImpl.java",
+    ]
+    jni_package = "android_webview/test"
+  }
+}
+
+android_library("aw_net_java_test_support") {
+  testonly = true
+  java_files = [
+    "java/src/org/chromium/net/test/AwEmbeddedTestServer.java",
+    "java/src/org/chromium/net/test/AwEmbeddedTestServerImpl.java",
+    "java/src/org/chromium/net/test/AwEmbeddedTestServerService.java",
+  ]
+  deps = [
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//net/android:net_java",
+    "//third_party/android_tools:android_support_annotations_java",
+    "//third_party/android_tools:legacy_http_javalib",
+  ]
+  srcjar_deps = [ ":aw_embedded_test_server_aidl" ]
+}
+
+static_library("aw_test_support") {
+  testonly = true
+  sources = [
+    "custom_handlers.cc",
+    "custom_handlers.h",
+  ]
+  public_deps = [
+    "//net:test_support",
+  ]
+}
+
+source_set("aw_java_test_native_support") {
+  testonly = true
+  sources = [
+    "aw_embedded_test_server_android.cc",
+    "aw_embedded_test_server_android.h",
+    "test/android/aw_test_entry_point.cc",
+    "test/android/aw_test_jni_onload.cc",
+    "test/android/aw_test_jni_onload.h",
+  ]
+
+  deps = [
+    ":aw_test_support",
+  ]
+  public_deps = [
+    ":aw_test_jni_headers",
+  ]
+}
+
+shared_library("aw_net_java_test_native_support") {
+  testonly = true
+  deps = [
+    ":aw_java_test_native_support",
+    "//net:test_support",
+  ]
+}
+
+android_apk("aw_net_test_support_apk") {
+  testonly = true
+
+  # Used as an additional_apk in test scripts.
+  never_incremental = true
+  deps = [
+    ":aw_net_java_test_support",
+    "//base:base_java",
+  ]
+  android_manifest = "java/AndroidManifest.xml"
+  apk_name = "ChromiumNetTestAwsupport"
+  shared_libraries = [ ":aw_net_java_test_native_support" ]
+}