Add a BUILD target and a script to build a public static library for ios/web_view.

ios/web_view/internal/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-source_set("internal") {
-  visibility = [
-    "//ios/web_view",
-    "//ios/web_view/internal/*",
-  ]
+_deps = [
+  "//base",
+  "//components/pref_registry",
+  "//components/prefs",
+  "//components/translate/core/browser",
+  "//components/translate/core/common",
+  "//ios/net",
+  "//ios/web",
+  "//ios/web:user_agent",
+  "//ios/web/public/app",
+  "//ios/web_view/internal/translate",
+  "//ios/web_view/public",
+  "//net",
+  "//net:extras",
+  "//ui/base",
+  "//url",
+]
 
+# An incomplete static library for //ios/web_view. Used as an input of
+# :lib_web_view.
+static_library("web_view_incomplete") {
+  visibility = [ ":*" ]
   sources = [
     "criwv.mm",
     "criwv_browser_state.h",
     "criwv_browser_state.mm",
     "criwv_network_delegate.cc",
     "criwv_network_delegate.h",
     "criwv_url_request_context_getter.h",
     "criwv_url_request_context_getter.mm",
     "criwv_web_client.h",
     "criwv_web_client.mm",
     "criwv_web_main_delegate.h",
     "criwv_web_main_delegate.mm",
     "criwv_web_main_parts.h",
     "criwv_web_main_parts.mm",
     "criwv_web_view.mm",
     "criwv_web_view_internal.h",
     "pref_names.cc",
     "pref_names.h",
   ]
-  deps = [
-    "//base",
-    "//components/pref_registry",
-    "//components/prefs",
-    "//components/translate/core/browser",
-    "//components/translate/core/common",
-    "//ios/net",
-    "//ios/web",
-    "//ios/web:user_agent",
-    "//ios/web/public/app",
-    "//ios/web_view/internal/translate",
-    "//ios/web_view/public",
-    "//net",
-    "//net:extras",
-    "//ui/base",
-    "//url",
-  ]
+  deps = _deps
   allow_circular_includes_from = [ "//ios/web_view/internal/translate" ]
 }
+
+# A static library which contains all dependencies of :web_view_incomplete.
+# Used to build "web_view".

[michaeldo, 2017/02/07 18:14:20]

Please remove the second comment line ("Used to build "web_view"."). This could
easily become a stale comment in the future.

[Hiroshi Ichikawa, 2017/02/08 01:16:21]

Done.

+static_library("deps_complete") {
+  visibility = [ ":*" ]
+  complete_static_lib = true
+  deps = _deps
+}
+
+# A static library expected to be used by apps outside Chromium code base.

[michaeldo, 2017/02/07 18:14:20]

I suggest removing these comments. The public interface to the library is in
//ios/web and you have similar comments there. You can leave the comments in
//ios/web. You can leave the TODO here, but please create bug and update format
to include bug number:

// TODO(crbug.com/######): Something that needs doing.

[Hiroshi Ichikawa, 2017/02/08 01:16:21]

Done.

+# This is a complete static library (containing all dependencies),
+# and it doesn't expose internal symbols to reduce risk of symbol conflict.
+#
+# //ios/web_view is an alias of this library.
+#
+# TODO(ichikawa): Support building a universal binary.
+action("lib_web_view") {
+  visibility = [
+    "//ios/web_view",
+    "//ios/web_view/internal/*",
+  ]
+  script = "hide_symbols.py"
+  deps = [
+    ":deps_complete",
+    ":web_view_incomplete",
+  ]
+  outputs = [
+    "$target_out_dir/libweb_view.a",
+    "$target_out_dir/libweb_view.o",
+  ]
+  args = [
+    "--input_lib",
+    rebase_path("$target_out_dir/libweb_view_incomplete.a", root_build_dir),
+    "--deps_lib",
+    rebase_path("$target_out_dir/libdeps_complete.a", root_build_dir),
+    "--output_obj",
+    rebase_path("$target_out_dir/libweb_view.o", root_build_dir),
+    "--output_lib",
+    rebase_path("$target_out_dir/libweb_view.a", root_build_dir),
+    "--current_cpu",
+    current_cpu,
+  ]
+}