[cronet] Make getAcceptLanguages index a static table instead of the application bundle.

components/cronet/ios/Cronet.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "components/cronet/ios/Cronet.h"
 
 #include <memory>
 
 #include "base/lazy_instance.h"
 #include "base/logging.h"
 #include "base/mac/bundle_locations.h"
 #include "base/mac/scoped_block.h"
 #include "base/memory/ptr_util.h"
 #include "base/memory/scoped_vector.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/synchronization/lock.h"
+#include "components/cronet/ios/accept_languages_table.h"
 #include "components/cronet/ios/cronet_environment.h"
 #include "components/cronet/url_request_context_config.h"
 #include "ios/net/crn_http_protocol_handler.h"
 #include "ios/net/empty_nsurlcache.h"
 #include "net/cert/cert_verifier.h"
 #include "net/url_request/url_request_context_getter.h"
 
 namespace {
 
 class CronetHttpProtocolHandlerDelegate;
 
 // Currently there is one and only one instance of CronetEnvironment,
 // which is leaked at the shutdown. We should consider allowing multiple
 // instances if that makes sense in the future.
 base::LazyInstance<std::unique_ptr<cronet::CronetEnvironment>>::Leaky
     gChromeNet = LAZY_INSTANCE_INITIALIZER;
 
 BOOL gHttp2Enabled = YES;
 BOOL gQuicEnabled = NO;
 cronet::URLRequestContextConfig::HttpCacheType gHttpCache =
     cronet::URLRequestContextConfig::HttpCacheType::DISK;
 ScopedVector<cronet::URLRequestContextConfig::QuicHint> gQuicHints;
 NSString* gUserAgent = nil;
 BOOL gUserAgentPartial = NO;
 NSString* gSslKeyLogFileName = nil;
 RequestFilterBlock gRequestFilterBlock = nil;
 std::unique_ptr<CronetHttpProtocolHandlerDelegate> gHttpProtocolHandlerDelegate;
 NSURLCache* gPreservedSharedURLCache = nil;
 BOOL gEnableTestCertVerifierForTesting = FALSE;
+NSString* gAcceptLanguages = nil;
 
 // CertVerifier, which allows any certificates for testing.
 class TestCertVerifier : public net::CertVerifier {
   int Verify(const RequestParams& params,
              net::CRLSet* crl_set,
              net::CertVerifyResult* verify_result,
              const net::CompletionCallback& callback,
              std::unique_ptr<Request>* out_req,
              const net::NetLogWithSource& net_log) override {
     net::Error result = net::OK;
@@ skipping 53 matching lines @@
 
 + (void)configureCronetEnvironmentForTesting:
     (cronet::CronetEnvironment*)cronetEnvironment {
   if (gEnableTestCertVerifierForTesting) {
     std::unique_ptr<TestCertVerifier> test_cert_verifier =
         base::MakeUnique<TestCertVerifier>();
     cronetEnvironment->set_mock_cert_verifier(std::move(test_cert_verifier));
   }
 }
 
++ (NSString*)getAcceptLanguagesFromPreferredLanguages:
+    (NSArray<NSString*>*)languages {
+  NSMutableArray* acceptLanguages = [NSMutableArray new];
+  for (NSString* lang_region in languages) {
+    NSString* lang = [lang_region componentsSeparatedByString:@"-"][0];
+    NSString* localeAcceptLangs = acceptLangs[lang_region] ?: acceptLangs[lang];
+    if (localeAcceptLangs)
+      [acceptLanguages
+          addObjectsFromArray:[localeAcceptLangs
+                                  componentsSeparatedByString:@","]];
+  }
+
+  NSString* acceptLanguageString =
+      [[[NSOrderedSet orderedSetWithArray:acceptLanguages] array]
+          componentsJoinedByString:@","];
+
+  return [acceptLanguageString length] != 0 ? acceptLanguageString
+                                            : @"en-US,en";
+}
+
 + (NSString*)getAcceptLanguages {
-  // Use the framework bundle to search for resources.
-  NSBundle* frameworkBundle = [NSBundle bundleForClass:self];
-  NSString* bundlePath =
-      [frameworkBundle pathForResource:@"cronet_resources" ofType:@"bundle"];
-  NSBundle* bundle = [NSBundle bundleWithPath:bundlePath];
-  NSString* acceptLanguages = NSLocalizedStringWithDefaultValue(
-      @"IDS_ACCEPT_LANGUAGES", @"Localizable", bundle, @"en-US,en",
-      @"These values are copied from Chrome's .xtb files, so the same "
-       "values are used in the |Accept-Language| header. Key name matches "
-       "Chrome's.");
-  if (acceptLanguages == Nil)
-    acceptLanguages = @"";
-  return acceptLanguages;
+  return [self
+      getAcceptLanguagesFromPreferredLanguages:[NSLocale preferredLanguages]];
+}
+
++ (void)setAcceptLanguages:(NSString*)acceptLanguages {
+  [self checkNotStarted];
+  gAcceptLanguages = acceptLanguages;
 }
 
 + (void)checkNotStarted {
   CHECK(gChromeNet == NULL) << "Cronet is already started.";
 }
 
 + (void)setHttp2Enabled:(BOOL)http2Enabled {
   [self checkNotStarted];
   gHttp2Enabled = http2Enabled;
 }
@@ skipping 43 matching lines @@
   else
     gRequestFilterBlock = block;
 }
 
 + (void)startInternal {
   cronet::CronetEnvironment::Initialize();
   std::string user_agent = base::SysNSStringToUTF8(gUserAgent);
   gChromeNet.Get().reset(
       new cronet::CronetEnvironment(user_agent, gUserAgentPartial));
   gChromeNet.Get()->set_accept_language(
-      base::SysNSStringToUTF8([self getAcceptLanguages]));
+      base::SysNSStringToUTF8(gAcceptLanguages ?: [self getAcceptLanguages]));
 
   gChromeNet.Get()->set_http2_enabled(gHttp2Enabled);
   gChromeNet.Get()->set_quic_enabled(gQuicEnabled);
   gChromeNet.Get()->set_http_cache(gHttpCache);
   gChromeNet.Get()->set_ssl_key_log_file_name(
       base::SysNSStringToUTF8(gSslKeyLogFileName));
   for (const auto* quicHint : gQuicHints) {
     gChromeNet.Get()->AddQuicHint(quicHint->host, quicHint->port,
                                   quicHint->alternate_port);
   }
@@ skipping 105 matching lines @@
       base::SysNSStringToUTF8(hostResolverRulesForTesting));
 }
 
 // This is a non-public dummy method that prevents the linker from stripping out
 // the otherwise non-referenced methods from 'bidirectional_stream.cc'.
 + (void)preventStrippingCronetBidirectionalStream {
   bidirectional_stream_create(NULL, 0, 0);
 }
 
 @end