Extended HistoryUITestCase to test titles.

ios/chrome/browser/ui/history/history_ui_egtest.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <EarlGrey/EarlGrey.h>
 #import <UIKit/UIKit.h>
 #import <XCTest/XCTest.h>
 
+#include "base/strings/stringprintf.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/browsing_data/core/pref_names.h"
 #include "components/prefs/pref_service.h"
 #include "components/strings/grit/components_strings.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/chrome_url_constants.h"
 #import "ios/chrome/browser/ui/history/history_entry_item.h"
 #import "ios/chrome/browser/ui/settings/clear_browsing_data_collection_view_controller.h"
 #import "ios/chrome/browser/ui/settings/settings_collection_view_controller.h"
 #import "ios/chrome/browser/ui/tools_menu/tools_menu_view_controller.h"
@@ skipping 11 matching lines @@
 #import "ios/public/provider/chrome/browser/signin/chrome_identity.h"
 #import "ios/public/provider/chrome/browser/signin/fake_chrome_identity.h"
 #import "ios/public/provider/chrome/browser/signin/fake_chrome_identity_service.h"
 #import "ios/testing/wait_util.h"
 #import "ios/web/public/test/http_server.h"
 #import "ios/web/public/test/http_server_util.h"
 #import "net/base/mac/url_conversions.h"
 #include "ui/base/l10n/l10n_util.h"
 
 using chrome_test_util::ButtonWithAccessibilityLabelId;
+using chrome_test_util::WebViewContainingText;
 
 namespace {
 char kURL1[] = "http://firstURL";
 char kURL2[] = "http://secondURL";
 char kURL3[] = "http://thirdURL";
-char kResponse1[] = "Test Page 1";
-char kResponse2[] = "Test Page 2";
-char kResponse3[] = "Test Page 3";
+char kTitle1[] = "Page 1";
+char kTitle2[] = "Page 2";
+char kResponse1[] = "Test Page 1 content";
+char kResponse2[] = "Test Page 2 content";
+char kResponse3[] = "Test Page 3 content";
 
-// Matcher for entry in history for URL.
-id<GREYMatcher> HistoryEntryWithUrl(const GURL& url) {
-  NSString* url_spec = base::SysUTF8ToNSString(url.spec());
-  return grey_allOf(grey_text(url_spec), grey_sufficientlyVisible(), nil);
+// Matcher for entry in history for URL and title.
+id<GREYMatcher> HistoryEntry(const GURL& url, const std::string& title) {
+  NSString* url_spec_text = base::SysUTF8ToNSString(url.spec());
+  NSString* title_text = base::SysUTF8ToNSString(title);
+
+  MatchesBlock matches = ^BOOL(HistoryEntryCell* cell) {
+    return [cell.textLabel.text isEqual:title_text] &&
+           [cell.detailTextLabel.text isEqual:url_spec_text];
+  };
+
+  DescribeToBlock describe = ^(id<GREYDescription> description) {
+    [description appendText:@"view containing URL text: "];
+    [description appendText:url_spec_text];
+    [description appendText:@" title text: "];
+    [description appendText:title_text];
+  };
+
+  return grey_allOf(grey_kindOfClass([HistoryEntryCell class]),
+                    [[[GREYElementMatcherBlock alloc]
+                        initWithMatchesBlock:matches
+                            descriptionBlock:describe] autorelease],

[Eugene But (OOO till 7-30), 2017/02/07 02:47:34]

Mike, I tried running this on downstream bots and got ARC-related compilation
failure:

../../ios/chrome/browser/ui/history/history_ui_egtest.mm:77:56: error:
'autorelease' is unavailable: not available in automatic reference counting mode
                            descriptionBlock:describe] autorelease],
                                                       ^
/b/build/slave/ipad10-simulator/build/src/build/ios_files/Xcode.app/Contents/Developer/Platforms/iPhoneSimulator.platform/Developer/SDKs/iPhoneSimulator10.2.sdk/usr/include/objc/NSObject.h:38:1:
note: 'autorelease' has been explicitly marked unavailable here
- (instancetype)autorelease OBJC_ARC_UNAVAILABLE;
^
../../ios/chrome/browser/ui/history/history_ui_egtest.mm:77:56: error: ARC
forbids explicit message send of 'autorelease'
                            descriptionBlock:describe] autorelease],
                            ~~~~~~~~~~~~~~~~~~~~~~~~~~ ^
2 errors generated.



