Fixed title updating for back forward navigation.

ios/web/web_state/ui/crw_web_controller.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/web_state/ui/crw_web_controller.h"
 
 #import <WebKit/WebKit.h>
 
 #import <objc/runtime.h>
 #include <stddef.h>
@@ skipping 700 matching lines @@
 // TODO(stuartmorgan): Move the pushState/replaceState logic into
 // NavigationManager.
 - (void)pushStateWithPageURL:(const GURL&)pageURL
                  stateObject:(NSString*)stateObject
                   transition:(ui::PageTransition)transition;
 // Assigns the given URL and state object to the current CRWSessionEntry.
 - (void)replaceStateWithPageURL:(const GURL&)pageUrl
                     stateObject:(NSString*)stateObject;
 // Sets _documentURL to newURL, and updates any relevant state information.
 - (void)setDocumentURL:(const GURL&)newURL;
+// Sets WKWebView's title to the last committed navigation item.
+- (void)updateNavigationItemTitle;
 // Returns YES if the current navigation item corresponds to a web page
 // loaded by a POST request.
 - (BOOL)isCurrentNavigationItemPOST;
 // Returns YES if current navigation item is WKNavigationTypeBackForward.
 - (BOOL)isCurrentNavigationBackForward;
 // Returns whether the given navigation is triggered by a user link click.
 - (BOOL)isLinkNavigation:(WKNavigationType)navigationType;
 
 // Inject windowID if not yet injected.
 - (void)injectWindowID;
@@ skipping 641 matching lines @@
   [self didUpdateHistoryStateWithPageURL:pageUrl];
 }
 
 - (void)setDocumentURL:(const GURL&)newURL {
   if (newURL != _documentURL && newURL.is_valid()) {
     _documentURL = newURL;
     _interactionRegisteredSinceLastURLChange = NO;
   }
 }
 
+- (void)updateNavigationItemTitle {
+  auto& navigationManager = _webStateImpl->GetNavigationManagerImpl();
+  web::NavigationItem* item = navigationManager.GetLastCommittedItem();
+  if (!item)
+    return;
+
+  base::string16 newTitle = base::SysNSStringToUTF16([_webView title]);

[kkhorimoto, 2017/02/07 23:59:44]

How about a separate variable for the NSString equal to [_webView title], since
it's used multiple places in this function?

[Eugene But (OOO till 7-30), 2017/02/08 01:50:27]

Done.

+  if (item->GetTitle() == newTitle)
+    return;
+
+  item->SetTitle(newTitle);
+  // TODO(crbug.com/546218): See if this can be removed; it's not clear that
+  // other platforms send this (tab sync triggers need to be compared against
+  // upstream).
+  navigationManager.OnNavigationItemChanged();
+
+  if ([_delegate respondsToSelector:@selector(webController:titleDidChange:)]) {
+    DCHECK([_webView title]);

[kkhorimoto, 2017/02/07 23:59:44]

Should we be DCHECKing this earlier?  Whats the consequence of passing a nil
title here?

[Eugene But (OOO till 7-30), 2017/02/08 01:50:27]

Done. I don't think anything will break, but this method should not be called
when title is nil (f.e. when web process crashes).

+    [_delegate webController:self titleDidChange:[_webView title]];
+  }
+}
+
 - (BOOL)isCurrentNavigationItemPOST {
   // |_pendingNavigationInfo| will be nil if the decidePolicy* delegate methods
   // were not called.
   NSString* HTTPMethod =
       _pendingNavigationInfo
           ? [_pendingNavigationInfo HTTPMethod]
           : [self currentBackForwardListItemHolder]->http_method();
   return [HTTPMethod isEqual:@"POST"];
 }
 
@@ skipping 3355 matching lines @@
 }
 
 - (void)webView:(WKWebView*)webView
     didCommitNavigation:(WKNavigation*)navigation {
   [_navigationStates setState:web::WKNavigationState::COMMITTED
                 forNavigation:navigation];
 
   DCHECK_EQ(_webView, webView);
   _certVerificationErrors->Clear();
 
-  // This is the point where the document's URL has actually changed, and
-  // pending navigation information should be applied to state information.
+  // This is the point where the document's URL and title have actually changed,
+  // and pending navigation information should be applied to state information.
   [self setDocumentURL:net::GURLWithNSURL([_webView URL])];
+  [self updateNavigationItemTitle];
 
   if (!_lastRegisteredRequestURL.is_valid() &&
       _documentURL != _lastRegisteredRequestURL) {
     // if |_lastRegisteredRequestURL| is an invalid URL, then |_documentURL|
     // will be "about:blank".
     [[self sessionController] updatePendingItem:_documentURL];
   }
   DCHECK(_documentURL == _lastRegisteredRequestURL ||
          (!_lastRegisteredRequestURL.is_valid() &&
           _documentURL.spec() == url::kAboutBlankURL));
@@ skipping 217 matching lines @@
 }
 
 - (void)webViewTitleDidChange {
   // WKWebView's title becomes empty when the web process dies; ignore that
   // update.
   if (_webProcessIsDead) {
     DCHECK_EQ([_webView title].length, 0U);
     return;
   }
 
-  if ([self.delegate
-          respondsToSelector:@selector(webController:titleDidChange:)]) {
-    DCHECK([_webView title]);
-    [self.delegate webController:self titleDidChange:[_webView title]];
+  if (web::WKNavigationState::COMMITTED <=

[kkhorimoto, 2017/02/07 23:59:44]

It's not obvious without looking up the enum definition ordering what this
means.  How about instead of <=, we check if it's == to COMMITTED, FINISHED, or
FAILED?  It's a little more verbose, but helps readability.

[Eugene But (OOO till 7-30), 2017/02/08 01:50:27]

I think checking multiple states is more error prone (one state can be missed by
accident). Added explanatory variable to improve readability.

+      [_navigationStates lastAddedNavigationState]) {
+    // Do not update the title if there is a navigation in progress because
+    // there is no way to tell if KVO change fired for new or previous page.
+    [self updateNavigationItemTitle];
   }
 }
 
 - (void)webViewURLDidChange {
   // TODO(stuartmorgan): Determine if there are any cases where this still
   // happens, and if so whether anything should be done when it does.
   if (![_webView URL]) {
     DVLOG(1) << "Received nil URL callback";
     return;
   }
@@ skipping 312 matching lines @@
   }
 
   return web::WEB_VIEW_DOCUMENT_TYPE_GENERIC;
 }
 
 - (NSString*)refererFromNavigationAction:(WKNavigationAction*)action {
   return [action.request valueForHTTPHeaderField:@"Referer"];
 }
 
 @end