Convert some of TabModel logic to WebStateListObservers.

ios/chrome/browser/tabs/tab_model_tab_model_observers_bridge.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/tabs/tab_model_tab_model_observers_bridge.h"
+
+#include "base/logging.h"
+#import "ios/chrome/browser/tabs/legacy_tab_helper.h"
+#import "ios/chrome/browser/tabs/tab_model.h"
+#import "ios/chrome/browser/tabs/tab_model_observers.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@implementation TabModelTabModelObserversBridge {
+  __weak TabModel* _tabModel;
+  __weak TabModelObservers* _tabModelObservers;
+}
+
+- (instancetype)initWithTabModel:(TabModel*)tabModel
+               tabModelObservers:(TabModelObservers*)tabModelObservers {
+  DCHECK(tabModel);
+  DCHECK(tabModelObservers);
+  if ((self = [super init])) {
+    _tabModel = tabModel;
+    _tabModelObservers = tabModelObservers;
+  }
+  return self;
+}
+
+#pragma mark WebStateListObserver
+
+- (void)webStateList:(WebStateList*)webStateList
+    webStateInserted:(web::WebState*)webState
+             atIndex:(NSUInteger)index {
+  [_tabModelObservers tabModel:_tabModel
+                  didInsertTab:LegacyTabHelper::GetTabForWebState(webState)
+                       atIndex:index
+                  inForeground:NO];
+  [_tabModelObservers tabModelDidChangeTabCount:_tabModel];
+}
+
+- (void)webStateList:(WebStateList*)webStateList
+       webStateMoved:(web::WebState*)webState
+           fromIndex:(NSUInteger)fromIndex
+             toIndex:(NSUInteger)toIndex {
+  [_tabModelObservers tabModel:_tabModel
+                    didMoveTab:LegacyTabHelper::GetTabForWebState(webState)
+                     fromIndex:fromIndex
+                       toIndex:toIndex];
+}
+
+- (void)webStateList:(WebStateList*)webStateList
+    webStateReplaced:(web::WebState*)oldWebState
+          byWebState:(web::WebState*)newWebState
+             atIndex:(NSUInteger)index {
+  [_tabModelObservers tabModel:_tabModel
+                 didReplaceTab:LegacyTabHelper::GetTabForWebState(oldWebState)
+                       withTab:LegacyTabHelper::GetTabForWebState(newWebState)
+                       atIndex:index];
+}
+
+- (void)webStateList:(WebStateList*)webStateList
+     webStateRemoved:(web::WebState*)webState
+             atIndex:(NSUInteger)index {
+  [_tabModelObservers tabModel:_tabModel
+                  didRemoveTab:LegacyTabHelper::GetTabForWebState(webState)
+                       atIndex:index];
+  [_tabModelObservers tabModelDidChangeTabCount:_tabModel];
+}
+
+@end