But this file is not ARC. Do you know where can be a problem?

[stkhapugin, 2017/02/07 12:35:15]

Oops, I haven't spotted this one at first. Just rebase and remove autorelease
here (and all other retain/autorelease/release). If you have further questions,
please feel free to loop me into the further review. 

+                    grey_sufficientlyVisible(), nil);
 }
 // Matcher for the history button in the tools menu.
 id<GREYMatcher> HistoryButton() {
   return ButtonWithAccessibilityLabelId(IDS_HISTORY_SHOW_HISTORY);
 }
 // Matcher for the done button in the navigation bar.
 id<GREYMatcher> NavigationDoneButton() {
   // Include sufficientlyVisible condition for the case of the clear browsing
   // dialog, which also has a "Done" button and is displayed over the history
   // panel.
@@ skipping 109 matching lines @@
 - (void)resetBrowsingDataPrefs;
 
 @end
 
 @implementation HistoryUITestCase
 
 // Set up called once for the class.
 + (void)setUp {
   [super setUp];
   std::map<GURL, std::string> responses;
-  responses[web::test::HttpServer::MakeUrl(kURL1)] = kResponse1;
-  responses[web::test::HttpServer::MakeUrl(kURL2)] = kResponse2;
+  const char kPageFormat[] = "<head><title>%s</title></head><body>%s</body>";
+  responses[web::test::HttpServer::MakeUrl(kURL1)] =
+      base::StringPrintf(kPageFormat, kTitle1, kResponse1);
+  responses[web::test::HttpServer::MakeUrl(kURL2)] =
+      base::StringPrintf(kPageFormat, kTitle2, kResponse2);
+  // Page 3 does not have <title> tag, so URL will be its title.
   responses[web::test::HttpServer::MakeUrl(kURL3)] = kResponse3;
   web::test::SetUpSimpleHttpServer(responses);
 }
 
 - (void)setUp {
   [super setUp];
   _URL1 = web::test::HttpServer::MakeUrl(kURL1);
   _URL2 = web::test::HttpServer::MakeUrl(kURL2);
   _URL3 = web::test::HttpServer::MakeUrl(kURL3);
   [ChromeEarlGrey clearBrowsingHistory];
@@ skipping 27 matching lines @@
   [self openHistoryPanel];
   [self assertNoHistoryShown];
 }
 
 // Tests that the history panel displays navigation history.
 - (void)testDisplayHistory {
   [self loadTestURLs];
   [self openHistoryPanel];
 
   // Assert that history displays three entries.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL2)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL3)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL3, _URL3.GetContent())]
       assertWithMatcher:grey_notNil()];
 
   // Tap a history entry and assert that navigation to that entry's URL occurs.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       performAction:grey_tap()];
-  id<GREYMatcher> webViewMatcher =
-      chrome_test_util::WebViewContainingText(kResponse1);
-  [[EarlGrey selectElementWithMatcher:webViewMatcher]
+  [[EarlGrey selectElementWithMatcher:WebViewContainingText(kResponse1)]
       assertWithMatcher:grey_notNil()];
 }
 
+// Tests that history is not changed after performing back navigation.
+// TODO(crbug.com/688047): Enable this test.
+- (void)DISABLED_testHistoryUpdateAfterBackNavigation {
+  [ChromeEarlGrey loadURL:_URL1];
+  [ChromeEarlGrey loadURL:_URL2];
+
+  [[EarlGrey selectElementWithMatcher:chrome_test_util::BackButton()]
+      performAction:grey_tap()];
+  [[EarlGrey selectElementWithMatcher:WebViewContainingText(kResponse1)]
+      assertWithMatcher:grey_notNil()];
+
+  [self openHistoryPanel];
+
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
+      assertWithMatcher:grey_notNil()];
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
+      assertWithMatcher:grey_notNil()];
+}
+
 // Test that history displays a message about entries only if the user is logged
 // in, and that tapping on the link in the message opens a new tab with the sync
 // help page.
 - (void)testHistoryEntriesStatusCell {
   [self loadTestURLs];
   [self openHistoryPanel];
   // Assert that no message is shown when the user is not signed in.
   NSRange range;
   NSString* entriesMessage = ParseStringWithLink(
       l10n_util::GetNSString(IDS_IOS_HISTORY_NO_SYNCED_RESULTS), &range);
   [[EarlGrey selectElementWithMatcher:grey_text(entriesMessage)]
       assertWithMatcher:grey_nil()];
   [[EarlGrey selectElementWithMatcher:NavigationDoneButton()]
       performAction:grey_tap()];
 
   // Sign in and assert that the page indicates what type of history entries
   // are shown.
   MockSignIn();
   [self openHistoryPanel];
   // Assert that message about entries is shown. The "history is showing local
   // entries" message will be shown because sync is not set up for this test.
   [[EarlGrey selectElementWithMatcher:grey_text(entriesMessage)]
       assertWithMatcher:grey_notNil()];
 
   // Tap on "Learn more" link and assert that new tab with the link is opened.
   [[EarlGrey
       selectElementWithMatcher:grey_kindOfClass([TransparentLinkButton class])]
       performAction:grey_tap()];
   chrome_test_util::AssertMainTabCount(2);
-  id<GREYMatcher> webViewMatcher = chrome_test_util::WebViewContainingText(
-      "Sync and view tabs and history across devices");
+  id<GREYMatcher> webViewMatcher =
+      WebViewContainingText("Sync and view tabs and history across devices");
   [[EarlGrey selectElementWithMatcher:webViewMatcher]
       assertWithMatcher:grey_notNil()];
 }
 
 // Tests that searching history displays only entries matching the search term.
 - (void)testSearchHistory {
   [self loadTestURLs];
   [self openHistoryPanel];
   [[EarlGrey selectElementWithMatcher:SearchIconButton()]
       performAction:grey_tap()];
 
   NSString* searchString =
       [NSString stringWithFormat:@"%s", _URL1.path().c_str()];
   [[EarlGrey selectElementWithMatcher:grey_keyWindow()]
       performAction:grey_typeText(searchString)];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL2)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
       assertWithMatcher:grey_nil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL3)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL3, _URL3.GetContent())]
       assertWithMatcher:grey_nil()];
 }
 
 // Tests deletion of history entries.
 - (void)testDeleteHistory {
   [self loadTestURLs];
   [self openHistoryPanel];
 
   // Assert that three history elements are present.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL2)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL3)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL3, _URL3.GetContent())]
       assertWithMatcher:grey_notNil()];
 
   // Enter edit mode, select a history element, and press delete.
   [[EarlGrey selectElementWithMatcher:NavigationEditButton()]
       performAction:grey_tap()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       performAction:grey_tap()];
   [[EarlGrey selectElementWithMatcher:DeleteHistoryEntriesButton()]
       performAction:grey_tap()];
 
   // Assert that the deleted entry is gone and the other two remain.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       assertWithMatcher:grey_nil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL2)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
       assertWithMatcher:grey_notNil()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL3)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL3, _URL3.GetContent())]
       assertWithMatcher:grey_notNil()];
 
   // Enter edit mode, select both remaining entries, and press delete.
   [[EarlGrey selectElementWithMatcher:NavigationEditButton()]
       performAction:grey_tap()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL2)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL2, kTitle2)]
       performAction:grey_tap()];
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL3)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL3, _URL3.GetContent())]
       performAction:grey_tap()];
   [[EarlGrey selectElementWithMatcher:DeleteHistoryEntriesButton()]
       performAction:grey_tap()];
 
   [self assertNoHistoryShown];
 }
 
 // Tests clear browsing history.
 - (void)testClearBrowsingHistory {
   [self loadTestURLs];
@@ skipping 26 matching lines @@
   [self assertNoHistoryShown];
 }
 
 // Tests display and selection of 'Open in New Tab' in a context menu on a
 // history entry.
 - (void)testContextMenuOpenInNewTab {
   [self loadTestURLs];
   [self openHistoryPanel];
 
   // Long press on the history element.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       performAction:grey_longPress()];
 
   // Select "Open in New Tab" and confirm that new tab is opened with selected
   // URL.
   [[EarlGrey selectElementWithMatcher:OpenInNewTabButton()]
       performAction:grey_tap()];
   [[EarlGrey selectElementWithMatcher:chrome_test_util::OmniboxText(
                                           _URL1.GetContent())]
       assertWithMatcher:grey_notNil()];
   chrome_test_util::AssertMainTabCount(2);
 }
 
 // Tests display and selection of 'Open in New Incognito Tab' in a context menu
 // on a history entry.
 - (void)testContextMenuOpenInNewIncognitoTab {
   [self loadTestURLs];
   [self openHistoryPanel];
 
   // Long press on the history element.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       performAction:grey_longPress()];
 
   // Select "Open in New Incognito Tab" and confirm that new tab is opened in
   // incognito with the selected URL.
   [[EarlGrey selectElementWithMatcher:OpenInNewIncognitoTabButton()]
       performAction:grey_tap()];
   [[EarlGrey selectElementWithMatcher:chrome_test_util::OmniboxText(
                                           _URL1.GetContent())]
       assertWithMatcher:grey_notNil()];
   chrome_test_util::AssertMainTabCount(1);
   chrome_test_util::AssertIncognitoTabCount(1);
 }
 
 // Tests display and selection of 'Copy URL' in a context menu on a history
 // entry.
 - (void)testContextMenuCopy {
   ProceduralBlock clearPasteboard = ^{
     [[UIPasteboard generalPasteboard] setURLs:nil];
   };
   [self setTearDownHandler:clearPasteboard];
   clearPasteboard();
 
   [self loadTestURLs];
   [self openHistoryPanel];
 
   // Long press on the history element.
-  [[EarlGrey selectElementWithMatcher:HistoryEntryWithUrl(_URL1)]
+  [[EarlGrey selectElementWithMatcher:HistoryEntry(_URL1, kTitle1)]
       performAction:grey_longPress()];
 
   // Tap "Copy URL" and wait for the URL to be copied to the pasteboard.
   [[EarlGrey selectElementWithMatcher:CopyUrlButton()]
       performAction:grey_tap()];
   bool success =
       testing::WaitUntilConditionOrTimeout(testing::kWaitForUIElementTimeout, ^{
         return _URL1 ==
                net::GURLWithNSURL([UIPasteboard generalPasteboard].URL);
       });
   GREYAssertTrue(success, @"Pasteboard URL was not set to %s",
                  _URL1.spec().c_str());
 }
 
 // Navigates to history and checks elements for accessibility.
 - (void)testAccessibilityOnHistory {
   [self openHistoryPanel];
   chrome_test_util::VerifyAccessibilityForCurrentScreen();
   // Close history.
   [[EarlGrey
       selectElementWithMatcher:chrome_test_util::ButtonWithAccessibilityLabelId(
                                    IDS_IOS_NAVIGATION_BAR_DONE_BUTTON)]
       performAction:grey_tap()];
 }
 
 #pragma mark Helper Methods
 
 - (void)loadTestURLs {
   [ChromeEarlGrey loadURL:_URL1];
-  id<GREYMatcher> response1Matcher =
-      chrome_test_util::WebViewContainingText(kResponse1);
-  [[EarlGrey selectElementWithMatcher:response1Matcher]
+  [[EarlGrey selectElementWithMatcher:WebViewContainingText(kResponse1)]
       assertWithMatcher:grey_notNil()];
 
   [ChromeEarlGrey loadURL:_URL2];
-  id<GREYMatcher> response2Matcher =
-      chrome_test_util::WebViewContainingText(kResponse2);
-  [[EarlGrey selectElementWithMatcher:response2Matcher]
+  [[EarlGrey selectElementWithMatcher:WebViewContainingText(kResponse2)]
       assertWithMatcher:grey_notNil()];
 
   [ChromeEarlGrey loadURL:_URL3];
-  id<GREYMatcher> response3Matcher =
-      chrome_test_util::WebViewContainingText(kResponse3);
-  [[EarlGrey selectElementWithMatcher:response3Matcher]
+  [[EarlGrey selectElementWithMatcher:WebViewContainingText(kResponse3)]
       assertWithMatcher:grey_notNil()];
 }
 
 - (void)openHistoryPanel {
   [ChromeEarlGreyUI openToolsMenu];
   [[EarlGrey selectElementWithMatcher:HistoryButton()]
       performAction:grey_tap()];
 }
 
 - (void)assertNoHistoryShown {
@@ skipping 13 matching lines @@
 - (void)resetBrowsingDataPrefs {
   PrefService* prefs = chrome_test_util::GetOriginalBrowserState()->GetPrefs();
   prefs->ClearPref(browsing_data::prefs::kDeleteBrowsingHistory);
   prefs->ClearPref(browsing_data::prefs::kDeleteCookies);
   prefs->ClearPref(browsing_data::prefs::kDeleteCache);
   prefs->ClearPref(browsing_data::prefs::kDeletePasswords);
   prefs->ClearPref(browsing_data::prefs::kDeleteFormData);
 }
 
 @end