Make new target for vector icon structs to replace ui/gfx/vector_icons/

ui/vector_icons/BUILD.gn

Index: ui/vector_icons/BUILD.gn
diff --git a/ui/vector_icons/BUILD.gn b/ui/vector_icons/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..65c6c155aac8dc63057b4088b5e39b200c4c65e6
--- /dev/null
+++ b/ui/vector_icons/BUILD.gn
@@ -0,0 +1,47 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+action("aggregate_vector_icons") {
+  visibility = [ ":*" ]
+
+  script = "//ui/gfx/vector_icons/aggregate_vector_icons.py"
+
+  icons = [
+    "close.1x.icon",
+    "close.icon",
+  ]
+
+  output_cc = "$target_gen_dir/vector_icons.cc"
+  output_h = "$target_gen_dir/vector_icons.h"
+
+  inputs = icons
+  inputs += [
+    "vector_icons.cc.template",
+    "vector_icons.h.template",
+  ]
+  outputs = [
+    output_cc,
+    output_h,
+  ]
+
+  response_file_contents = rebase_path(icons, root_build_dir)
+
+  args = [
+    "--working_directory=" + rebase_path("./"),
+    "--file_list={{response_file_name}}",
+    "--output_cc=" + rebase_path(output_cc, root_build_dir),
+    "--output_h=" + rebase_path(output_h, root_build_dir),
+  ]
+}
+
+static_library("vector_icons") {
+  sources = get_target_outputs(":aggregate_vector_icons")
+  sources += [ "//ui/gfx/vector_icon_types.h" ]
+
+  deps = [
+    ":aggregate_vector_icons",
+    "//base",
+    "//skia",
+  ]
+}